Topic: convert layers linetype

[PM]

Hi i have a big list of layers and want to change all linetype to continuous by default. Is any lisp code for this?

Thanks

[Dlanor]

Try this, it currently does all layers in the drawing but can be adapted inside the for loop to work with checking if the layer name is in a list.

Code - Auto/Visual Lisp: [Select]

1. (defun c:l2c ( / doc)
2.   (vl-load-com)
3.  
4.   (vlax-for lyr (vla-get-layers (setq doc (vla-get-activedocument (vlax-get-acad-object))))
5.     (vlax-put lyr 'linetype "CONTINUOUS")
6.   )
7.   (vlax-invoke doc 'regen acallviewports)
8.   (princ)
9. )
10.  

[PM]

thank you Dlanor

[Dlanor]

I've converted it to a function. Just pass the function a list of layer name and it will convert the linetypes of those layers to "CONTINUOUS" ie (rh:l2c layerlist)

Code - Auto/Visual Lisp: [Select]

1. (defun rh:l2c ( lst / doc)
2.   (setq lst (mapcar 'strcase lst))
3.   (vlax-for lyr (vla-get-layers (setq doc (vla-get-activedocument (vlax-get-acad-object))))
4.     (if (vl-position (strcase (vlax-get lyr 'name)) lst) (vlax-put lyr 'linetype "CONTINUOUS"))
5.   )
6.   (vlax-invoke doc 'regen acallviewports)
7. )
8.  

[JohnK]

Drive-by optimization.

Discussing your line #3.

Code - Auto/Visual Lisp: [Select]

1. (vlax-for lyr (vla-get-layers (setq doc (vla-get-activedocument (vlax-get-acad-object))))

which creates a variable ("doc") each iteration of the loop and is VERY inefficient and slow.

Consider the following small, but efficient, bit of code as a template for you to consider.

Code - Auto/Visual Lisp: [Select]

1. (setq *acadobject*
2.          (cond
3.            (*acadobject*)
4.            ((vlax-get-acad-object)))
5.       *activedocument*
6.          (cond
7.            (*activedocument*)
8.            ((vla-get-activedocument *acadobject*))) )

If you study this bit of code you can see the effency in it (hint: cond) which should lead you down the path of

Code - Auto/Visual Lisp: [Select]

1. (setq *acadobject*
2.          (cond
3.            (*acadobject*)
4.            ((vlax-get-acad-object)))
5.       *activedocument*
6.          (cond
7.            (*activedocument*)
8.            ((vla-get-activedocument *acadobject*)))
9.          $lay-col$
10.           (cond
11.             ($lay-col$)
12.             ((vla-get-layers *activedocument*))) )
13. ...
14.  
15. (vlax-for lyr $lay-col$ ...
16.  

EDIT: Fixed spelling error ("of").