Topic: LISP to insert block and rename

[like_citrus]

Hi, is there a LISP anyone has to insert a block from another drawing and rename it with a suffix, to differentiate from the original block.
Something like Open, Select file, Paste, Rename with suffix.

[mhupp]

For importing blocks
http://www.lee-mac.com/steal.html

This is what i use to rename blocks.

Code - Auto/Visual Lisp: [Select]

1. ;;----------------------------------------------------------------------------;;
2. ;; Add Prefix/Suffix to Block Name
3. (defun C:BLKRENAME (/ blklst SS blk lst c a n)
4.   (vl-load-com)  
5.   (setq blklst (vla-get-Blocks (vla-get-activedocument (vlax-get-acad-object))))
6.   (prompt "\nSelect Block(s) or Enter To Rename All")
7.   (if (or (setq ss (ssget '((0 . "INSERT")))) (setq ss (ssget "_X" '((0 . "INSERT")))))
8.     (foreach e (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
9.       (setq blk (cdr (assoc 2 (entget e))))  ;Get Block Name
10.       (if (not (vl-position blk lst))        ;If Block Name is not in List Add
11.         (setq lst (cons blk lst))
12.       )
13.     )
14.   )
15.   (setq c 0)        ;Count
16.   (initget "Prefix Suffix")
17.   (setq rep
18.     (cond
19.       ((getkword "\n Specify your aim [Prefix/Suffix] :")) ( "Suffix")
20.     )
21.   )
22.   (cond
23.     ((= rep "Prefix")
24.       (setq prfx (getstring "\nEnter Prefix: "))
25.       (foreach n lst
26.         (vla-put-Name (vla-item blklst n) (strcat prfx n))
27.         (setq c (1+ c))
28.       )
29.     )
30.     ((= rep "Suffix")
31.       (setq sufx (getstring "\nEnter Suffix: "))
32.       (foreach n lst
33.         (vla-put-Name (vla-item blklst n) (strcat n sufx))
34.         (setq c (1+ c))
35.       )
36.     )
37.   )
38.   (prompt (strcat "\n" (rtos c 2 0) " Block(s) Renamed"))
39.   (princ)
40. )

[like_citrus]

Thanks for sending this. I'll look into it soon.

[ScottMC]

Check out this persons helpful library.
http://www.lee-mac.com/copyblock.html

[like_citrus]

Thanks, will do.