Topic: How many ways can you create a LINE

[Mark]

Just for fun.

How many ways can you create a line [ (0 . "LINE") ] using Auto/Visual LISP?

[MP]

Modifiy  to  suit.

[Mark]

Here are three more ways. 

Code: [Select]


(if (setq sp (getpoint "\nStarting Point: "))
  (if (setq ep (getpoint sp "\nEnding Point: "))
    (command "_.line" sp ep "")
    )
  )


(if (setq sp (getpoint "\nStarting Point: "))
  (if (setq ep (getpoint sp "\nEnding Point: "))
    (entmake
      (list
'(0 . "LINE")
'(100 . "AcDbLine")
(cons 10 sp)
(cons 11 ep)
      )
    )
  )
)


(vl-cmdf "_.line"
(setq sp (getpoint "\nStart Point: "))
(getpoint sp "\nEnd Point: ")
""
)

[MP]

In case anyone couldn't see how they should modify this to suit here's some code to chew on --

Code: [Select]

(defun RubeGoldberg ( points / *error* document space p1 p2 )

    ;;  a different way to handle bozo input

    (cond
        (
            (or
                (null (listp points))
                (< (length points) 2)
                (null
                    (vl-every
                       '(lambda (point)
                            (apply 'and
                                (mapcar
                                   'numberp
                                    point
                                )
                            )
                        )
                        points
                    )
                )
            )
            (defun *error* (x)
                (princ
                    (strcat
                        "Bozo alert: Must be a list "
                        "of at least 2 points.\n"
                    )   
                )
                (princ)
            )
            (exit)
        )
    )
   
    ;;  space, the final frontier             

    (setq space
        (if
            (zerop
                (vla-get-activespace
                    (setq document
                        (vla-get-activedocument
                            (vlax-get-acad-object)
                        )
                    )   
                )
            )
            (vla-get-paperspace document)
            (vla-get-modelspace document)
        )   
    )
   
    ;;  normalize the points (i.e. make sure they're
    ;;  all 3D)
   
    (setq points
        (mapcar
           '(lambda (point)
                (while (< (length point) 3)
                    (setq point
                        (append point
                          '(0)
                        )
                    )
                )
                point
            )
            points
        )               
    )
   
    ;;  let's make two arrays before entering the loop
    ;;  (instead of making them for each iterration)
    ;;
    ;;  [ coded specifically to annoy Se7en ]
   
    (mapcar
        '(lambda (x)
            (set x
                (vlax-make-safearray
                    vlax-vbdouble
                    (cons 0 2)
                )
            )   
        )
       '(p1 p2)
    )

    ;;  a more logical way to achieve
    ;;  the same would be --
    ;;
    ;;  (foreach x '(p1 p2)
    ;;      (set x
    ;;          (vlax-make-safearray
    ;;              vlax-vbdouble
    ;;              (cons 0 2)
    ;;          )
    ;;      )   
    ;;  )
    ;;
    ;;  in the event you're going, "what
    ;;  the .." is he talking about all the
    ;;  crud above does the same as --
    ;;
    ;;  (setq
    ;;      p1 (vlax-make-safearray vlax-vbdouble (cons 0 2))
    ;;      p2 (vlax-make-safearray vlax-vbdouble (cons 0 2))
    ;;  ) 
    ;;
    ;;  Why do I bother? Because it's fun
    ;;  and I don't have many toys.
   
    ;;  anyway, let's rock and roll --
   
    (while (< 1 (length points))   
        (vlax-invoke-method
            Space
           'AddLine
            (vlax-safearray-fill p1 (car points))       
            (vlax-safearray-fill p2 (cadr points))       
        )
        (setq points (cdr points))
    )

    (princ)

)

[Bob Wahr]

(defun c:makealine()(command ".line"))

[CAB]

Here are two simple ways you see in routines.

Code: [Select]

(command "LINE" pause pause "")

Code: [Select]

(command "LINE")
(while (> (getvar "CMDACTIVE") 0)
  (command pause)
)

[Bob Wahr]

Code: [Select]

(command "LINE")
(while (> (getvar "CMDACTIVE") 0)
 (command pause)
)

correct me if I'm wrong but this would fail miserably wouldn't it?

[MP]

I must correct you because you are wrong.

[Bob Wahr]

You're right, doesn't work as desired though.  All of this

Code: [Select]

(while (> (getvar "CMDACTIVE") 0)
(command pause)
)
is wasted and it requires enter to be pressed to get rid of the extra

Code: [Select]

)

[MP]

<clearing throat>

...

Eh?

[Bob Wahr]

Code: [Select]

(command "LINE")
(while (> (getvar "CMDACTIVE") 0)
(command pause)
)pasted into the command line looks a lot like

Code: [Select]

Command: (command "LINE")
LINE Specify first point: nil
Specify first point: (while (> (getvar "CMDACTIVE") 0)
(_> (command pause)
(_> )

Specify next point or [Undo]:
Specify next point or [Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Command: nil
He's missing the beginning bits like a

Code: [Select]

(and maybe a

Code: [Select]

defun or so.

[Bob Wahr]

if not, what am I missing?

[MP]

I didn't say it's elegant, just that is doesn't fail miserably.

[Bob Wahr]

I agreed with that.  My last post was in response to "Eh?"

[MP]

Sorry. It could benefit from a wrapper, agreed. Since we all know CAB is capable of a lot more than that I choose to believe he was just showing the bare minimum of what is frequently done.