Topic: Draw a 3dpoly with point in a list

[Amsterdammed]

Hello everybody.
The challenge I face today is to draw a 3dpoly line with points coming out of a list. The length of the list can vary.

Any Ideas?

Thanks in Advance

Bernd

[Peter Jamtgaard]

Code: [Select]

(defun Draw3dpoly (lstOfPoints / lstPoint)
  (command "3dpoly")
  (foreach lstPoint lstOfPoints
    (command lstPoint)
  )
  (command "")
 )


[MP]

Code: [Select]

(apply 'command
    (append
       '(".3dpoly")
        points
       '("")
    )
)

[MP]

Code: [Select]

(defun foo ( points )

    (entmake
       '(
           (0 . "POLYLINE")
           (100 . "AcDbEntity")
           (100 . "AcDb3dPolyline")
           (66 . 1)
           (10 0.0 0.0 0.0)
           (70 . 8)
           (40 . 0.0)
           (41 . 0.0)
           (210 0.0 0.0 1.0)
           (71 . 0)
           (72 . 0)
           (73 . 0)
           (74 . 0)
           (75 . 0)
        )
    )
   
    (foreach point points
        (entmake
            (append
               '(
                   (0 . "VERTEX")
                   (100 . "AcDbEntity")
                   (100 . "AcDbVertex")
                   (100 . "AcDb3dPolylineVertex")
                )
                (list (cons 10 point))
               '(
                   (40 . 0.0)
                   (41 . 0.0)
                   (42 . 0.0)
                   (70 . 32)
                   (50 . 0.0)
                   (71 . 0)
                   (72 . 0)
                   (73 . 0)
                   (74 . 0)
                )
            )   
        )   
    )
   
    (entmake
       '(
           (0 . "SEQEND")
           (100 . "AcDbEntity")
        )
    )
   
    (princ)
   
)

[MP]

Code: [Select]

(defun foo2 ( points / *error* document space )

    ;;  a different way to handle bozo input

    (cond
        (
            (or
                (null (listp points))
                (< (length points) 2)
                (null
                    (vl-every
                       '(lambda (point)
                            (apply 'and
                                (mapcar
                                   'numberp
                                    point
                                )
                            )
                        )
                        points
                    )
                )
            )
            (defun *error* (x)
                (princ
                    (strcat
                        "Bozo alert: Must be a list "
                        "of at least 2 points.\n"
                    )   
                )
                (princ)
            )
            (exit)
        )
    )
   
    ;;  let's rock it out               

    (setq space
        (if
            (zerop
                (vla-get-activespace
                    (setq document
                        (vla-get-activedocument
                            (vlax-get-acad-object)
                        )
                    )   
                )
            )
            (vla-get-paperspace document)
            (vla-get-modelspace document)
        )   
    )
   
    (vlax-invoke-method
        space
       'Add3DPoly
        (vlax-safearray-fill
            (vlax-make-safearray
                vlax-vbdouble
                (cons 0
                    (1-
                        (length
                            (setq points
                                (apply 'append
                                    (mapcar
                                       '(lambda (point)
                                            (while (< (length point) 3)
                                                (setq point
                                                    (append point
                                                      '(0)
                                                    )
                                                )
                                            )
                                            point
                                        )
                                        points
                                    )               
                                )
                            )   
                        )   
                    )
                )
            )
            points
        )       
    )

    (princ)

)

[Amsterdammed]

Wou,
eh, thanks Micheal. I'm impressed.

Bernd

[MP]

Wou,
eh, thanks Micheal.

Bernd

My pleasure. I frequently get kinda chatty after a migraine (yesterday I was wiped out).

[Kerry]

Now, ... THIS is funny.

[added]
The comparisons of code I mean ..
.. perhaps I do need testing after all.

[Mark]

Code: [Select]

(apply 'command
    (append
       '(".3dpoly")
        points
       '("")
    )
)

What the . . .   didn't know you could do that

Thanks for the lesson Michael.  :kewl:

[LE]

other....

Code: [Select]

  (command "_.pline")
  (mapcar 'command pts)
  (command "_c")


[Kerry]

Yes Mark, thats very pretty isn't it.

[LE]

Or...

Code: [Select]

$ (setq pts (list a b c d "_c"))
((-6.67905 14.9635 0.0) (-3.9975 13.5826 0.0) (-6.09851 12.3811 0.0) (-6.99697 13.403 0.0) "_c")
_$ (command "_.pline")
  (mapcar 'command pts)


[LE]

or...

Code: [Select]

$ (setq pts (list "_.pline" a b c d "_c"))
("_.pline" (-6.67905 14.9635 0.0) (-3.9975 13.5826 0.0) (-6.09851 12.3811 0.0) (-6.99697 13.403 0.0) "_c")
(mapcar 'command pts)


[Mark]

And the hits just keep on coming. Very nice Luis.  :kewl:

[Mark]

Yes Mark, thats very pretty isn't it.

Indeed it is.  You guys never cease to amaze me.