Topic: Line hop routine anyone??

[PDJ]

I think I used to have this routine but, I haven't been able to find it yet. 

What I need is like when you have a circuit or electrical drawing and one line crosses another without an actual connection, the line basically is broken and then an arc is drawn between the two broken parts.  So, you have one solid line say running north to south and the line running from east to west has a chunk taken out of it where it crosses the N/S line and an arc spanning the chunk, in a sense, hopping over the N/S wire..

It would be nice if the chunk that's removed and the arc were somehow able to be set to a certain amount or radius or somethin, know what I mean??

OK, that's what I got.. Any ideas??

[David Hall]

I have a routine that breaks the line, could be modified pretty easily

[David Hall]

Code: [Select]

(DEFUN C:Bkwr (/ PT PT1 PT2 PT3 A1)
  (modes '("CMDECHO" "osmode" "orthomode"))
  (PROMPT "\n \nBreak @ Intersection")
  (INITGET 1)
  (SETVAR "OSMODE" 32)
  (COMMAND "SNAP" "OFF")
  (setq dsc (getvar "dimscale"))
  (SETQ PT1 (GETPOINT "\n\n Pick intersection to be broken: "))
  (SETVAR "OSMODE" 0)
  (INITGET 33)
  (SETVAR "OSMODE" 512)
  (SETQ PT (GETPOINT PT1 "\n Pick Line to be broken: "))
  (IF (= BRKW NIL)
    (SETQ BRKW 0.0625) ;set wire gap here. Gap is double the value set
  )
  (SETQ A1  (ANGLE PT1 PT)
PT2 (POLAR PT1 A1 (* dsc BRKW))
PT3 (POLAR PT1 (+ A1 PI) (* dsc BRKW))
  )
  (COMMAND ".BREAK" PT "F" PT2 PT3)
  (moder)
)
Just add the code for an arc after the break part

[David Hall]

modes and moder are system setvar store routines.  You might need those if you dont have them already, OR just do 2 setq's

[Dommy2Hotty]

Courtesy of Resource Cad


EDIT: DELETED ATTACHMENT

[CAB]

http://www.theswamp.org/forum/index.php?topic=2561.msg32351#msg32351

http://www.theswamp.org/forum/index.php?topic=2670.msg33775#msg33775

[PDJ]

Thanks mega bunches for the help guys.. Post a request before lunch and have multiple solutions by the time you get back.. Can't get any better than that..

[Amsterdammed]

Yes, isn't the swamp a great place!!!!!!!!!!!!!

[John Hancock]

YES ! ! !  The Swamp is great ! ! ! !     

[Andrea]

no...the swamp is the best !

[hyposmurf]

I use CAB's routine for trimming pipework/electrical cabling crossovers.The time it takes to move pipes to align with a new architects layout.Don't think allot of the engineers realise the lines have to moved offset trimmed etc,on a complex drawing this can take a while.CAB's  routine  is a Godsend.

[CAB]

Not sure if you were referring to this routine http://www.theswamp.org/forum/index.php?topic=2651.msg67536#msg67536

or the one I modified originally by A.Henderson http://www.theswamp.org/forum/index.php?topic=2651.msg33953#msg33953



Thanks for the mention. Glad you have found the routine helpful.
It's amazing how much cumulative time is saved with all the lisp helpers!

[Peter Jamtgaard]

Here is another version.

Code: [Select]

(defun C:Hop (/ lstIntPOint
                 lstPoint1
                 lstPoint2
                 objSelection1
                 objSelection2
                 sngDistance
                 sngDistance1
                 sngDistance2
                 sngRadius
              )
 (setq objSelection1 (vlax-ename->vla-object
                      (car (entsel "\nSelect line to be broken: ")))
       objSelection2 (vlax-ename->vla-object
                      (car (entsel "\nSelect line to NOT be broken: ")))
       sngRadius     (getdist "\nEnter radius: ")
       lstIntPoint  (vlax-safearray->list
                     (variant-value
                      (vla-intersectwith objSelection1 objSelection2 0)))
       sngDistance  (vlax-curve-getdistatpoint objSelection1 lstIntPoint)
       sngDIstance1 (- sngDistance sngRadius)
       sngDIstance2 (+ sngDistance sngRadius)
 )                   
 (vl-cmdf "break"
          (vlax-vla-object->ename objSelection1)
          "f"
          (setq lstPOint1 (vlax-curve-getpointatdist objSelection1 sngDistance1))
          (setq lstPOint2 (vlax-curve-getpointatdist objSelection1 sngDistance2))
 )
 (vl-cmdf "arc"
           lstPOint1
          "c"
          lstIntPOint
          lstPoint2
 )       
)