Topic: Snap From Endpoint

[Kerry]

Tracey,

Do you want Text or Mtext in your details ?

If Mtext, do you want the  monotxt.shx override maintained.
If Mtext, do you want the  0.75 TextWidth override maintained.

Style for 0.4 Text   [ and/or Mtext ]
Style for 0.2 Text   [ and/or Mtext ]  Note it is 1.8 H is some design dwgs 2.0 in others ?

Do you want the labels converted to uppercase ?

[Kerry]

OK you two.....get a ROOM or something! Sheeeesh!

Your meaning eludes me. ?

[jonesy]

Poor Mr Bear, did you want to join in the fun!


Kerry, the font should print out as the client standard, which would be either Romand or arial depending on the client, and the height should be 2. The labels, uppercase would be nice, but not essential!

Many thanks
T

[Kerry]

This is worse that pulling teeth .. 

Unless you say otherwise :

Text will be used .. Mtext will be converted.
Style will be "oxford standard" [ currently defined using romand.shx ]
Width scale factor  will be changed from 0.75 to 1.0
0.18 High Text will be changed to 0.2  High and the insert point moved Y -0.2
Table label Text will be changed to uppercase.

Can you resolve these. .. may need to email the .shx files

Substituting [isocp.shx] for [Babtie].
Substituting [isocp.shx] for [Mark 1].

mapping.shx required
civil.shx required

[jonesy]

Kerry, sorry about the delay. (I thought I'd e-mailed you the details)
The Babtie and Mark 1, I dont know why they are in there! It may be something to do with the translation from MX.

I will e-mail the mapping and civil shx files to your e-mail address.

Many thanks for your time

Tracey

[Kerry]

Got them Tracey.

I'll have another look after I have dinner.

[Kerry]

Tracey,
You'll need to explode the "ACAD_PROXY_ENTITY" then explode the "MTEXT"

I used QSELECT quite sucessfully, selecting a column at a time. you should be left with LWPOLYLINE and TEXT only.

Insert the exploded design sections into your Template drawing.

Convert using TJ880.

Relocate using TJ990.

Code: [Select]

(prompt
  "\n SuperDuper SectionTable modifier for Jonesy.[build 2.0]\n Type TJ880 at the commandLine to start"
)

(defun c:TJ880 (/
                ;; Functions
                ProcessPoly     ProcessText    sset->vlalist
                ;; Variables
                TextStyle      LayerExisting   LayerText
                LayerFrame      oName           TJ-KAHUNA
               )
  (setq TextStyle    "oxford standard"
        LayerExisting "C-LEVL-EXTG"
        LayerProposed "C-LEVL-PROP"
        LayerText     "C-LEVL-TEXT"
        LayerFrame    "C-LEVL-FRAM"
  )
  ;;
  ;; KWB @ The Swamp 20051024
  ;;
  ;; ----------------------
  (defun ProcessText (oText / oTextTrueColor oTextString)

    ;;
    (if (equal 0.18 (vla-get-height oText) 0.005)
      (vla-put-height oText 0.20)
    )
    ;;
    (if (equal (/ pi 2) (vla-get-rotation oText) 0.0005)
      (vla-put-insertionpoint
        oText
        (vlax-3d-point
          (mapcar '-
                  (vlax-safearray->list
                    (vlax-variant-value (vla-get-insertionpoint oText))
                  )
                  '(0.0 0.2 0.0)
          )
        )
      )
    )
   
    ;;
    (vla-put-textstring oText (strcase (vla-get-textstring oText)))

    ;;
    (setq oTextTrueColor (vla-get-colorindex (vla-get-truecolor oText))
          oTextString    (vla-get-textstring oText)
    )
   
    ;;
    (cond ((vl-string-search "LEVEL DATUM" oTextString)
           (vla-put-layer oText LayerText)
          )
          ;;
          ((vl-string-search "CHAINAGE" oTextString)
           (vla-put-layer oText LayerText)
          )
          ;;         
          ((= oTextTrueColor acred) (vla-put-layer oText LayerProposed))
          ((= oTextTrueColor acgreen) (vla-put-layer oText LayerExisting))
    )
    (vla-put-stylename oText TextStyle)   
    (vla-put-ScaleFactor oText 1.0)
    (vla-put-color oText acbylayer)
   
    (princ)
  )
  ;; ----------------------
  (defun ProcessPoly (oPoly / oPolyLength oPolyTrueColor)
    (setq oPolyTrueColor (vla-get-colorindex (vla-get-truecolor oPoly))
          oPolyLength    (vla-get-length oPoly)
    )
    (cond ((= oPolyTrueColor acred)
           (vla-put-layer oPoly LayerProposed)
           (vla-put-color oPoly acbylayer)
           ;; To Do :
           ;; add the incline Text
           ;;
          )
          ((= oPolyTrueColor acgreen)
           (vla-put-layer oPoly LayerExisting)
           (vla-put-color oPoly acbylayer)
          )
          ((or (> oPolyLength 15) (equal oPolyLength 0.100 0.01))
           ;; rectangles or markers ..
           (vla-put-layer oPoly LayerFrame)
           (vla-put-color oPoly acbylayer)
          )
          (t
           (vla-put-layer oPoly LayerProposed)
           (vla-put-color oPoly acbylayer)
          )
    )
  )
  ;; ----------------------
  ;; ----------------------
  (defun sset->vlalist (sset / index ReturnValue)
    (setq index (if sset
                  (1- (sslength sset))
                  -1
                )
    )
    (while (>= index 0)
      (setq ReturnValue (cons (vlax-ename->vla-object (ssname sset index))
                              ReturnValue
                        )
            index       (1- index)
      )
    )
    ReturnValue
  )
  ;;
  ;; Main ------------------
  ;;
  ;; Make a selection of the Tables .. saved in TJ-kahuna
  ;;
  (prompt "\n Select Frames to modify.")
  (setq TJ-kahuna (sset->vlalist (ssget)))
  ;;
  ;; Do the mojo
  ;;
  (foreach item TJ-kahuna
    ;; (setq tmp item)
    (cond ((= (vla-get-objectname item) "AcDbPolyline") (ProcessPoly item))
          ((= (vla-get-objectname item) "AcDbText") (ProcessText item))
    )
  ) 
  (princ)
)
(princ)

[jonesy]

WOW

Thank you very much Kerry, it works great, and will save mucho time = more swamp time.


Many thanks

Tracey

[t-bear]

Good looking bit of coding there Kerry!  I especially like the commenting......
"Do the Mojo"? 
"TJ-kahuna"?? 
Sweeeet!!

Have fun there, "TJ"............................

[jonesy]

Thanks T-Bear, now I CAN have some fun instead of pulling my hair out every time there is a design change!

[Kerry]

....... I especially like the commenting......

It's probably just as well most of my code isn't public, some of it DOES have frivolous comments.

Yep, that was fun Ted. No need for pages of assertion testing and error testing.

.. and knowing how much time it would save Tracey was icing on the cake, so to speak.

[jonesy]

Glad you enjoyed yourself Kerry!

Thanks again for the files. Cant wait to start using it in on the next scheme.

Catch you later

T

[jonesy]

Kerry,


THANK YOU, THANK YOU, THANK YOU!

I have just used your routines (the design changed yet again on the 44 drawing sheet scheme I originally whined here about.

Start to finish (with a bit of "talking time") it took around about 1 hour, instead of the nearly 30 hours the first batch took.

Once again, thanks for your help

Tracey

[Kerry]

<SatisfiedSigh.wav>

[MP]

Well done Kerry. I had offered to help our fair friend, but you beat me to it, so I begged off, knowing you'd write an outstanding solution.