Topic: Relative paths

[PKENEWELL]

Here is a new version of the batch import routine, using some ideas from kpblc and adding my own.

I added in a check at the beginning to make sure the user is in a new, blank drawing. I also made a choice at the end to close AutoCAD completely, or just close the open drawing.

Code - Auto/Visual Lisp: [Select]

1. (defun C:MicroStationToAutoCAD (/ acd doc *error* fil fn pth oecho odgn resp tx1 tx2 tx3 tx4 tx5)
2.    (vl-load-com)
3.    
4.    (defun *error* (msg)
5.       (if (not (wcmatch (strcase msg T) "*break*,*cancel*,*quit*,*exit*"))
6.          (princ (strcat "\nError: " msg "\n"))
7.          (princ "\nProgram Aborted.\n")
8.       )
9.       (setvar "cmdecho" oecho)
10.       (setvar "dgnimportmode" odgn)
11.       (setvar "nomutt" omut)
12.    )
13.    
14.    (setq fn "list.txt"
15.          tx1 (findfile fn)
16.          tx4 "Default"
17.          oecho (getvar "cmdecho")
18.          odgn (getvar "dgnimportmode")
19.          omut (getvar "nomutt")
20.          acd (vlax-get-acad-object)
21.          doc (vla-get-activedocument acd)
22.    )
23.    (setvar "cmdecho" 0)
24.    (setvar "dgnimportmode" 1)
25.    
26.    (if (not tx1)
27.       (princ "\nList file not found! Check the support paths. ")
28.       (progn
29.          (setq pth (vl-filename-directory tx1)
30.                tx2 (strcat pth "\\in\\")
31.                tx3 (strcat pth "\\out\\")
32.          )
33.          (initget "Yes No")
34.          (if (= (setq resp (getkword (strcat "\nFile List \"" fn "\" found. You should be in a new drawing to begin conversion. Proceed [Yes/No] <Yes>: "))) "No")
35.             (setq pth nil)
36.          )
37.       )
38.    )
39.    (if pth
40.       (progn
41.          (setq fil (open tx1 "r")
42.                tx5 (read-line fil)
43.          )
44.          (princ (strcat "\nConverting Files in " fn "> ="))
45.          (setvar "nomutt" 1)
46.          (while tx5
47.             (if (and (wcmatch (strcase tx5) "*`.DGN")
48.                      (findfile (strcat tx2 tx5))
49.                 )
50.                (progn
51.                   (setq tx5 (vl-filename-base tx5))
52.                   (command "._UNDO" "_MARK"
53.                            "._-DGNIMPORT" (strcat tx2 tx5) tx4
54.                   )
55.                   (while (= (logand (getvar "cmdactive") 1) 1) (command ""))
56.                   (vla-zoomall acd)
57.                   (vla-saveas doc (strcat tx3 tx5 ".dwg") ac2013_dwg)
58.                   (command "._UNDO" "_BACK")
59.                   (if (= (logand (getvar "cmdactive") 1) 1)(Alert "Something Did not process correctly in this drawing.\nVerify the command sequence."))
60.                   (princ "=")
61.                )
62.                (princ (strcat "\n file \"" tx5 "\" not found. File does not exist or filename is incorrect in \"" fn "\". Skipping file."))
63.             )
64.             (setq tx5 (read-line fil))
65.          )
66.          (close fil)
67.          (princ " Conversion Completed! ")
68.          (setvar "nomutt" omut)
69.          (initget "Yes No")
70.          (if (or (= (setq resp (getkword "\nDo you want to quit AutoCAD? [Yes/No] <Yes>: ")) "Yes")(= resp nil))
71.            (command "._QUIT" "_Y")
72.            (command "._CLOSE" "_y")
73.          )
74.       )
75.    )
76.    (setvar "cmdecho" oecho)
77.    (setvar "dgnimportmode" odgn)
78.    (princ)
79. )
80.  

EDIT: Added even more checks in the program, including testing if the file exists and is in fact a DGN file.
EDIT2: Changed response test to getkword from incorrect "" to correct nil.

[like_citrus]

Thanks very much PKENEWELL, this works now.
I think your previous shorter version works as well.

Long story, but the issue was with the text file, as I discovered having issues with the initial code, once working, then not. It took me a while to figure it out. I was using Excel to dump the drawing list data into the text file and AutoCAD didn't seem to accept it.
Initially I tried the latest code, that did not work, then after working out the issue, your code did work and the previous shorter version seems to work as well.

Sorry if this wasted your time, but it may be useful for someone else.

[PKENEWELL]

Thanks very much PKENEWELL, this works now.
I think your previous shorter version works as well.

Long story, but the issue was with the text file, as I discovered having issues with the initial code, once working, then not. It took me a while to figure it out. I was using Excel to dump the drawing list data into the text file and AutoCAD didn't seem to accept it.
Initially I tried the latest code, that did not work, then after working out the issue, your code did work and the previous shorter version seems to work as well.

Sorry if this wasted your time, but it may be useful for someone else.

No Problem Like_Citrus.  I enjoyed playing with the program and trying to make it better! There is still more that could be done, but I like how this works.

Examples of improvements:

• Store the name of the file list and the paths in the registry.
• Add a DCL configuration interface to change saved values for above.
• Create folders if they don't exist.
• Eliminate the file list and just use (vl-directory-files) to get the list of files to import.

I might look back on these and add features if I have time.

[PKENEWELL]

Here is an alternative I just wrote that does not rely on a text file to list the files. It just searches the import path for DGN files and processes them.

Upon the first time starting, the program will ask for the Import and Output folders using a "Browse for Folder" dialog (thanks to Lee Mac's function). Then it saves them to the registry for future use. You can afterward use the "Configure" option at the "...Proceed? " prompt to change them if needed.

Before proceeding with the conversion, Make sure the Import folder you selected has the DGN files in it that you want to convert, and that you are currently in a NEW BLANK drawing. Then select "Yes" to proceed with the conversion. This uses all the default options of the DGNIMPORT comment so just update the command string if you need different options.

Any other Guru's out there - feel free to critique and note any improvements or issues with the code. There are still improvements that could be made, such as a DCL interface for the "Configure" option and the first start up. Note: I don't normally deal with Microstation files at all, so someone with a better understanding of the DGNIMPORT options could chime in and give some advisement.

[like_citrus]

Thanks for your efforts again. The code seems quite sophisticated. It does work as described and seems to have been thought through.

[PKENEWELL]

Thanks Like_Citrus. It's better than the old method used before we had the benefit of Visual LISP added to AutoLISP. The original AutoLISP language did not have any methods for querying and manipulating files outside of the (findfile) and text file functions, nor had any ActiveX / COM access like it does now. There were some creative ways around those problems, but now it's much easier.