Topic: Draw points at end points of lines

[Coder]

Hello everyone.

I have polylines and lines objects and I would like to add point objects at the end points of the connected lines and add points to the individual lines as in my screen shot.

I hope its possible to use ssget function because I have many line objects to select.

Thanks in advance.

[Dlanor]

A basic attempt. You'll have to set pdmode and pdsize. Points will be in current layer.

Code - Auto/Visual Lisp: [Select]

1. (defun c:lends (/ *error* c_doc c_spc ss cnt ent tlst pt plst)
2.  
3.   (defun *error* ( msg )
4.     (if (not (wcmatch (strcase msg) "*BREAK*,*CANCEL*,*EXIT*")) (princ (strcat "\nOops an Error : " msg " occurred")))
5.     (princ)
6.   );end_defun
7.  
8.   (setq c_doc (vla-get-activedocument (vlax-get-acad-object))
9.         c_spc (vlax-get-property c_doc (if (= 1 (getvar 'cvport)) 'paperspace 'modelspace))
10.         ss (ssget '((0 . "LINE,LWPOLYLINE,POLYLINE")))
11.   );end_setq
12.  
13.   (cond (ss
14.           (repeat (setq cnt (sslength ss))
15.             (setq ent (ssname ss (setq cnt (1- cnt)))
16.                   tlst (cons (vlax-curve-getstartpoint ent) tlst)
17.                   tlst (cons (vlax-curve-getendpoint ent) tlst)
18.             );end_setq
19.           );end_repeat
20.           (while (> (length tlst) 0)
21.             (setq pt (car tlst) tlst (cdr tlst))
22.             (if (not (vl-position pt tlst))
23.               (setq plst (cons pt plst))
24.               (setq tlst (vl-remove pt tlst))
25.             )
26.           );end_while
27.           (foreach pt plst (vlax-invoke c_spc 'addpoint pt))
28.         )
29.         (t (alert "Nothing Selected"))
30.   );end_cond
31.  
32.   (princ)
33. );end_defun
34.  

[Coder]

Beautiful,

Thank you so much for the codes and for the fast response.