Topic: Do I have to check if exists before I entmake a layer

[JohnK]

Given a layer maker function (entmake based) below do I technically have to check to see if the layer exists before I make it?

Code - Auto/Visual Lisp: [Select]

1. (defun makelayer ( name )
2.   (entmake (list
3.              '(0 . "LAYER")
4.              '(100 . "AcDbSymbolTableRecord")
5.              '(100 . "AcDbLayerTableRecord")
6.              (cons 2 name )                     ; layername
7.              (cons 70 0)                        ; vis stuff
8.              (cons 62 7)                        ; color number
9.              (cons 6 "Continuous")              ; linetype
10.              )
11.            )
12.   )
13. ;; Should I use:
14. (if (not (tblsearch "layer" "MyLayer"))
15.   (makelayer "MyLayer")
16.   )
17.  
18. ;; OR can I just try to make it?
19. (makelayer "MyLayer")
20.  

I know that if I were to use VisualLisp to create the layer, I would have to release the object if I tried to take a similar approach.

VL EXAMPLE:

Code - Auto/Visual Lisp: [Select]

1. ;;;===================================================================;
2. ;;; ax:MakeLayer                                                      ;
3. ;;;-------------------------------------------------------------------;
4. ;;; Create a new layer.                                               ;
5. ;;;                                                                   ;
6. ;;; Args: The new layer name                                          ;
7. ;;;                                                                   ;
8. ;;; History: Got this from AcadX.com                                  ;
9. ;;;                                                                   ;
10. ;;; NOTES: Returns the new layer object on successful creation,       ;
11. ;;;        an existing layer object if the layer already exists,      ;
12. ;;;        or NIL if the layer name cannot be created.                ;
13. ;;;                                                                   ;
14. ;;; Usage: (ax:MakeLayer "A-Layer")                                   ;
15. ;;;===================================================================;
16. (defun ax:MakeLayer (lName / oLayer)
17.   (if
18.     (vl-catch-all-error-p
19.       (setq oLayer
20.           (vl-catch-all-apply
21.             'vla-add
22.               (list
23.                 (vla-get-layers
24.                   (vla-get-activedocument
25.                     (vlax-get-acad-object)
26.                     )
27.                   )
28.                 lName
29.                 )
30.              )
31.           )
32.         )
33.     nil
34.     oLayer
35.     )
36.   )
37.  
38. ;; When making the layer with VL I need to release the object.
39. (progn
40.   (setq LayerName (ax:MakeLayer "MyLayer"))
41.   (if (not (vlax-object-released-p LayerName))
42.     (vlax-release-object LayerName)
43.    )
44. (princ)
45. )

[ronjonp]

You don't have to check although it also depends on if you want to return something like the layer ename. If the layer exists without the check, you get a nil return.

Code - Auto/Visual Lisp: [Select]

1. (defun makelayer (name)
2.   (cond ((tblobjname "layer" name))
3.         ((entmakex (list '(0 . "LAYER")
4.                          '(100 . "AcDbSymbolTableRecord")
5.                          '(100 . "AcDbLayerTableRecord")
6.                          (cons 2 name)  ; layername
7.                          (cons 70 0)    ; vis stuff
8.                          (cons 62 1)    ; color number
9.                          (cons 6 "Continuous") ; linetype
10.                    )
11.          )
12.         )
13.   )
14. )
15. (makelayer "test")

[Tharwat]

Hello,
I believe there is no need for vl-catch* functions since vla-add function won't return error if layer name was existed or absent.

So checking if object was released is also unnecessarily in this case since vla-add function will return vla-object all the time whilst this is enough to release it but its also not necessarily.

Code - Auto/Visual Lisp: [Select]

1. (defun Vla:MakeLayer (lName / oLayer)
2.   (setq oLayer
3.          (vla-add
4.            (vla-get-layers
5.              (vla-get-activedocument
6.                (vlax-get-acad-object)
7.              )
8.            )
9.            lName
10.          )
11.   )
12. )
13.  
14. (vlax-release-object (Vla:MakeLayer "MyLayer"))
15.  

Hope this helps.
 

[JohnK]

@ronjonp
Nice. Thank you!  No, I don't care to return the layer information at all, to be honest; this is going to be a quick "set the current layer situation". -i.e.

Code: [Select]

( (lambda ()
   ; ...
   (makelayer "test")
   (setvar 'CLAYER "test")
   ; ...
  )
) Thanks again!

@Tharwat
Nice. Didn't even think of that. But if I'm honest, I didn't write that function I just used it for this post. But that's good info; I'll have to add those notes to that function in my notes. Thanks.

[JohnK]

I found one of my old routines (starting over is hard; I have forgotten all of the little nuances).

Code - Auto/Visual Lisp: [Select]

1. (defun make-or-modify-layer (LNAM$ LCLR# LTYP$ LWGT# / #prog)
2.    ;;
3.    ;; Ex:
4.    ;; (make-or-modify-layer "Test-Layer" 1 "Continuous" 18)
5.    ;;  > create the layer
6.    ;; (make-or-modify-layer "Test-Layer" 1 "Continuous" 18)
7.    ;;  > would override the current layer def.
8.    ;;
9.    ;; By: John K
10.    ;;
11.   (if (null (tblsearch "layer" LNAM$))
12.     (set '#prog (lambda ( x ) (entmake x)))
13.     (set '#prog (lambda (x / ent y)
14.                   (setq ent (entget (tblobjname "LAYER" LNAM$)))
15.                   (foreach y x
16.                            (if (not (member (car y) '(0 100 2)))
17.                              (setq ent (subst y (assoc (car y) ent) ent))))
18.                   (entmod ent) )))
19.   (#prog
20.    (list
21.      (cons 0   "LAYER")
22.      (cons 100 "AcDbSymbolTableRecord")
23.      (cons 100 "AcDbLayerTableRecord")
24.      (cons 2    LNAM$)
25.      (cons 6    LTYP$)
26.      (cons 62   LCLR#)
27.      (cons 70   0)
28.      (cons 290  1)
29.      (cons 370  LWGT#)
30.      )
31.    )
32.  (princ)
33.  )

[Tharwat]

I found one of my old routines (starting over is hard; I have forgotten all of the little nuances).

Code - Auto/Visual Lisp: [Select]

1. (defun make-or-modify-layer (LNAM$ LCLR# LTYP$ LWGT# / #prog)

Good stuff John,
Just one issue is that the LineType must be loaded with your codes in prior if it is not available / loaded into your current running drawing.

[JohnK]

No it wont. Yes they do, but that is a good point to make for anyone that finds this code later. I have a separate routine for setup that does all that; this is one of those routines that quite likely never gets used (it is just passed through). I am working on a routine to draw some parametric fittings and I am going to use this to make sure that the centerlines I draw are on a no-plot layer.