Topic: SOLVED_Calculate endpoint of line given initial point, azi, incli, distance

[nekonihonjin]

Hi guys,

Is there something like the Polar function, but for a point in 3D?

Given an initial point, distance, inclination and azimuth; calculate the point where a line would reach in that direction.
I was using the command _line -> initial pt ->  @dist<azim<inclination 
but I think it the lisp would be faster if I avoid using the command line and create the line with entmake


Found this in a topic here a the forum, but need some modification:

Code: [Select]

(defun polar3D-incl (pt dist inclination azimuth /)
  (mapcar '+
          pt
          (list (* dist (sin inclination) (cos azimuth))
                (* dist (sin inclination) (sin azimuth))
                (* dist (cos inclination))
          )
  )
)
the main problem is that the azimuth I have is the one used in topography/geology, which starts from 0° in the north (y-axis) and from there clockwise.
while autocad handles 0° to the east (a line to the positive x-axis), and increases the angle counterclockwise.
So my CVS file has an azimuth of 10°, for autocad it would be 80°, while an azimuth of 135° in my file would be 315° in autocad.

[Jim2018]

The easy way: change autocad to start count angles from north and clockwise!

[Marc'Antonio Alessi]

See ANGDIR and ANGBASE (System Variable)

[nekonihonjin]

See ANGDIR and ANGBASE (System Variable)

The easy way: change autocad to start count angles from north and clockwise!

It's a way to solve it, but it's meant for other people to use it, and I wouldn't like an error to occur while running the lisp and leave those variables changed to the user, but it will do for now

Thank you both

[VovKa]

isn't it just (- (/ pi 2) azimuth) ?

[57gmc]

See ANGDIR and ANGBASE (System Variable)

The easy way: change autocad to start count angles from north and clockwise!

It's a way to solve it, but it's meant for other people to use it, and I wouldn't like an error to occur while running the lisp and leave those variables changed to the user, but it will do for now

Thank you both

In addition to VovKa's suggestion and for future reference, it's good programming practice when you want to change a program's setting to create a new variable, store the current setting's value, and then make your change. At the end of your code, you can then reset the setting using the value stored in your variable. For example:

Code - Auto/Visual Lisp: [Select]

1. (setq "vAngDir" (getvar "ANGDIR"))
2. (setvar "ANGDIR" 90)
3. **do your thing
4. (setvar "ANGDIR" vAngDir)

**what language name do you use to format the code tag for lisp?

[nekonihonjin]

isn't it just (- (/ pi 2) azimuth) ?

since I'm a noob, had to do this:

Code: [Select]

(defun aztocad (ang /)
  (if (<= ang 90)
      (- 90 ang)
      (- 450 ang)
  )
)

(setq az (dtr (aztocad (getreal "\nEnter azimuth: "))))
but every piece of advice is for learning and is appreciated

now I just need to reduce this code with the help of mapcar:

Code: [Select]

(defun pol3d (pt az incl dist / )
(setq x (car pt))
(setq y (car (cdr pt)))
(setq z (car (cdr (cdr pt))))


(setq dx (* dist (* (cos az) (cos incl))))
(setq dy (* dist (* (sin az) (cos incl))))
(setq dz (* dist (sin incl)))

(list (+ x dx) (+ y dy) (+ z dz) )

)

[nekonihonjin]

See ANGDIR and ANGBASE (System Variable)

The easy way: change autocad to start count angles from north and clockwise!

It's a way to solve it, but it's meant for other people to use it, and I wouldn't like an error to occur while running the lisp and leave those variables changed to the user, but it will do for now

Thank you both

In addition to VovKa's suggestion and for future reference, it's good programming practice when you want to change a program's setting to create a new variable, store the current setting's value, and then make your change. At the end of your code, you can then reset the setting using the value stored in your variable. For example:

Code - Text: [Select]

1. (setq "vAngDir" (getvar "ANGDIR"))
2. (setvar "ANGDIR" 90)
3. **do your thing
4. (setvar "ANGDIR" vAngDir)

That's good advice GMC, I'm still not good with error handling, I prefer not to risk that something happens in the middle of the **do your thing, but before the (setvar "ANGDIR" vAngDir).
I see how advanced users convert a code that would take 5 lines, into 30 just to deal with whether the right object was selected, if the function has the necessary arguments or if there was missclick. between AND, NOT, IF, OR strings.
I still have a way to go to get there.

[efernal]

I have made something about this, long time ago...

https://www.gr-acad.com.br/pac/gr-pack-001.gif

(forgive me for my bad site, no time to improve it...)

[kirby]

Or just build all the cases of AngBase and AngDir into your solution.

And don't get hung up on shortening or 'mapcar lambda apply'-ifying your code for the sake of brevity or elegance, lots of comments and avoiding shortcut steps will help you debug and understand in  the future.

Code - Auto/Visual Lisp: [Select]

1. (defun C:TestPolar3D ( /
2.                         StartPoint k MyAzimuth MyInclination MyDist NextPoint Cancel
3.                         )
4. ; Test function for 'Polar3D'
5. ; KJM - Nov 2022
6.  
7. (setvar "CMDECHO" 0)
8.  
9. ; Report angle settings
10. (prompt "\n  AUnits = ")(princ (getvar "AUNITS"))
11. (prompt "  AngDir = ")(princ (getvar "ANGDIR"))
12. (prompt "  AngBase = ")(princ (getvar "ANGBASE"))
13.  
14. ; Starting point
15. (setq StartPoint (getpoint "\nSelect starting point..."))
16. (prompt "\n  Starting Point = ")(princ StartPoint)(princ)
17. (command ".POINT" StartPoint)
18.  
19. ; Loop for repeat entry of segments
20. (setq k 1)
21. (while k
22.  
23.         ; Get segment details
24.         (setq MyAzimuth (getreal "\nEnter azimuth angle in decimal degrees (0.0 = north, measured CW)..."))
25.         (setq MyInclination (getreal "\nEnter inclination angle from horizontal in decimal degrees..."))
26.         (setq MyDist (getreal "\nEnter length of 3D line segment..."))
27.  
28.         (if (and MyAzimuth MyInclination MyDist (not (zerop MyDist)))
29.           (progn
30.  
31.                 ; Get 3d point using custom function.  Assumes AngBase = 0.0 (east) and AngDir = 0 (CCW)
32.                 (setq NextPoint (Polar3D StartPoint MyAzimuth MyInclination MyDist 1 270.0 1))
33.                 (prompt "\n  Next Point = ")(princ NextPoint)(princ)
34.        
35.                 ; Draw the line segment
36.                 (command ".LINE" StartPoint NextPoint "")
37.  
38.                 ; Update starting point
39.                 (setq StartPoint NextPoint)
40.           )
41.         ) ; close if  
42.        
43.         ; continue to quit
44.         (setq Cancel (strcase (substr (getstring "\nE to end or any key to continue entering segments...") 1 1)))
45.         (if (= Cancel "E")
46.           (progn
47.                 (setq k nil)
48.                 (prompt "\nTerminating...")(princ)
49.           )    
50.         ) ; close if
51.  
52. ) ; close while loop
53.  
54. (princ)
55. )      
56.  
57.  
58.  
59.  
60.  
61. (defun Polar3D (BasePoint Azimuth Inclination Dist AngUnits ZeroAngle PosAngDir /
62.                         Verbose NewAzimuth DistH DistV NewPoint2D NewPoint3D
63.                         )
64. ; Compute a 3D point given a basepoint, azimuth, inclination, distance and angle measurement properties
65. ; KJM - Nov 2022
66. ; Input:
67. ;       BasePoint - (point) base point for measurment
68. ;       Azimuth - (real) Horizontal azimuth angle (degrees or radians)
69. ;       Inclination - (real) Vertical inclination / declination angle (degrees or radians)
70. ;       Dist - (real) 3D length of line segment
71. ;       AngUnits - (integer) code indicating units for angles 0=radians, 1=degrees, nil = 0 (radians).  Note: differs from sysvar 'AUNITS'
72. ;                       (Surveyors, etc -> use 1)
73. ;       ZeroAngle - (real) zero angle in degrees or radians.  nil = use AngBase
74. ;               if PosAngDir = 0 (CCW), east = 0.0, north = 90.0 / hpi, west = 180.0 / pi, and south = 270.0 / 1.5pi
75. ;               if PosAngDir = 1 (CW), east = 0.0, north = 270.0 / 1.5pi, west = 180.0 / pi, and south = 90.0 / hpi
76. ;                       (Surveyors, etc -> use 270.0)
77. ;       PosAngDir - (integer) code matching AngDir.  0 = counterclockwise, 1 = clockwise,  nil = use AngDir
78. ;                       (Surveyors, etc -> use 1)
79. ; Returns:
80. ;       point
81. ; Notes:
82. ;       does not consider UCS
83. ; Uses custom functions:
84. ;       dtr
85.  
86. (setq Verbose 1)        ; set to 0 to supress comments
87.  
88. ; defaults
89. (if (not AngUnits) (setq AngUnits 0))                   ; default is radians
90.  
91. (if (not ZeroAngle)
92.         (setq ZeroAngle (getvar "ANGBASE"))             ; default uses ANGBASE
93.         (if (eq AngUnits 1)
94.                 (setq ZeroAngle (dtr ZeroAngle))        ; Convert entered value to radians
95.         )      
96. )
97.  
98. (if (not PosAngDir) (setq PosAngDir (getvar "ANGDIR"))) ; default uses ANGDIR
99.  
100. ; Convert entered angles to radians
101. (if (eq AngUnits 1)
102.   (progn
103.         (setq Azimuth (dtr Azimuth))
104.         (setq Inclination (dtr Inclination))
105.   )
106. )
107.  
108. ; Convert azimuth angle to current
109. (if (eq PosAngDir 0)
110.         (setq NewAzimuth (- Azimuth ZeroAngle))                         ; Angles provided in CCW units (Acad standard / cartesian)
111.         (setq NewAzimuth (- (- (+ pi pi) ZeroAngle) Azimuth))           ; Angles provided in CW units
112. )      
113.  
114. (if (eq Verbose 1)
115.   (progn
116.         (prompt "\n  PosAngDir = ")(princ PosAngDir)
117.         (prompt "  ZeroAngle = ")(princ ZeroAngle)(prompt " (")(princ (rtd ZeroAngle))(prompt " d)")
118.         (prompt "  Azimuth = ")(princ Azimuth)(prompt " (")(princ (rtd Azimuth))(prompt " d)")
119.         (prompt "  NewAzimuth = ")(princ NewAzimuth)(prompt " (")(princ (rtd NewAzimuth))(prompt " d)")
120.         (princ)
121.   )
122. ) ; close if  
123.  
124. ; Get horizontal and vertica components of distance
125. (setq DistH (* Dist (cos Inclination)))
126. (setq DistV (* Dist (sin Inclination)))
127.  
128. ; Get point on plane, then add elevation
129. (setq NewPoint2D (polar BasePoint NewAzimuth DistH))                                            ; Note: polar always used CCW and east=0.0 cartesian angles
130. (setq NewPoint3D (list (car NewPoint2D) (cadr NewPoint2D) (+ (caddr NewPoint2D) DistV)))       
131.  
132. NewPoint3D
133. )
134.  
135.  
136. (defun RTD (A)
137. ; Radians to Degrees
138.         (* 180.0 (/ A pi))
139. )
140.  
141. (defun DTR (A)
142. ; Degrees to Radians
143.         (* pi (/ A 180.0))
144. )
145.  
146.  

[57gmc]

That's good advice GMC, I'm still not good with error handling, I prefer not to risk that something happens in the middle of the **do your thing, but before the (setvar "ANGDIR" vAngDir).
I see how advanced users convert a code that would take 5 lines, into 30 just to deal with whether the right object was selected, if the function has the necessary arguments or if there was missclick. between AND, NOT, IF, OR strings.
I still have a way to go to get there.

My name is Ed, GMC is my truck.
You bring up a good point. The trick to handling mishaps like that is to implement UNDO functionality. That way if something goes wrong, the user can just undo. To do this all you have to do is start an undo mark at the beginning and then create an undo mark at the end of your code. See this help topic.

[nekonihonjin]

That's good advice GMC, I'm still not good with error handling, I prefer not to risk that something happens in the middle of the **do your thing, but before the (setvar "ANGDIR" vAngDir).
I see how advanced users convert a code that would take 5 lines, into 30 just to deal with whether the right object was selected, if the function has the necessary arguments or if there was missclick. between AND, NOT, IF, OR strings.
I still have a way to go to get there.

My name is Ed, GMC is my truck.
You bring up a good point. The trick to handling mishaps like that is to implement UNDO functionality. That way if something goes wrong, the user can just undo. To do this all you have to do is start an undo mark at the beginning and then create an undo mark at the end of your code. See this help topic.

I had used the undomark when the lisp creates many objects and does many actions and if you want to go back is step by step delete one by one the objects, with the undomark you delete everything, but I did not know that it also returned the variables to the value they had before the mark. one more reason to use it.

Thanks again Ed,

Or just build all the cases of AngBase and AngDir into your solution.

And don't get hung up on shortening or 'mapcar lambda apply'-ifying your code for the sake of brevity or elegance, lots of comments and avoiding shortcut steps will help you debug and understand in  the future.

Code - Auto/Visual Lisp: [Select]

1. (defun C:TestPolar3D ( /
2.                         StartPoint k MyAzimuth MyInclination MyDist NextPoint Cancel
3.                         )
4. ; Test function for 'Polar3D'
5. ; KJM - Nov 2022
6.  
7. (setvar "CMDECHO" 0)
8.  
9. ; Report angle settings
10. (prompt "\n  AUnits = ")(princ (getvar "AUNITS"))
11. (prompt "  AngDir = ")(princ (getvar "ANGDIR"))
12. (prompt "  AngBase = ")(princ (getvar "ANGBASE"))
13.  
14. ; Starting point
15. (setq StartPoint (getpoint "\nSelect starting point..."))
16. (prompt "\n  Starting Point = ")(princ StartPoint)(princ)
17. (command ".POINT" StartPoint)
18.  
19. ; Loop for repeat entry of segments
20. (setq k 1)
21. (while k
22.  
23.         ; Get segment details
24.         (setq MyAzimuth (getreal "\nEnter azimuth angle in decimal degrees (0.0 = north, measured CW)..."))
25.         (setq MyInclination (getreal "\nEnter inclination angle from horizontal in decimal degrees..."))
26.         (setq MyDist (getreal "\nEnter length of 3D line segment..."))
27.  
28.         (if (and MyAzimuth MyInclination MyDist (not (zerop MyDist)))
29.           (progn
30.  
31.                 ; Get 3d point using custom function.  Assumes AngBase = 0.0 (east) and AngDir = 0 (CCW)
32.                 (setq NextPoint (Polar3D StartPoint MyAzimuth MyInclination MyDist 1 270.0 1))
33.                 (prompt "\n  Next Point = ")(princ NextPoint)(princ)
34.        
35.                 ; Draw the line segment
36.                 (command ".LINE" StartPoint NextPoint "")
37.  
38.                 ; Update starting point
39.                 (setq StartPoint NextPoint)
40.           )
41.         ) ; close if  
42.        
43.         ; continue to quit
44.         (setq Cancel (strcase (substr (getstring "\nE to end or any key to continue entering segments...") 1 1)))
45.         (if (= Cancel "E")
46.           (progn
47.                 (setq k nil)
48.                 (prompt "\nTerminating...")(princ)
49.           )    
50.         ) ; close if
51.  
52. ) ; close while loop
53.  
54. (princ)
55. )      
56.  
57.  
58.  
59.  
60.  
61. (defun Polar3D (BasePoint Azimuth Inclination Dist AngUnits ZeroAngle PosAngDir /
62.                         Verbose NewAzimuth DistH DistV NewPoint2D NewPoint3D
63.                         )
64. ; Compute a 3D point given a basepoint, azimuth, inclination, distance and angle measurement properties
65. ; KJM - Nov 2022
66. ; Input:
67. ;       BasePoint - (point) base point for measurment
68. ;       Azimuth - (real) Horizontal azimuth angle (degrees or radians)
69. ;       Inclination - (real) Vertical inclination / declination angle (degrees or radians)
70. ;       Dist - (real) 3D length of line segment
71. ;       AngUnits - (integer) code indicating units for angles 0=radians, 1=degrees, nil = 0 (radians).  Note: differs from sysvar 'AUNITS'
72. ;                       (Surveyors, etc -> use 1)
73. ;       ZeroAngle - (real) zero angle in degrees or radians.  nil = use AngBase
74. ;               if PosAngDir = 0 (CCW), east = 0.0, north = 90.0 / hpi, west = 180.0 / pi, and south = 270.0 / 1.5pi
75. ;               if PosAngDir = 1 (CW), east = 0.0, north = 270.0 / 1.5pi, west = 180.0 / pi, and south = 90.0 / hpi
76. ;                       (Surveyors, etc -> use 270.0)
77. ;       PosAngDir - (integer) code matching AngDir.  0 = counterclockwise, 1 = clockwise,  nil = use AngDir
78. ;                       (Surveyors, etc -> use 1)
79. ; Returns:
80. ;       point
81. ; Notes:
82. ;       does not consider UCS
83. ; Uses custom functions:
84. ;       dtr
85.  
86. (setq Verbose 1)        ; set to 0 to supress comments
87.  
88. ; defaults
89. (if (not AngUnits) (setq AngUnits 0))                   ; default is radians
90.  
91. (if (not ZeroAngle)
92.         (setq ZeroAngle (getvar "ANGBASE"))             ; default uses ANGBASE
93.         (if (eq AngUnits 1)
94.                 (setq ZeroAngle (dtr ZeroAngle))        ; Convert entered value to radians
95.         )      
96. )
97.  
98. (if (not PosAngDir) (setq PosAngDir (getvar "ANGDIR"))) ; default uses ANGDIR
99.  
100. ; Convert entered angles to radians
101. (if (eq AngUnits 1)
102.   (progn
103.         (setq Azimuth (dtr Azimuth))
104.         (setq Inclination (dtr Inclination))
105.   )
106. )
107.  
108. ; Convert azimuth angle to current
109. (if (eq PosAngDir 0)
110.         (setq NewAzimuth (- Azimuth ZeroAngle))                         ; Angles provided in CCW units (Acad standard / cartesian)
111.         (setq NewAzimuth (- (- (+ pi pi) ZeroAngle) Azimuth))           ; Angles provided in CW units
112. )      
113.  
114. (if (eq Verbose 1)
115.   (progn
116.         (prompt "\n  PosAngDir = ")(princ PosAngDir)
117.         (prompt "  ZeroAngle = ")(princ ZeroAngle)(prompt " (")(princ (rtd ZeroAngle))(prompt " d)")
118.         (prompt "  Azimuth = ")(princ Azimuth)(prompt " (")(princ (rtd Azimuth))(prompt " d)")
119.         (prompt "  NewAzimuth = ")(princ NewAzimuth)(prompt " (")(princ (rtd NewAzimuth))(prompt " d)")
120.         (princ)
121.   )
122. ) ; close if  
123.  
124. ; Get horizontal and vertica components of distance
125. (setq DistH (* Dist (cos Inclination)))
126. (setq DistV (* Dist (sin Inclination)))
127.  
128. ; Get point on plane, then add elevation
129. (setq NewPoint2D (polar BasePoint NewAzimuth DistH))                                            ; Note: polar always used CCW and east=0.0 cartesian angles
130. (setq NewPoint3D (list (car NewPoint2D) (cadr NewPoint2D) (+ (caddr NewPoint2D) DistV)))       
131.  
132. NewPoint3D
133. )
134.  
135.  
136. (defun RTD (A)
137. ; Radians to Degrees
138.         (* 180.0 (/ A pi))
139. )
140.  
141. (defun DTR (A)
142. ; Degrees to Radians
143.         (* pi (/ A 180.0))
144. )
145.  
146.  

Kirby, that's a good routine, and with all the comments and explanations it's gold for me, thanks man.

I have made something about this, long time ago...

https://www.gr-acad.com.br/pac/gr-pack-001.gif

(forgive me for my bad site, no time to improve it...)

that's pretty interesting, although my field is underground topography.

[kirby]

Comments are over the top, but better more than less to help understand flow.