Topic: Reducing the XYZ-points (of a DEM/DTM)

[Peter2]

I have a lot of XYZ points which are the base of a DEM/DTM. Sometimes there are too many points so they should be reduced.

So I'm seeking for ideas / algorithms / solutions relating ..

- what to reduce? Better the points from raw data then the points from DTM - but is it possible (without TIN)?
- how to reduce? There are some ways to calculate - min, max, average, max. differences in height or slope or ..
- existing solutions? The best way - "take solution XY from here, it's great and it's free"

(I know the "lastools", but the pricing is not that funny ..)

[d2010]

You must interpolate the Coordinate~s.
You re-mix all Coordinates with  Spline'Engine math.
 

[BIGAL]

There is no easy way other than like delete every 2nd point. But a Las file at 200MB is hard to handle, do you have access to Recap I think it does it.

[ribarm]

Although it's terribly slow, maybe it could help at least a bit... But I think that BCAD TIN command would create triangles faster then this routine would delete points... Still if you are confused with amount of points and you want to remove some, this untested snippet may work after all :

Code - Auto/Visual Lisp: [Select]

1. (defun c:reduceptsamount ( / mindist-eea-MR adoc ss n dd ti i pl l pp )
2.  
3.   (vl-load-com)
4.  
5.   (defun mindist-eea-MR ( l / f d q )
6.  
7.     (defun f ( p l / di )
8.       (while l
9.         (if (equal p (car l) (+ d 1e-8))
10.           (cond ( (= (setq di (distance p (car l))) d) (setq q (list p (car l))) )
11.                 ( (< di d)
12.                   (setq d di
13.                         q (list p (car l))
14.                   )
15.                 )
16.           )
17.         )
18.         (setq l (cdr l))
19.       )
20.     )
21.  
22.     (setq d (distance (car l) (cadr l)))
23.     (foreach a l
24.       (f a (cdr l))
25.       (setq l (cdr l))
26.     )
27.     q
28.   )
29.  
30.   (vla-startundomark (setq adoc (vla-get-activedocument (vlax-get-acad-object))))
31.   (prompt "\nSelect points on unlocked layer(s)...")
32.   (if (setq ss (ssget "_:L" '((0 . "POINT"))))
33.     (progn
34.       (initget 6)
35.       (setq n (getint "\nSpecify amount of points to be left after - for only fuzz distance checking use 0 <0> : "))
36.       (if (null n)
37.         (setq n 0)
38.       )
39.       (initget 7)
40.       (setq dd (getdist "\nPick or specify fuzz distance for reducing points : "))
41.       (setq ti (car (_vl-times)))
42.       (if (< (sslength ss) n)
43.         (progn
44.           (prompt "\nSelected number of points smaller then amount you specified... Quitting...")
45.           (exit)
46.         )
47.         (progn
48.           (repeat (setq i (sslength ss))
49.             (setq pl (cons (cdr (assoc 10 (entget (ssname ss (setq i (1- i)))))) pl))
50.           )
51.           (setq l t)
52.           (while (and l (> (length pl) n))
53.             (setq pp (mindist-eea-MR pl))
54.             (if (and pp (< (distance (car pp) (cadr pp)) dd))
55.               (setq pl (vl-remove (car pp) pl))
56.               (setq l nil)
57.             )
58.           )
59.           (repeat (setq i (sslength ss))
60.             (if (not (vl-position (cdr (assoc 10 (entget (ssname ss (setq i (1- i)))))) pl))
61.               (entdel (ssname ss i))
62.             )
63.           )
64.         )
65.       )
66.       (prompt "\nElapsed time : ") (princ (rtos (- (car (_vl-times)) ti) 2 20)) (prompt " milliseconds...")
67.     )
68.   )
69.   (vla-endundomark adoc)
70.   (princ)
71. )
72.  

[Peter2]

You must interpolate the Coordinate~s.
You re-mix all Coordinates with  Spline'Engine math.
 

What? Where? How?
Please add more details ..

There is no easy way other than like delete every 2nd point. But a Las file at 200MB is hard to handle, do you have access to Recap I think it does it.

It seem that "Recap Simple" is not available any more - on Autodesk page I found only "ReCap Pro Test". I have to look at older software packages - or do you know another original source?

Although it's terribly slow, maybe it could help at least a bit... But I think that BCAD TIN command would create triangles faster then this routine would delete points... Still if you are confused with amount of points and you want to remove some, this untested snippet may work after all :

- You mean Bricscad (Pro?) has a TIN command? Or do you mean another software?
- Which idea is behind your code? "Remove the nearest one" or something else?

[ribarm]

Although it's terribly slow, maybe it could help at least a bit... But I think that BCAD TIN command would create triangles faster then this routine would delete points... Still if you are confused with amount of points and you want to remove some, this untested snippet may work after all :

- You mean Bricscad (Pro?) has a TIN command? Or do you mean another software?
- Which idea is behind your code? "Remove the nearest one" or something else?

- Yes, BricsCAD V20 has TIN command...
- Idea behind my code is to remove point that forms shortest line between other point from point list... Now I've updated my code not to search for smallest lines and remove all until desired amount of point is reached, but to search also for length of line and if it falls smaller than specified fuzz distance then remove point - if smallest line length that follows is bigger than fuzz distance then routine terminates and if amount of points specified is less than remaining points in list routine terminates leaving points that can't form line smaller than fuzz, if otherwise specified amount of point is reached first and there still exist points with smaller line length, routine also terminates leaving specified amount of points not removed...

[d2010]

You re-mix all Coordinates with  Spline'Engine math.
 

What? Where? How?
You make  user account of the forum
https://youtu.be/7FFyfOkl5Oc?t=415

[ribarm]

Just slightly faster, but every improvement is welcome...

Code - Auto/Visual Lisp: [Select]

1. (defun c:reduceptsamount-new ( / mindist-eea-MR-mod adoc ss n dd ti i pl l pp )
2.  
3.   (vl-load-com)
4.  
5.   (defun mindist-eea-MR-mod ( l dd / f d q ll )
6.  
7.     (defun f ( p l dd / q )
8.       (vl-some (function (lambda ( x ) (if (equal p x dd) (if (< (distance p x) dd) (setq q (list p x)))))) l)
9.       q
10.     )
11.  
12.     (setq d (distance (car l) (cadr l)))
13.     (if (< d dd)
14.       (setq q (list (car l) (cadr l)))
15.       (while (and l (null (vl-some (function (lambda ( a ) (if (null ll) (setq ll l)) (setq q (f a (setq ll (cdr ll)) dd)))) l)))
16.         (setq l (cdr l) ll nil)
17.       )
18.     )
19.     q
20.   )
21.  
22.   (vla-startundomark (setq adoc (vla-get-activedocument (vlax-get-acad-object))))
23.   (prompt "\nSelect points on unlocked layer(s)...")
24.   (if (setq ss (ssget "_:L" '((0 . "POINT"))))
25.     (progn
26.       (initget 6)
27.       (setq n (getint "\nSpecify amount of points to be left after - for only fuzz distance checking use 0 <0> : "))
28.       (if (null n)
29.         (setq n 0)
30.       )
31.       (initget 7)
32.       (setq dd (getdist "\nPick or specify fuzz distance for reducing points : "))
33.       (setq ti (car (_vl-times)))
34.       (if (< (sslength ss) n)
35.         (progn
36.           (prompt "\nSelected number of points smaller then amount you specified... Quitting...")
37.           (exit)
38.         )
39.         (progn
40.           (repeat (setq i (sslength ss))
41.             (setq pl (cons (cdr (assoc 10 (entget (ssname ss (setq i (1- i)))))) pl))
42.           )
43.           (setq l t)
44.           (while (and l (> (length pl) n))
45.             (setq pp (mindist-eea-MR-mod pl dd))
46.             (if pp
47.               (setq pl (vl-remove (car pp) pl))
48.               (setq l nil)
49.             )
50.           )
51.           (repeat (setq i (sslength ss))
52.             (if (not (vl-position (cdr (assoc 10 (entget (ssname ss (setq i (1- i)))))) pl))
53.               (entdel (ssname ss i))
54.             )
55.           )
56.         )
57.       )
58.       (prompt "\nElapsed time : ") (princ (rtos (- (car (_vl-times)) ti) 2 20)) (prompt " milliseconds...")
59.     )
60.   )
61.   (vla-endundomark adoc)
62.   (princ)
63. )
64.  

HTH.

[Peter2]

- Yes, BricsCAD V20 has TIN command...

I see - but only for Platinum, Mech and BIM licences ...

For the tools:
Thanks to both, but at the moment I have to finish other stuffs. So it will take time to test and to answer.

[lamarn]

It runs in Pro as well. not in Lite (2D) and Shape (Free)
https://help.bricsys.com/hc/en-us/articles/360011845493-Tin

[Peter2]

It runs in Pro as well. not in Lite (2D) and Shape (Free)
https://help.bricsys.com/hc/en-us/articles/360011845493-Tin

Thanks, a colleague already started testing.