Topic: Routine runs straight through but not complete.

[jlogan02]

If I separate ----Test TBs----- from the ---dcl--- & ----Scale TBs------- all works fine in two separate routines. Combining them doesn't seem to work. Debugging isn't showing me anything at all. The routine goes through (for the most part) the entire routine.

I've experienced this before with combining routines and the same thing happened, so I'm assuming I'm missing a piece of the puzzle.

Code - Auto/Visual Lisp: [Select]

1.  
2. (vl-load-com)
3.  
4. (defun c:spacex (/ ss attvalue dimsc blk1 fld1 siz names dsty dstydata userclick x obj obj1 obj2
5.                        olay ss ss1 ss2 tag1 tag2 att )
6.   (defun *error* (msg)
7.     (if osm
8.       (setvar 'osmode osm)
9.     )
10.     (if (not (member msg '("Function cancelled" "quit / exit abort")))
11.       (princ (strcat "\nError: " msg))
12.     )
13.     (princ)
14.   )
15.   (setq osm (getvar 'osmode))
16.   (setvar 'osmode 0)
17.   (setvar 'cmdecho 0)
18.  
19.     (defun lm:getattributevalue (blk tag / val enx)
20.     (while
21.       (and (null val)
22.            (= "ATTRIB"
23.               (cdr (assoc 0 (setq enx (entget (setq blk (entnext blk))))))
24.            )
25.       )
26.       (if (= (strcase tag) (strcase (cdr (assoc 2 enx))))
27.         (setq val (cdr (assoc 1 enx)))
28.       )
29.     )
30.   )
31.  
32. ;;------------------test and insert TBs---------------------------  
33.  
34.   (setq ss (ssget "x" '((0 . "INSERT") (2 . "ATTSubCode") (66 . 1))))
35.   (setq attvalue (LM:GetAttributeValue (ssname ss 0) "HIDDEN_SUBJCODE"))
36.   (setq dimsc (getvar 'dimscale))
37.   (cond
38.    ((wcmatch (strcase attvalue)
39.               "03,05,84,60,62,64,80,66,67,68,72,70,71,73,74,86,88,89,82,83,90,92,93,94,96,98,41,42,43,43,44,45,46,47,48,49,50,51,52,53,54,55,56,57,58,59"
40.    )
41.    
42.     (command-s "layout" "t" "TBLK_BORD_STR_STD" "ANSI-D 22x34")
43.     (command "Clayout" "ANSI-D 22x34")
44.     (command "_.-insert" "STA_STR_STANDARDS" "0,0" dimsc dimsc "0")
45.     (command "-layer" "filter" "s" "All" "")
46.     (command "zoom" "all")
47.     )
48.  
49.   ((wcmatch (strcase attvalue)
50.               "05,01,10,14,16,40,12,29,20,22,30,34,32,35,41,42,56,44,46,48,49,50,52,67"
51.    )
52.     (command "Clayout" "Model")
53.     (command "_.-insert" "BLANK" "0,0" dimsc dimsc "0")
54.     (command "explode" "last")
55.     ;;(command "._layer" "unlock" "TTBK_BORD_LINES" "")
56.     ;;(command "._layer" "Make" "LINE1" "C" "YELLOW" "LINE1" "")
57.     (command "Zoom" "Extents")
58.   )
59.  )
60.  
61. ;;-----------------dcl------------------
62.  
63.  (setq SIZ "0")
64.   (setq NAMES '("NONE" "1/4\" = 1'-0\"" "1/2\" = 1'-0\"" "1\" = 1'-0\""
65.                 "1-1/2\" = 1'-0\"" "3\" = 1'-0\"" "6\" = 1'-0\""
66.                )
67.   )
68.  
69.   (setq dcl_id (load_dialog "STA_Scale_TB.dcl")) ;load dialog
70.  
71.   (if (not (new_dialog "STA_Scale_TB" dcl_id))  ;test for dialog
72.     (exit) ;exit if no dialog
73.   ) ;if
74.  
75.   (start_list "scales") ;start the list box
76.   (mapcar 'add_list NAMES) ;fill the list box
77.   (end_list) ;end list
78.  
79.   (action_tile
80.     "cancel" ;if cancel button pressed
81.     "(done_dialog) (setq userclick nil)" ;close dialog, set flag
82.   ) ;action_tile
83.  
84.   (action_tile
85.     "accept" ;if O.K. pressed
86.     (strcat ;string 'em together
87.             "(progn
88.        (setq SIZ (get_tile \"scales\")))"
89.             ;get list selection
90.             "(done_dialog)(setq userclick T))" ;close dialog, set flag
91.     ) ;strcat
92.   ) ;action tile
93.  
94.   (start_dialog) ;start dialog
95.  
96.   (unload_dialog dcl_id) ;unload
97.  
98.   (if userclick  ;check O.K. was selected
99.     (progn
100.       (cond
101.         ((= SIZ "0") (setvar "dimscale" 1))
102.         ;;FULL
103.         ((= SIZ "1") (setvar "dimscale" 48))
104.         ;;1/4"
105.         ((= SIZ "2") (setvar "dimscale" 24))
106.         ;;1/2"
107.         ((= SIZ "3") (setvar "dimscale" 12))
108.         ;;1"
109.         ((= SIZ "4") (setvar "dimscale" 8))
110.         ;;1 1/2"
111.         ((= SIZ "5") (setvar "dimscale" 4))
112.         ;;3"
113.         ((= SIZ "6") (setvar "dimscale" 2))
114.         ;;6"
115.       ) ;cond
116.  
117.  
118.     (setq tag1 "DRAWINGSCALE")
119.       (setq ss (ssget "x" '((2 . "TBLK_ATT_STA") (66 . 1))))
120.       (repeat (setq x (sslength ss))
121.         (setq obj (vlax-ename->vla-object (ssname SS (setq x (- x 1)))))
122.         (if (= (vla-get-hasattributes obj) :vlax-true)
123.           (foreach att (vlax-invoke obj 'getattributes)
124.             (if (= tag1 (strcase (vla-get-tagstring att)))
125.               (vla-put-textstring att (nth (atoi siz) names))
126.             )
127.           )
128.         )
129.       )
130.  
131.    
132.   (setq tag2 "DESIGNER")
133.    (if (setq ss1 (ssget "_X" '((0 . "INSERT") (2 . "TBLK_ATT_STA") (66 . 1))))
134.     (repeat (setq idx (sslength ss1))
135.         (setq idx (1- idx)
136.               obj (vlax-ename->vla-object (ssname ss1 idx))
137.         )
138.         (vl-some
139.            '(lambda ( att )
140.                 (if (and (= tag2 (strcase (vla-get-tagstring att))) (vlax-write-enabled-p att))
141.                     (not (vla-put-textstring att (strcase (substr (getvar 'loginname) 1 3))))
142.                 )
143.             )
144.             (vlax-invoke obj 'getattributes)
145.         )
146.     )
147. )
148.  
149. ;;--------------------Scale TBs------------------------
150.  
151.      (setq dimsc (getvar 'dimscale))
152.         (command "-layer" "unlock" "TTBK_BORD_LINES" "")
153.  
154.       (setq blk1 (ssget "x" '((2 . "TBLK_BORD_CTL,TBLK_BORD_MAX,TBLK_ATT_STA"))))  ;;TBLK_BORD_CTL
155.         (command "scale" blk1 "" "0,0" dimsc)
156.      
157.      
158.       (setq fld1 (ssget "x" '((8 . "TTBK_TBLK_VAULTNO"))))  ;;Vault number field.
159.         (command "scale" fld1 "" "0,0" dimsc)
160.      
161.       ;;(command "-layer" "lock" "TTBK_BORD_LINES" "")
162.  
163.       (setvar "fielddisplay" 0)
164.  
165.       (if (= (tblsearch "layer" "TTBK_TBLK_REVINIT"))
166.         (command "-Layer" "Make" "TTBK_TBLK_REVINIT" "c" "green" "TTBK_TBLK_REVINIT" "")
167.       )
168.      
169.       (setq Odyn (getvar 'dynmode))
170.       (setvar 'dynmode 0)
171.      
172.       (while (setq dsty (tblnext "dimstyle" (not dsty)))
173.         (setq dstydata (entget
174.                          (tblobjname "dimstyle" (cdr (assoc 2 dsty)))
175.                        )
176.         )
177.         (if (assoc 40 dstydata)  ; [because not included in data if default 1.0]
178.           (entmod
179.             (subst (cons 40 dimsc) (assoc 40 dstydata) dstydata)
180.           )
181.           ; then -- replace it
182.           (entmod (append dstydata (list (cons 40 dimsc))))
183.           ; else -- add it
184.         )
185.       )
186.  
187.       (command "layer" "M" "LINE1" "C" "YELLOW" "LINE1" "")
188.       (command "limits" (getvar "extmin") (getvar "extmax"))
189.       (command "zoom" "e")
190.  
191.  
192.       (setvar "CMDECHO" 0)
193.       (setvar "BLIPMODE" 0)
194.  
195.       (command ".style" "Standard" "ipco.shx" (* 1.000 dimsc) "0.85" "0" "n" "n" "n")
196.       (command ".style" "L080" "ipco.shx" (* 0.0781 dimsc) "0.85" "0" "n" "n" "n")
197.       (command ".style" "L100" "ipco.shx" (* 0.0938 dimsc) "0.85" "0" "n" "n" "n")
198.       (command ".style" "L120" "ipco.shx" (* 0.1094 dimsc) "0.85" "0" "n" "n" "n")
199.       (command ".style" "L140" "ipco.shx" (* 0.1406 dimsc) "0.85" "0" "n" "n" "n")
200.       (command ".style" "L175" "ipco.shx" (* 0.1563 dimsc) "0.85" "0" "n" "n" "n")
201.       (command ".style" "L200" "ipco.shx" (* 0.1719 dimsc) "0.85" "0" "n" "n" "n")
202.       (command ".style" "L240" "ipco.shx" (* 0.2187 dimsc) "0.85" "0" "n" "n" "n")
203.    
204.       (command ".style" "Ls080" "ipco.shx" (* 0.0781 dimsc) "0.85" "0" "n" "n" "n")
205.       (command ".style" "Ls100" "ipco.shx" (* 0.0938 dimsc) "0.85" "0" "n" "n" "n")
206.       (command ".style" "Ls120" "ipco.shx" (* 0.1094 dimsc) "0.85" "0" "n" "n" "n")
207.       (command ".style" "Ls140" "ipco.shx" (* 0.1406 dimsc) "0.85" "0" "n" "n" "n")
208.       (command ".style" "Ls175" "ipco.shx" (* 0.1563 dimsc) "0.85" "0" "n" "n" "n")
209.       (command ".style" "Ls200" "ipco.shx" (* 0.1719 dimsc) "0.85" "0" "n" "n" "n")
210.       (command ".style" "Ls240" "ipco.shx" (* 0.2187 dimsc) "0.85" "0" "n" "n" "n")
211.      
212.     ) ;progn
213.    )
214.    
215.       (setvar "cmdecho" 1)
216.       (setvar "dynmode" Odyn)
217.       (command "_zoom" "e")
218.      
219.       (alert "Way to go!!! You scaled the border.")
220.  
221.    (princ)
222. )

The theory is...
We have a 3rd party drawing vault where a properties card is filled out with a subject code for each drawing type. This routine would look at the subject code in the TB attribute and insert the correct title block. If the subject code is a model space code the dcl fires and asks the user for a scale (I know...why don't you use paper space?!?!? If you feel the need to discuss that, please move on.) I get the dcl to pop up and the dimscale is properly set from that selection, the line1 layer is set current but nothin else in that section is working.

[jlogan02]

forgot to attach the dcl. Sadly, I can't attach company drawings.

[BIGAL]

A couple of suggestions, use a dwg template with your layouts all setup with different sizes, I dont understand why your scaling your title block, we never did that, that is what Mview is for set a scale for the view of the model objects

Re your dcl you can use this in future it only requires like 2 lines of code to make a dcl and get an answer. Look at examples in start of code, you get a string as answer form pick or for multiple choices look at the value of "but" and compare to a list.

By using a dwt all your layers are set and all your styles exist. We would get a dwg from a external source and just paste into our template so everything was there.