Topic: [challenge] A15 : list length

[ElpanovEvgeniy]

you need to calculate the length of any list, for example:

Code - Auto/Visual Lisp: [Select]

1. (list-length '(1 2 3))                                              ; >> 3
2. (list-length '(1 (2 (3))))                                          ; >> 3
3. (list-length '(1 (2 ((3 . 4) 5) 6) 7))                              ; >> 7
4. (list-length '(nil ("a" ((1 . 1) 2) 2) nil))                        ; >> 7
5. (list-length '(nil))                                                ; >> 1
6. (list-length nil)                                                   ; >> 0

[gile]

Code - Auto/Visual Lisp: [Select]

1. (defun list-length (l)
2.   (cond ((null l) 0)
3.         ((atom l) 1)
4.         ((atom (car l)) (1+ (list-length (cdr l))))
5.         (T (+ (list-length (car l)) (list-length (cdr l))))
6.   )
7. )

[JohnK]

Some of those conditions are just mean! I've made one quick attempt but I failed so I'll have to find some time in a bit to try again.

[ElpanovEvgeniy]

Some of those conditions are just mean! I've made one quick attempt but I failed so I'll have to find some time in a bit to try again.

You prepared well while I was away. This task massage the brain a bit.

Code - Auto/Visual Lisp: [Select]

1. (defun list-length (l)
2.   (cond ((null l) 0)
3.         ((atom l) 1)
4.         ((atom (car l)) (1+ (list-length (cdr l))))
5.         (T (+ (list-length (car l)) (list-length (cdr l))))
6.   )
7. )

Perfect solution! I wrote - word for word, while preparing this topic.

[kirby]

Couldn't wait for lunchtime...
(too much fun, also beats work)

Code - Auto/Visual Lisp: [Select]

1. (defun C:TestListLength ( / MyTestList MyItem CNT Ans)
2. ; Test routine for Challenge A15
3.  
4. (setq MyTestList (list
5.         '(1 2 3)                                ; >> 3
6.         '(1 (2 (3)))                            ; >> 3
7.         '(1 (2 ((3 . 4) 5) 6) 7)                ; >> 7
8.         '(nil ("a" ((1 . 1) 2) 2) nil)          ; >> 7
9.         '(nil)                                  ; >> 1
10.         nil                                     ; >> 0
11. ))
12.  
13. (setq CNT 0)
14. (repeat (length MyTestList)
15.         (setq MyItem (nth CNT MyTestList))
16.         (setq Ans (List-Length-Kirby MyItem))  
17.        
18.         (prompt "\nList = ")(princ MyItem)(prompt "  List Length = ")(princ Ans)
19.         (setq CNT (1+ CNT))
20. ) ; close repeat       
21. (princ)
22. )
23.  
24.  
25. (defun List-Length-Kirby (MyList / Verbose OutVal Count CNT NewCount MyItem)
26. ; Challenge A15 : List length
27. ; Input:
28. ;       MyList - a list
29. ; Returns:
30. ;       count of list items including items in sublists
31. ;       If MyList is not a list or nil, return 0
32.  
33. (setq Verbose 0)        ; =1 to show debug info
34. (setq OutVal 0)
35.  
36. (if (eq (type MyList) 'LIST)
37.   (progn
38.         (setq Count 0)
39.  
40.         (setq CNT 0)
41.         (repeat (length MyList)                         ; Uses 'Length' command, does this disqualify?  Could use recursion
42.                 (setq MyItem (nth CNT MyList))
43.        
44.                 (if (eq Verbose 1)
45.                   (progn
46.                         ; Show debug
47.                         (prompt "\n  CNT = ")(princ CNT)(prompt "  Item = ")(princ MyItem)(prompt "  Type = ")(princ (type MyItem))(princ)
48.                   )
49.                 )
50.        
51.                 (cond
52.                         ((dottedpairp MyItem) (setq NewCount 2))                                ; Custom function.  Thanks Giles!
53.                         ((eq (type MyItem) 'List) (setq NewCount (List-Length-Kirby MyItem)))   ; Yikes, recursion
54.                         ((eq MyItem nil) (setq NewCount 1))                                     ; nil counts as 1
55.                         ('T (setq NewCount 1))                                                  ; Not a list, count is 1
56.                 )      
57.        
58.        
59.                 (setq Count (+ Count NewCount))
60.                 (if (eq Verbose 1)
61.                   (progn
62.                         ; Show debug
63.                         (prompt "\n    NewCount = ")(princ NewCount)(prompt "  Total Count = ")(princ Count)(princ)
64.                   )
65.                 )
66.        
67.                 (setq CNT (1+ CNT))
68.         ) ; close repeat
69.         (setq OutVal Count)
70.   )
71. ) ; close if
72.  
73. OutVal
74. )
75.  
76.  
77. (defun dottedPairp (p)
78. ; Test for dotted pair, by Gile (Gilles Chanteau)
79. ; http://www.theswamp.org/index.php?topic=42940.msg482148#msg482148
80. ; Returns T is dotted pair and nil if not
81.         (and (listp p) (cdr p) (atom (cdr p)))
82. )
83.  
84.  

[bruno_vdh]

Hi,

Code - Auto/Visual Lisp: [Select]

1. (defun list-length (l)
2.   (cond ((null l) 0)
3.         ((atom l) 1)
4.         ((atom (car l)) (1+ (list-length (cdr l))))
5.         (T (+ (list-length (car l)) (list-length (cdr l))))
6.   )
7. )

Congratulations, Gile is the fastest, to console me I give the iterative version...

Code - Auto/Visual Lisp: [Select]

1. (defun list-length-vdh (l / m n)
2.   (setq n 0)
3.   (while (or l m)
4.     (cond ((null l) (setq l (car m) m (cdr m)))
5.           ((atom l) (setq n (1+ n) l (car m) m (cdr m)))
6.           ((atom (car l)) (setq n (1+ n) l (cdr l)))
7.           (T (setq m (cons (cdr l) m) l (car l)))
8.     )
9.   )
10.   n
11. )

[Marc'Antonio Alessi]

Code: [Select]

(defun LengthN_ALE (L / Fx c)
  (setq c 0)
  (defun Fx (L n)
    (foreach e L
      (setq n (1+ n))
      (or
        (atom e)
        (if (listp (cdr e))
          (setq n (1- (Fx e n)))
          (setq n (1+ n))
        )
      )
    )
    n
  )
  (Fx L c)
)more readable...

Code: [Select]

(defun LengthN_ALE2 (L / Fx c)
  (setq c 0)
  (defun Fx (L n)
    (foreach e L
      (cond
        ( (atom e)        (setq n (1+   n)) )
        ( (listp (cdr e)) (setq n (Fx e n)) )
        ( T               (setq n (+ 2  n)) )
      )
    )
    n
  )
  (Fx L c)
)

[ElpanovEvgeniy]

Code - Auto/Visual Lisp: [Select]

1. (defun f (l)
2.   (cond ((not l) 0)
3.         ((atom l) 1)
4.         ((+ (if (atom (car l)) 1 (f (car l))) (f (cdr l))))
5.   )
6. )

[bruno_vdh]

Code - Auto/Visual Lisp: [Select]

1. (defun f (l)
2.   (cond ((not l) 0)
3.         ((atom l) 1)
4.         ((+ (if (atom (car l)) 1 (f (car l))) (f (cdr l))))
5.   )
6. )

Congratulations, the factorization had escaped me.

[Marc'Antonio Alessi]

Mapcar version:

Code: [Select]

(defun LengthN_ALE3 (L / Fx c)
  (setq c 0)
  (defun Fx (L n)
    (mapcar
     '(lambda (e)
        (cond
          ( (atom e)        (setq n (1+   n)) )
          ( (listp (cdr e)) (setq n (Fx e n)) )
          ( T               (setq n (+ 2  n)) )
        )
      )
      L
    )
    n
  )
  (Fx L c)
)