Topic: how can i make it work ?

[Andrea]

Hi all..

I have this..

Code: [Select]

(setq b1 2)
(setq val1 (getstring "Enter the value : "))
so if I answer this:

command: Endter the value : (* b1 3)

it doesn't work..

why ?

[Murphy]

Because you are getting a string. You need to use getreal.

[CarlB]

Because you can't reenter lisp.  You should have got that message when you tried it.  You are suppyling a lisp expression to a lisp function that is expecting a string.

[Andrea]

I know I can make this..


(setq b1 2)
(setq val1 (getreal "Enter the value : "))

(setq result (* b1 val1))


But I need to allow user to put his own calculation..

see ?

so he can put (/ (+ b1 2) (* b1 4.3) 1.44)

see ?

[Andrea]

ok ...i found it..

(setq b1 2
        x (getstring "enter your code:")
       y (eval (read x))
)

[MP]

Suggestion --

Code: [Select]

(defun evaluate ( expression / result )
    (setq result
        (vl-catch-all-apply
           '(lambda ( )
                (eval
                    (if (eq 'str (type expression))
                        (read expression)
                        expression
                    )
                )
            )
        )
    )   
    result
)
Then your program can intelligently branch if your user provides bozo input:

Code: [Select]

(defun c:Test ( / expression result texteval )
    (setq texteval (getvar "texteval"))
    (setvar "texteval" 0)
    (if     
        (vl-catch-all-error-p
            (setq result
                (evaluate
                    (setq expression
                        (getstring
                            "Enter an expression: "
                            t
                        )
                    )   
                )
            )
        )
        (princ
            (strcat
                "Error: "
                expression
                " => "
                (vl-catch-all-error-message result)
            )
        )
        (princ
            (strcat
                expression
                " => "
                (vl-prin1-to-string result)
            )
        )
    )
    (setvar "texteval" texteval)
    (princ)
)
Test drive:

Code: [Select]

Command: TEST
Enter an expression: (/ 1 0)
Error: (/ 1 0) => divide by zero

Command:
Command: TEST
Enter an expression: (/ 1 2.0)
(/ 1 2.0) => 0.5
Unless of course a pie in the face is acceptable behavior.

[LE]

Here is a mickey mouse approach, I wrote some years ago..... the request was about on how to add fractional numbers i.e.
12' 5-1/2" + 6' 3-5/8" = 18' 9-1/8"

MMcal = Mickey Mouse Calculator....

Code: [Select]

(defun C:MMcal (/ key fun input inputA data r)
  (initget "+ - Div")
  (if (setq key (getKword "\nOperation [+/-/Div]: "))
    (progn
      (setq fun (eval (read key)))
      (cond
((= fun +)
(while (setq input (getDist "\nInput: "))
   (if input
     (setq data (cons input data))))
(setq r (apply 'fun data)))
((= fun -)
(setq inputA (getDist "\nSubtract base: "))
(while (setq input (getDist "\nFollowing number: "))
   (if input
     (setq data (cons input data))))
(foreach i  data
   (setq inputA (fun inputA i)))
(setq r inputA))
((= key "Div")
(setq inputA (getDist "\nDivide base: "))
(while (setq input (getDist "\nFollowing number: "))
   (if input
     (setq data (cons input data))))
(foreach i  data
   (setq inputA (/ inputA i)))
(setq r inputA)))
      (princ "\nResult: ")
      (princ (rtos r (getvar "lunits") (getvar "luprec")))))
  (princ))