Topic: Determining if a Block is Dynamic

[bertybassett]

Hi,

Is it possible to find out if a block is dynamic from its table/definition properties. I can do it by selecting blocks:

(setq myblk (vlax-ename->vla-object(car(entsel))))(vla-get-IsDynamicBlock myblk)

But I don't want to select the block. I just need to know from its definition that it is dynamic or contains a visibility parameter.

Thanks in advance.

[ronjonp]

Welcome to TheSwamp

Try this:

Code - Auto/Visual Lisp: [Select]

1. (if (setq myblk (car (entsel)))
2.   (vla-get-isdynamicblock
3.     (vla-item (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
4.               (vla-get-effectivename (vlax-ename->vla-object myblk))
5.     )
6.   )
7. )

[bertybassett]

Hi ronjonp,

Thank you for your response. As I say I can get the result by selecting the block as you have done. What I'm looking for is something along the lines of:

(tblsearch "block" myblk) if my myblk exists then test if it is dynamic. I suppose a work around would be to insert the block, test it, then delete entlast. Just trying to find the cleanest solution possible.

[Lee Mac]

If you look slightly closer at Ron's example, the selection is purely to facilitate acquiring a test block for the purposes of the example - the code is retrieving the value of the isdynamicblock property from the block definition, not the selected reference.

The example could have equivalently been written to provide a block name instead of a selection, e.g.:

Code - Auto/Visual Lisp: [Select]

1. (if
2.     (and
3.         (/= "" (setq blk (getstring t "\nSpecify block name: ")))
4.         (tblsearch "block" blk)
5.     )
6.     (vla-get-isdynamicblock (vla-item (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))) blk))
7. )

[bertybassett]

Apologies Ron for not reading properly. Thank you for clarifying Lee.

Goal achieved. Thank you both.

[ronjonp]

Apologies Ron for not reading properly. Thank you for clarifying Lee.

Goal achieved. Thank you both.

Glad you got it sorted.