Topic: Change the layer of attribute labels in a block

[nini007]

Hello the forum,

I need your help😀.
I have a "BIL" block on the "0-INFO-LOCAL" layer made up of three attributes on the "0" layer.

I would like by a lisp or any other command to change the layer of the labels of the attributes "0" in "0-INFO-LOCAL" or any other layer of my choice.
There is indeed the command "DEFDUCALQUE" the problem is that this only moves on DUCALQUE or DUBLOC.
I tried this macro:

Code: [Select]

^C^C-MODIFBLOCK;BIL;chprop;;_all;CA;0-INFO-LOCAL;_bclose; that doesn't work, I don't understand the error.
I also tried to change directly in my original block, re-import it and redefine all blocks unfortunately it doesn't work.

Does anyone have a tip or a lisp because I have plans with dozens of attributes to change.

PS: block in the attached file


thank you in advance for your help
Best regards

[kpblc]

I think the better way is to change attribute definitions to layer "0", all properties "ByBlock" and then _.attsync command

[nini007]

Hello,

Thank you for your message and your help.
Yes your proposal is fine unfortunately I have to do it on several dozen shots and do the manipulation on two different name blocks.
I would have liked if it is possible, maybe not, to automate the commands with a lisp, a macro or a script.

Best regard

[kpblc]

TO normalize block definition:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun norm-block-def (/ ent adoc vla_ent def)
3.   (if (= (type
4.            (setq ent (vl-catch-all-apply (function (lambda () (car (entsel "\nSelect block to normalize <Cancel> : "))))))
5.          ) ;_ end of type
6.          'ename
7.       ) ;_ end of =
8.     (if (and (= (cdr (assoc 0 (entget ent))) "INSERT") (= (cdr (assoc 66 (entget ent))) 1))
9.       (progn (vla-startundomark (setq adoc (vla-get-activedocument (vlax-get-acad-object))))
10.              (setq vla_ent (vlax-ename->vla-object ent)
11.                    def     (vla-item (vla-get-blocks adoc)
12.                                      (if (vlax-property-available-p vla_ent 'effectivename)
13.                                        (vla-get-effectivename vla_ent)
14.                                        (vla-get-name vla_ent)
15.                                      ) ;_ end of if
16.                            ) ;_ end of vla-item
17.              ) ;_ end of setq
18.              (vlax-for sub def
19.                (if (= (vla-get-objectname sub) "AcDbAttributeDefinition")
20.                  (progn (vla-put-layer sub "0")
21.                         (vla-put-color sub 0)
22.                         (vla-put-lineweight sub aclnwtbyblock)
23.                         (vla-put-linetype sub "ByBlock")
24.                  ) ;_ end of progn
25.                ) ;_ end of if
26.              ) ;_ end of vlax-for
27.              (vl-cmdf "_.attsync" "_name" (vla-get-name def))
28.              (vla-endundomark adoc)
29.       ) ;_ end of progn
30.       (princ "\nIt's not block with attributes!")
31.     ) ;_ end of if
32.     (princ "\nNothing selected")
33.   ) ;_ end of if
34.   (princ)
35. ) ;_ end of defun

[nini007]

Hello ,

I thank you for your message.
Pretty works for your code, it works great.
I make two small modifications in your code, I added "c:" and change the layer "0" by the layer "0-INFO-LOCAL"
One last little thing if possible, to be able to put the name of the block in the code so that it does not manually select it ?


Best regards

PS: no problem my English is not great either, more comfortable with French or Italian

[kpblc]

Seems like this.I didn't test this code

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun norm-block-def (/ ent adoc vla_ent def)
3.   (if (and (= (type
4.                 (setq ent (vl-catch-all-apply (function (lambda () (getstring "\nEnter block name <Cancel> : ")))))
5.               ) ;_ end of type
6.               'str
7.            ) ;_ end of =
8.            (tblobjname "block" ent)
9.       ) ;_ end of and
10.     (progn (vla-startundomark (setq adoc (vla-get-activedocument (vlax-get-acad-object))))
11.            (setq def (vla-item (vla-get-blocks adoc) ent))
12.            (vlax-for sub def
13.              (if (= (vla-get-objectname sub) "AcDbAttributeDefinition")
14.                (progn (vla-put-layer sub "0")
15.                       (vla-put-color sub 0)
16.                       (vla-put-lineweight sub aclnwtbyblock)
17.                       (vla-put-linetype sub "ByBlock")
18.                ) ;_ end of progn
19.              ) ;_ end of if
20.            ) ;_ end of vlax-for
21.            (vl-cmdf "_.attsync" "_name" (vla-get-name def))
22.            (vla-endundomark adoc)
23.     ) ;_ end of progn
24.     (princ "\nWrong block name!")
25.   ) ;_ end of if
26.   (princ)
27. ) ;_ end of defun

[nini007]

Hello ,

Thank you for your message and for your help .
Sorry, maybe I misspoke.

I would have wanted the name of the block to be in the code without having to select it and write its name.


Best regards

[nini007]

Hello ,
I have code which modifies the text of the attributes and I would like to modify some additional options.
For color and rotation it was easy, I found it to be "color and rotation" --> (setpropertyvalue e "Color" 5) and (setpropertyvalue e "rotation" 0)

I would like to know what the following options are called: --> Text style, width factor, slant angle, etc.

For the width factor I tried (setpropertyvalue e "width" 0.75), it doesn't work.


Thank you for your help.