Topic: Copy viewport and linked Objects

[CADwiesel]

Hello all,
I have copied a layout that contains a viewport (New Layout).
In the viewport there is an object in model space.
Now I copy this object to another place in the model space.

Her comes my question...
in my previously copied layout with the viewport (new layout), I want now to have the same view on the copied object as the 'old' viewport has on the 'old' object.

The whole thing should not work via commands or switching to the layouts or AF's, but programmatically via Lisp/Vlisp.
In my manual attempts I noticed that the only difference between the two AF's is the dxf 12 an 17. But these Points couldn't be changed by subst, and they are not in a vl-propetry list.
However, I don't know how to calculate this point, let alone what it should even mean.
So how can i point to the new view using (V)Lisp?

Thanks

[ribarm]

I suppose this is what you're looking for :

Code - Auto/Visual Lisp: [Select]

1. (defun c:copyobjs+matchlayout ( / cmd vp vx doc v vs vc ss bp ep vec )
2.  
3.   (vl-load-com)
4.  
5.   (defun *error* ( m )
6.     (if (= 8 (logand 8 (getvar (quote undoctl))))
7.       (if command-s
8.         (command-s "_.UNDO" "_E")
9.         (vl-cmdf "_.UNDO" "_E")
10.       )
11.     )
12.     (if cmd
13.       (setvar (quote cmdecho) cmd)
14.     )
15.     (if m
16.       (prompt m)
17.     )
18.     (princ)
19.   )
20.  
21.   (setq cmd (getvar (quote cmdecho)))
22.   (setvar (quote cmdecho) 0)
23.   (if (= 8 (logand 8 (getvar (quote undoctl))))
24.     (if command-s
25.       (command-s "_.UNDO" "_E")
26.       (vl-cmdf "_.UNDO" "_E")
27.     )
28.   )
29.   (if command-s
30.     (command-s "_.UNDO" "_M")
31.     (vl-cmdf "_.UNDO" "_M")
32.   )
33.   (if
34.     (and
35.       (setq vp (car (entsel "\nPick VIEWPORT in Layout...")))
36.       (= (cdr (assoc 0 (setq vx (entget vp)))) "VIEWPORT")
37.     )
38.     (progn
39.       (vla-put-activepviewport (setq doc (vla-get-document (setq v (vlax-ename->vla-object vp)))) v)
40.       (setq vs (getvar (quote viewsize)))
41.       (setq vc (getvar (quote viewctr)))
42.       (if
43.         (and
44.           (setq ss (ssget "_:L"))
45.           (setq bp (getpoint "\nPick or specify base point for copying : "))
46.         )
47.         (progn
48.           (vl-cmdf "_.COPY" ss "" "_non" bp)
49.           (while (< 0 (getvar (quote cmdactive)))
50.             (vl-cmdf "\\")
51.           )
52.           (setq ep (getvar (quote lastpoint)))
53.           (setq vec (mapcar (function -) ep bp))
54.           (vlax-invoke-method
55.             (vlax-get-acad-object)
56.             (quote zoomcenter)
57.             (vlax-3d-point (mapcar (function +) (trans vc 1 0) (trans vec 1 0 t)))
58.             vs
59.           )
60.           (vla-put-mspace doc 0)
61.         )
62.       )
63.       (prompt "\nFor UNDO - type \"UNDO\" - \"Back\" option...")
64.     )
65.   )
66.   (*error* nil)
67. )
68.  

M.R.

[kruuger]

Hello all,
I have copied a layout that contains a viewport (New Layout).
In the viewport there is an object in model space.
Now I copy this object to another place in the model space.

Her comes my question...
in my previously copied layout with the viewport (new layout), I want now to have the same view on the copied object as the 'old' viewport has on the 'old' object.

The whole thing should not work via commands or switching to the layouts or AF's, but programmatically via Lisp/Vlisp.
In my manual attempts I noticed that the only difference between the two AF's is the dxf 12 an 17. But these Points couldn't be changed by subst, and they are not in a vl-propetry list.
However, I don't know how to calculate this point, let alone what it should even mean.
So how can i point to the new view using (V)Lisp?

Thanks

it is somehow related to my topic and manipulation with ViewCenter/X and ViewCenter/Y.
https://www.theswamp.org/index.php?topic=57407.msg611689#msg611689
Simple adjustments easily done with these lines:

Code: [Select]

(defun c:TEST (/ vp)
  (setq vp (entsel "\nSelect viewport to set view to 1.0, 1.0 point: "))
  (setpropertyvalue (car vp) "ViewCenter/X" 1.0)
  (setpropertyvalue (car vp) "ViewCenter/Y" 1.0)
  (princ)
)This will set view to 1.0, 1.0 But there is more to consider, like ucs, twist, target and direction for viewport.

I don't think this will work how you describe. Viewport don't know what was copied.
Logic should be more like this:
1. Create new viewport
2. Jump to model and select vector, from which point to which point view needs to be updated (vector of your copied object).
3. Back to layout and update ViewCenter/X/Y of viewport
kruuger

[CADwiesel]

Thanks for sharing the code, ribarm!

that's true, kruuger...

Code: [Select]

(setq vec (mapcar '- p2 p1))
(setq vs (getvar 'viewsize))
(setq vc (getvar 'viewctr))
(setq nvpt (mapcar '+ vc vec))
(vlax-invoke-method (vlax-get-acad-object) 'zoomcenter (vlax-3d-point nvpt) vs)
This code is working fine for vports, which have a view from top or front to that copied object.
But if you want to have a view from eg, left or right side of an (3D)Object you need to calculate the vector on a different way.
don't know yet how 

[ribarm]

Thanks for sharing the code, ribarm!

that's true, kruuger...

Code: [Select]

(setq vec (mapcar '- p2 p1))
(setq vs (getvar 'viewsize))
(setq vc (getvar 'viewctr))
(setq nvpt (mapcar '+ vc vec))
(vlax-invoke-method (vlax-get-acad-object) 'zoomcenter (vlax-3d-point nvpt) vs)
This code is working fine for vports, which have a view from top or front to that copied object.
But if you want to have a view from eg, left or right side of an (3D)Object you need to calculate the vector on a different way.
don't know yet how 

@CADwiesel

I've looked at my post and see no real reasons for not working in any view/ucs formation in 3D... If you have problems ab this task from your point of view, I'd try to something fix like relation I suppose Visual Lisp function should operate by default - (vlax-3d-point) variant requirement of 3D WCS point list... So, experimental proposal : (vlax-3d-point (trans (mapcar (function +) (trans vc 1 0) (trans vec 1 0 t)) 0 1))