Topic: Closet Shelf Creator

[CAB]

This is  routine I wrote to create a "Shelf & Rod" in a closet
by picking the wall corners where the shelf will be and the
picking the side of the wall the shelf will be.

Routine creates the the following  if it doesn't exist.
linetype "Short Dash"
layer "Shelf"
option to create layer "Rod"

Comments, correction or improvements welcome.

CAB

Code: [Select]


;;             Shelf.lsp
;;      Created by C. Alan Butler  2003
;;       Version 1.2 01/22/2004  added linetype create
;;       Version 2.0 01/23/2004  added layer create
;;;
;;;   THIS SOFTWARE IS PROVIDED "AS IS" WITHOUT EXPRESS OR IMPLIED
;;;   WARRANTY.  ALL IMPLIED WARRANTIES OF FITNESS FOR ANY PARTICULAR
;;;   PURPOSE AND OF MERCHANTABILITY ARE HEREBY DISCLAIMED.
;;;
;;;
;;
;;

 ;======================
 ;    Start of Routine
 ;======================
(defun c:shelf (/ pto pt1 pt2 usercmd useros str en1 rod shelf lntyp)
  ;; error function & Routine Exit
  (defun *error* (msg)
    (if
      (not
        (member
          msg
          '("console break" "Function cancelled" "quit / exit abort" "")
        )
      )
       (princ (strcat "\nError: " msg))
    ) ; if
    (setvar "osmode" useros)
    (setvar "CMDECHO" usercmd)

    (princ);; Exit quietly
  ) ;
 ;end error function

;;; -------  Some Housekeeping   ------------------
  (setq usercmd (getvar "CMDECHO"))
  (setvar "CMDECHO" 0)
  (setvar "PLINEWID" 0) ; did not save this setting
  (setq useros (getvar "osmode")
        str    ""
        lntyp  "Short Dash"
  )
  (setvar "osmode" 175) ; force snaps on

  ;; Line type setup
  (if (not (tblsearch "ltype" lntyp)) ; ltype not found
    (progn
      (prompt (strcat "\nCreating Linetype \"" lntyp "\""))
      (if (not (entmake ; create a linetype
                 (list '(0 . "LTYPE")
                       '(100 . "AcDbSymbolTableRecord")
                       '(100 . "AcDbLinetypeTableRecord")
                       (cons 2 lntyp) ; this allows variables
                       '(70 . 0)
                       '(3 . "Very short dash  - - - - - -")
                       '(72 . 65)
                       '(73 . 2)
                       '(40 . 0.25)
                       '(49 . 0.125)
                       '(74 . 0)
                       '(49 . -0.125)
                       '(74 . 0)
                 ) ; end list
               ) ; end entmake
          )

        (setq lntyp nil)
        ;;create failed flag failed linetype
      ) ; endif
    ) ; end progn
  ) ; endif
  ;;  Layer Setup
  (if (not (tblsearch "layer" "Shelf"))
    (command "-layer" "_M" ; New
             "Shelf" ; name
             "_C" "3" ; color green
             "" "" ; done
  )
    )
  ;;  IF you want the rod on another layer
 ;(if (not (tblsearch "layer" "Rod"))
 ;  (command "-layer" "_M" "Rod"
 ;           "_L" lntyp ; set line type
 ;           "_C" "1"   ; set color
 ;           "" "")
 ;)
  ;; if you want the rod & shelf on same layer use this next line
  ;; as is. to use rod layer change "shelf" to "rod"
  (setq rodlay "Shelf")

  ;; Draw the pline, get the first point
  (if (setq pt1 (getpoint "\nPick points, Enter when done."))
    (progn
      ;;  start the pline command and get second point
      (command "PLINE" pt1 (setq pt2 (getpoint pt1)))
      (if pt2
        (progn
          ;;  loop getting points until user presses enter
          (while (setq pt2 (getpoint pt2 "\nNext point: "))
            (command pt2)
          )
          (command "") ; make sure command is ended
          (princ)
          (setq en1 (entlast)) ; get the pline drawn

          ;; getthe side to offset the shelf to
          (setvar "osmode" 0) ; turn osnaps off
          (initget 1)
          (if (setq pto (getpoint "\nPick Side to offset to:"))
            (progn
              (command "_.offset" 14 en1 pto "") ; shelf line 14
              (setq shelf (entlast))
              (command "_.offset" 12 en1 pto "") ; rod line 12
              (setq rod (entlast))
              (if lntyp ; if linetype exist or was created use it
                (command "Change" rod "" "P" "LT" lntyp "")
              )
              (command "change" shelf "" "p" "la" rodlay "")
              (command "change" shelf "" "p" "la" "shelf" "")
              (entdel en1) ; remove the user drawn line
            ) ; end progn
          ) ; endif pto
        ) ; end progn
      ) ; endif pt2
    ) ; end progn
  ) ; endif pt1
  (*error* "")
  ;; go to *error* for Exit Sequence

) ;_end of defun

;;; Notify user program ready to use
(prompt "\n Shelves Creator Loaded:   Type 'Shelf' to run it.")
(princ)


[Keith™]

Cab, for my Shelf & Rod, I use a custom MLine type and a custom button to set the scale, offset, and layer for the line. I can then select any point follow along that line and select the other point for the shelf.

I can post the linetype if you are interested.

[CAB]

K
Curious as always.

Does it handle irregular closets, ie U shaped, L shaped, 45deg walls?

Would like to see how you did it.

CAB

[CAB]

Here are my only personal line types.

[hendie]

that first one is okay if you're drawing in imperial but what if you're drawing in metric ?














 

[Dommy2Hotty]

Here's the one I made for closets...it uses a polyline for irregular closets...

(defun c:RODSHELF()

(command "._pline") ; start pline
(while (eq (logand (getvar "CmdActive") 1) 1) ; while active command
(command pause) ; get user's input
) ;_ closes while


(setq PL (entlast))

(setq INT (getpoint "\nSelect Interior of closet : " ))
;gets side to offset

(command "offset" "12.0" PL INT "")

(setq SHELF (entlast))

(command "change" SHELF "" "P" "LA" "CAB" "")

(command "offset" "10.0" PL INT "")

(setq ROD (entlast))

(command "change" ROD "" "P" "LA" "CAB" "LT" "CENTER2" "")

(command "erase" PL "")

(command "explode" SHELF "")

(command "explode" ROD "")

(princ)

)
(princ)

[Keith™]

Paste this in a custom.mln file and load it with mlstyle

justification = zero, scale = 1, style = shelf

MLSTYLE
2
 SHELF
70
 0
3
 SHELF AND ROD
62
 256
51
 90.00000000000000
52
 90.00000000000000
71
 2
49
 12.00000000000000
62
 256
6
 Continuous
49
 10.00000000000000
62
 256
6
 DASHED
0

[Keith™]

Oh.. .and yes CAB it DOES handle irregular shapes