Topic: Changing attributes

[hudster]

If i have a block with 5 attributes

1, 2, 3 ,4 & 5 how do I extract the information for attribute 3 only?

[Kerry]

What is the TagName for Attribute 3 ??

You could extract all attributes with a generic extractor, then test the return list for the value you want.

The return from getattributelist will be something like this :
(("LABEL" . "VIEW ") ("DET" . "A") ("DWG" . "-") ("N1" . " 32424") ("N2" . " 234534") ("N3" . " 3246463"))

Say your attribute tag is "N1"

Try this :

Code: [Select]

(if (and (setq blockref (car (entsel)))
         (setq attributelist (getattributelist blockref))
         (setq tagvalue (getass "N1" attributelist))
    )
  (Prompt tagvalue)
)With this loaded :

Code: [Select]

(defun getass (key data /) (cdr (assoc key data)))

(defun GetAttributeList (blockref / catchit returnval)
;;
;; kwb@theswamp

  (if (= (type blockref) 'ename)
    (setq blockref (vlax-ename->vla-object blockref))
  )
  (if (and (= (vla-get-objectname blockref) "AcDbBlockReference")
           (= (vla-get-hasattributes blockref) :vlax-true)
      )
    (if (vl-catch-all-error-p
          (setq catchit (vl-catch-all-apply 'vlax-invoke
                                            (list blockref 'getattributes)
                        )
          )
        )
      (alert (vl-catch-all-error-message catchit))
      ;; else should be OK
      (setq returnval (mapcar '(lambda (attref)
                                 (cons (vla-get-tagstring attref)
                                       (vla-get-textstring attref)
                                 )
                               )
                              catchit
                      )
      )
    )
  )
  returnval
)

[hudster]

Call it tag3.

This was just a general question.  I couldn't find anything in the help menu about extracting the value of 1 specific attribute, so I thought I'd ask here.

[Kerry]

Hi Hudster.

You can step through the AcDbBlockReference but it's a pain.

... and what happens when you want 1, 3 and 5 .. you will have to pen a NEW routine, or run yours three times.

Using the method I've posted, you have ALL attributes to deal with at your leisure, and the routine is generic enough to throw into a library file and use regularly without having to think about it.

[hudster]

cheers.

pity there isn't an option like vl-get-attrib or something similar, this would make it easier for newbs like me.

[Kerry]

This will probably work for you.

Code: [Select]

(get-attribute-value (car (entsel)) "N1")

Code: [Select]

(defun get-attribute-value (blockref tag / ent data)
  ;;
  ;; kwb@theswamp
  ;;
  (setq ent blockref)
  (while (and (setq ent (entnext ent))
              (setq data (entget ent))
              (eq (cdr (assoc 0 data)) "ATTRIB")
              (/= (strcase (cdr (assoc 2 data))) tag)
         )
  )
  (if (eq (cdr (assoc 0 data)) "ATTRIB")
    (cdr (assoc 1 data))
  )
)


[modified] edit formatting [/modified]

[MP]

Safe code (making sure a block with attributes) not included ...

Code: [Select]

(if (setq ename (car (entsel)))
    (mapcar
       '(lambda (attribute)
            (cons
                (vla-get-textstring attribute)
                (vla-get-tagstring attribute)
            )
        )
        (vlax-invoke
            (vlax-ename->vla-object ename)
           'GetAttributes
        )
    )
)

[Kerry]

or this for an ActiveX and Error Trapped TagValue getter ...

Code: [Select]

(if (and (setq blockref (car (entsel)))
         (setq tagvalue (getattributeval blockref "N1"))
    )
  (prompt tagvalue)
)

Code: [Select]

(defun getattributeVal (blockref tag / catchit returnval)
  ;;
  ;; kwb@theswamp
  (if (= (type blockref) 'ename)
    (setq blockref (vlax-ename->vla-object blockref))
  )
  (if (and (= (vla-get-objectname blockref) "AcDbBlockReference")
           (= (vla-get-hasattributes blockref) :vlax-true)
      )
    (if (vl-catch-all-error-p
          (setq catchit (vl-catch-all-apply 'vlax-invoke
                                            (list blockref 'getattributes)
                        )
          )
        )
      (alert (vl-catch-all-error-message catchit))
      ;; else should be OK
      (foreach attref catchit
        (if (= (vla-get-tagstring attref) tag)
          (setq returnval (vla-get-textstring attref))
        )
      )
    )
  )
  returnval
)

[Peter Jamtgaard]

Here is another way

Code: [Select]


(defun GetAttributeValue (objSelection strTagstring / dprPair)
 (if (setq lstAttributePairs (getAttributePairs objSelection))
  (if (setq dprPair (assoc (strcase strTagString) lstAttributePairs))
   (vla-get-textstring (cdr dprPair))
  )
 )
)

(defun GetAttributePairs (objSelection / lstAttributes)
 (if (= (type objSelection) 'ename)
  (setq objSelection (vlax-ename->vla-object objSelection))
 )
 (if (and
      (vlax-property-available-p objSelection "hasattributes")
      (setq lstAttributes (vlax-invoke objSelection "GetAttributes"))
     )
  (mapcar '(lambda (objAttribute) (cons (strcase (vla-get-tagstring  objAttribute))
                                        objAttribute
                                  )
           )
           lstAttributes
  )
 )
)