Topic: Last Command executed

[Marc'Antonio Alessi]

Maybe it's very simple but...   With this function:

Code: [Select]

(defun C:DclUtils ( / Dcl_Id WhtNxt)
  (setq Dcl_Id (load_dialog "DclUtils.dcl"))
  (if (or (minusp Dcl_Id) (not (new_dialog "DclUtils" Dcl_Id))) (exit))
  (action_tile "accept"    "(done_dialog 0)")
  (action_tile "Program01" "(done_dialog 1)")
  (action_tile "Program02" "(done_dialog 2)")
  (setq WhtNxt (start_dialog))
  (cond
    ( (= 1 WhtNxt)    (C:Foo1) )
    ( (= 2 WhtNxt)    (C:Foo2) )
  )
  (unload_dialog Dcl_Id)
  (princ)
)
after the execution of the C:Foo1 or C:Foo2 commands if I press enter I re-launch the command C:DclUtils. Is there a way that pressing enter will launch the last command executed (C:Foo1 or C:Foo2) within C:DclUtils?

[jtoverka]

Try this instead

Code - Auto/Visual Lisp: [Select]

1. (cond
2.   ( (= 1 WhtNxt) (Command-s "Foo1") ) ; ( (= 1 WhtNxt) (C:Foo1) )
3.   ( (= 2 WhtNxt) (Command-s "Foo2") ) ; ( (= 2 WhtNxt) (C:Foo2) )
4. )
5.  

[Marc'Antonio Alessi]

Try this instead

Code - Auto/Visual Lisp: [Select]

1. (cond
2.   ( (= 1 WhtNxt) (Command-s "Foo1") ) ; ( (= 1 WhtNxt) (C:Foo1) )
3.   ( (= 2 WhtNxt) (Command-s "Foo2") ) ; ( (= 2 WhtNxt) (C:Foo2) )
4. )
5.  

Sorry but do not works:

Code: [Select]

Command: (defun C:Foo1 ( ) (print "Hallo "))
C:FOO1

Command: (c:Foo1)
"Hallo " "Hallo "

Command: (command "Foo1")
Unknown command "FOO1".  Press F1 for help.
nil

Command: (command-s "Foo1")
; error: Unknown (command-s) failure.


[Lee Mac]

I would suggest using sendcommand, e.g.:

Code - Auto/Visual Lisp: [Select]

1. (defun c:dclutils ( / dch opt )
2.     (if
3.         (and
4.             (< 0 (setq dch (load_dialog "dclutils.dcl")))
5.             (new_dialog "dclutils" dch)
6.         )
7.         (progn
8.             (foreach key '("Program01" "Program02")
9.                 (action_tile key "(setq opt $key) (done_dialog 2)")
10.             )
11.             (cond
12.                 (   (/= 2 (start_dialog)))
13.                 (   (= "Program01" opt) (sendcommand "foo1\n"))
14.                 (   (= "Program02" opt) (sendcommand "foo2\n"))
15.             )
16.             (unload_dialog dch)
17.         )
18.         (princ "\nUnable to load & open dialog.")
19.     )
20.     (princ)
21. )
22.  
23. (defun sendcommand ( com )
24.     (eval (list 'defun 'sendcommand '( com ) (list 'vla-sendcommand (vla-get-activedocument (vlax-get-acad-object)) 'com)))
25.     (sendcommand com)
26. )
27.  
28. (vl-load-com) (princ)

[jtoverka]

Sorry but do not works:

I forgot to add

Code: [Select]

(vlax-add-cmd "FOO1" 'c:foo1)
(vlax-add-cmd "FOO2" 'c:foo2)

The command is invoked. However, I just tested it and that does not keep that as the last command unfortunately.

I would suggest using sendcommand

Fortunately, this command works well.

[Marc'Antonio Alessi]

I would suggest using sendcommand, e.g.: ….

GRANDE! It works In fact I thought that it would take a cunning. Thanks also to jtoverka. 

[Lee Mac]

You're welcome