Topic: xdata ssget

[ronjonp]

Why won't this work: 

Code: [Select]

(ssget "X" '((-3 ("WID_Node" (1005 . "0")))))
The block has this xdata in it:

Code: [Select]

(-3 ("WID_Node" (1005 . "0") (1040 . 42.1855)) ("WID_Sprinkler" (1071 . 2010)
(1005 . "0") (1070 . 0) (1070 . 0) (1070 . 0) (1070 . -1) (1040 . 1.5708) (1040
. 19.8122) (1070 . 0)) ("WID_ObjectType" (1070 . 3)))

But it won't make the sset?

[Fatty]

Why won't this work: 

Code: [Select]

(ssget "X" '((-3 ("WID_Node" (1005 . "0")))))
The block has this xdata in it:

Code: [Select]

(-3 ("WID_Node" (1005 . "0") (1040 . 42.1855)) ("WID_Sprinkler" (1071 . 2010)
(1005 . "0") (1070 . 0) (1070 . 0) (1070 . 0) (1070 . -1) (1040 . 1.5708) (1040
. 19.8122) (1070 . 0)) ("WID_ObjectType" (1070 . 3)))

But it won't make the sset?

Sorry I can't to test this but you will try something like this

(setq ss (ssget "_x" (list (list -3 (list 1005 . "0"))))

[ronjonp]

fatty,

This is what i get:

; error: bad argument type: consp "0"

[MP]

If memory serves me correctly you cannot filter beyond the appid name.

[Fatty]

Sorry I can't to test this but you will try something like this

(setq ss (ssget "_x" (list (list -3 (list 1005 . "0"))))

I think better yet:

Code: [Select]

(ssget "_X" (list(list -3(list "WID_Node" ))))

[ronjonp]

That does the same as:

(ssget "X" '((-3 ("WID_Node"))))

I was trying to get the APPID and match data as well.

Thanks,

Ron

[Serge J. Gianolla]

Check Rakesh's site:
http://www.4d-technologies.com/techcenter/index.htm
in the Selection section, have a look at SSgetXD. It can always be modified to suit!

[MP]

In this post I penned this --

Code: [Select]

(defun RemoveFromPicksetIf ( ss func )
    ;;  The supplied func must take one
    ;;  argument, an ename. What it does
    ;;  we don't care, but if it returns
    ;;  a non nil result remove the entity
    ;;  from the pickset
    (if (eq 'pickset (type ss))
        (repeat (setq i (sslength ss))
            (if
                (func
                    (setq ename
                        (ssname ss
                            (setq i (1- i))
                        )
                    )
                )
                (ssdel ename ss)
            )
        )
    )
    ss
)
Which you could then use thusly --

Code: [Select]

(setq ss
    (RemoveFromPicksetIf
        (ssget "X" '((-3 ("WID_Node"))))
        (lambda ( ename / xdata )
            (cond
                (   (null
                        (setq xdata
                            (assoc -3
                                (entget ename
                                   '("WID_Node")
                                )
                            )
                        )
                    )
                )
                (   (null
                        (member
                           '(1005 . "0")
                            (cdadr xdata)
                        )
                    )
                )
            )
        )
    )
)
Coded blind but gotta be close.

[ronjonp]

Thanks guys . I'll take a look at this today and let you know how it works.

[MP]

This is a tad more succinct --

Code: [Select]

(setq ss
    (RemoveFromPicksetIf
        (ssget "X" '((-3 ("WID_Node"))))
        (lambda ( ename / xdata )
            (or
                (null
                    (setq xdata
                        (assoc -3
                            (entget ename
                               '("WID_Node")
                            )
                        )
                    )
                )
                (null
                    (member
                       '(1005 . "0")
                        (cdadr xdata)
                    )
                )
            )
        )
    )
)

[Andrea]

can you send us the file...so we can test..