Topic: Why isn't my osmode setting changing?

[bman]

Why isn't my osmode changing to intersection @ line 12? Do I have it in the wrong place? I want it to change prior to issuing the rotate command.

Code: [Select]

(defun c:cir (/ osmd rw bldg pad padendp dist)
  (setq osmd (getvar "osmode"))
  (setvar "cmdecho" 0)
  (setvar "osmode" 4)
  (setq rw (getpoint "\nSnap to Center of R/W Arc: "))
  (setvar "osmode" 1)
  (setq bldg (getpoint "\nSelect Endpoint of Bldg. Front: "))
  (setq dist (distance rw bldg))
  (command "circle" rw dist)
  (setq pad (entsel "\nSelect Bldg. Pad: "))
  (setq padendp (getpoint "\nSelect Pad Endpoint Near Lot Line: "))
  (setvar "osmode" 32)
  (command "rotate" pad "" rw "r" rw padendp)
  (setvar "osmode" osmd)
 )

[bman]

nevermind I just figured it out

[daron]

I don't know if you'd like it, but if you'd like a rubber-band line from pad point to padendp you could do this:

Code: [Select]

(setq padendp (getpoint (cadr pad) "\nSelect Pad Endpoint Near Lot Line: "))

[CAB]

How about some error checking.
If you abort or fail to pick it will quit and remove the circle.
You may need to tweak to suite you specific needs but it is a start.

Code: [Select]

(defun c:cir (/ *error* osmd rw bldg pad padendp dist)
  ;; error function & Routine Exit
  (defun *error* (msg)
    (if
      (not
        (member
          msg
          '("console break" "Function cancelled" "quit / exit abort" "")
        )
      )
       (princ (strcat "\nError: " msg))
    ) ; endif

    ;;reset all variables here
    (if cir (entdel cir))
    (setq cir nil)
    (setvar "osmode" osmd)
  )

 
  (setq osmd (getvar "osmode"))
  (setvar "cmdecho" 0)
  (setvar "osmode" 4)
  (if
    (and
      (setq rw (getpoint "\nSnap to Center of R/W Arc: "))
      (setvar "osmode" 1)
      (setq bldg (getpoint "\nSelect Endpoint of Bldg. Front: "))
      (setq dist (distance rw bldg))
      (setvar "osmode" 0)
      (not (command "circle" rw dist))
      (setq cir (entlast))
      (setvar "osmode" 1)
      (setq pad (entsel "\nSelect Bldg. Pad: "))
      (setq
        padendp (getpoint (cadr pad) "\nSelect Pad Endpoint Near Lot Line: ")
      )
      (setvar "osmode" 32)
      (not (command "rotate" pad "" rw "r" rw padendp pause))
    )
     (prompt "\n***  Command complete  ***")
     (progn
       (prompt "\n***  Command Aborted  ***")
       (if cir (entdel cir))
     )
  )
  (*error* "")
  (princ)
)
(prompt "\nCircle Loaded, Enter Cir to run.")
(princ)

[bman]

Sweet! Thanks for the tips.

[bman]

How do I get the rubber band effect  between these two points?

Code: [Select]

     (setq rw (getpoint "\nSnap to Center of R/W Arc: "))
      (setq bldg (getpoint  "\nSelect Endpoint of Bldg. Front: "))
I tried this but it didn't work:

Code: [Select]

     (setq rw (getpoint "\nSnap to Center of R/W Arc: "))
      (setq bldg (getpoint (cadr rw) "\nSelect Endpoint of Bldg. Front: "))

[David Hall]

i think you only need :

Code: [Select]

(setq rw (getpoint "\nSnap to Center of R/W Arc: "))
      (setq bldg (getpoint rw "\nSelect Endpoint of Bldg. Front: "))

[David Hall]

The cadr from Daron's example was because you used entsel to grab the building.  In this case, your are using an existing point your just defined, rw.

[bman]

Thanks for the tip!

[daron]

If you want a rectangular rubber-banding effect for any reason, just repleace the second points getpoint with getcorner.