Topic: LISP similar to "BLOCK" command

[like_citrus]

I wanted to achieve the following in LISP, relating to creating a block:
- Select elements.
- Choose a point (usually Endpoint for one of the lines).
- Once the point is selected, two things happen. (1) Elements are deleted (2) A block is inserted with anchor or base at previous chosen point. This is done all on one step, triggered by the chosen point.

The above is similar to the BLOCK command which converts elements into a block. But I prefer not to enter a name, just to use randomly generated name.

[Keith™]

Something I wrote maybe 20 years ago to turn a selection set into an anonymous block

Code - Auto/Visual Lisp: [Select]

1. (defun C:ANON()
2.  (SETQ SSST (SSGET))
3.  (SETQ ST (GETPOINT "\nInsertion point: "))
4.  (ENTMAKE
5.    (LIST
6.      (CONS 0 "BLOCK")
7.      (CONS 2 "*U")
8.      (CONS 10 ST)
9.      (CONS 70 67)
10.    )
11.  )
12.  (SETQ NDX 0)
13.  (REPEAT (SSLENGTH SSST)
14.   (ENTMAKE
15.     (CDR (ENTGET (SSNAME SSST NDX)))
16.   )
17.   (SETQ NDX (+ 1 NDX))
18.  )
19.  (SETQ BKN(entmake (list (cons 0 "ENDBLK"))))
20.  (SETQ EEE
21.    (LIST
22.      (CONS 0 "INSERT")
23.      (CONS 2 BKN)
24.      (CONS 6 (GETVAR "CELTYPE"))
25.      (CONS 8 (GETVAR "CLAYER"))
26.      (CONS 66 0)
27.      (CONS 10 ST)
28.      (CONS 41 1)
29.      (CONS 42 1)
30.      (CONS 43 1)
31.      (CONS 50 (GETANGLE ST "\nRotation angle: "))
32.      (CONS 71 0)
33.      (CONS 44 0)
34.      (CONS 45 0)
35.    )
36.   )
37.  (ENTMAKE EEE
38.  )
39.  (COMMAND "_.ERASE" SSST "")
40. )
41. (PRINC)

[like_citrus]

Keith, this is what I was looking for. Thanks for sending.
If I want to remove the rotation angle input, can I just delete the line shown below? Or remove other portions as well?

Code: [Select]

(CONS 50 (GETANGLE ST "\nRotation angle: "))

[Keith™]

I am not 100% sure you have to specify a rotation angle, but specifying 0 will not change the orientation of anything and it certainly won't hurt anything.

Change this:

Code - Auto/Visual Lisp: [Select]

1. (CONS 50 (GETANGLE ST "\nRotation angle: "))

to this:

Code - Auto/Visual Lisp: [Select]

1. (CONS 50 0.0)

[like_citrus]

This works as intended now. Thank you for the revised code.
I also wanted to know: Whilst looking at the block name "*U", a search suggests this is an anonymous block. How does this differ to blocks with names such as A$C0E547C8C? Do you know of a reference which could explain this?

[Keith™]

I do not know of any particular reference that will explain it, but I will explain what I understand:

An anonymous block is not named, at least not in the classical sense. It is numbered in the block table and that is pretty much it. So for what that gets you, you cannot insert a block reference using the insert command. You can however, entmake one. Whenever you create an anonymous block, it is guaranteed to have a unique name (they are incremented numerically in the block table *U1, *U2, *U3 etc.)

When you have a block that is named with a random name as you have shown in your example, a block reference may be inserted using the insert command, I suppose you could also entmake the reference is you wanted.

The name as you have shown is a name just like any other named block. There is nothing materially different except the name is probably meaningless. It can be inserted and manipulated just like any block reference because it IS just a regular block reference, only with a weird name.

The added benefit of anonymous blocks is that if you create a single anonymous block in two drawings, both indexed at 1 (i.e. *U1) and you insert both base drawings into a third drawing, the anonymous blocks remain unique. On the other hand, if you create a block in one drawing named A$C0E547C8C and you create a block in another drawing named A$C0E547C8C with different geometry, then try to insert both of those base drawings into a new third drawing, the block named A$C0E547C8C will be redefined such that both instances in the third drawing will have identical geometry.

In essence so far as AutoCAD is concerned, *U1 does not equal *U1 if they come from different drawings, but A$C0E547C8C does equal A$C0E547C8C when from different drawings IF you try to put them both in the same drawing.

I hope this makes sense.

[ronjonp]

A$* blocks are generated using the paste as block option from the clipboard: CNTRL+SHIFT+V or PASTEBLOCK command.

[like_citrus]

@Keith, thanks for the detailed explanation, it certainly helps.
Unfortunately it seems that the anonymous block can't be edited using the "Edit Block In-place" function.
Is there a way to turn the elements into a block of "A$*" type. I tried replacing "*U" with "A$*" in the code but noting happened.

Text in bottom window: Invalid block name.; error: bad DXF group: (2)

[BIGAL]

Why not give it  a proper name like random1 random2 etc can pretty easy check if exists already and x=x+1

[like_citrus]

Why not give it  a proper name like random1 random2 etc

How could this be done?

[ronjonp]

Why not give it  a proper name like random1 random2 etc

How could this be done?

Try this quick mod:

Code - Auto/Visual Lisp: [Select]

1. (defun c:anon (/ bkn eee i ndx nm ssst st)
2.   (if (and (setq ssst (ssget)) (setq st (getpoint "\nInsertion point: ")))
3.     ;; RJP modified to generate a "Block-#" name
4.     (progn (setq i -1)
5.            (setq ndx 0)
6.            (while (tblobjname "block" (setq nm (strcat "Block-" (itoa (setq i (1+ i)))))))
7.            (entmake (list '(0 . "BLOCK")
8.                           '(100 . "AcDbEntity")
9.                           '(67 . 0)
10.                           '(8 . "0")
11.                           '(100 . "AcDbBlockReference")
12.                           (cons 2 nm)
13.                           (cons 10 st)
14.                           '(70 . 0)
15.                     )
16.            )
17.            (repeat (sslength ssst)
18.              (entmake (cdr (entget (ssname ssst ndx))))
19.              (entdel (ssname ssst ndx))
20.              (setq ndx (+ 1 ndx))
21.            )
22.            (entmake '((0 . "ENDBLK") (100 . "AcDbBlockEnd") (8 . "0")))
23.            (entmake (list (cons 0 "INSERT")
24.                           (cons 2 nm)
25.                           (cons 6 (getvar "CELTYPE"))
26.                           (cons 8 (getvar "CLAYER"))
27.                           (cons 66 0)
28.                           (cons 10 st)
29.                           (cons 41 1)
30.                           (cons 42 1)
31.                           (cons 43 1)
32.                           (cons 50 0)
33.                           (cons 71 0)
34.                           (cons 44 0)
35.                           (cons 45 0)
36.                     )
37.            )
38.     )
39.   )
40.   (princ)
41. )

[roy_043]

Note that with the proposed method, entget-entmake cloning, all associative relations between the selected objects will be lost.

[like_citrus]

@ronjop, thanks very much this works very well. It could not delete the original elements for me, so replaced one of your lines with @Keith code, see below. Now it's all good.
@roy_043, what do you mean by "all associative relations between the selected objects will be lost"? Is it any different than if I was to Copy and Paste as Block as done normally, giving an $A* block?

This is more complicated than I originally thought.

Code: [Select]

; (mapcar 'entdel ssst)
; replaced with

(ENTMAKE EEE
)
(COMMAND "_.ERASE" SSST "")
)

[ronjonp]

@ronjop, thanks very much this works very well. It could not delete the original elements for me, so replaced one of your lines with @Keith code, see below. Now it's all good.
@roy_043, what do you mean by "all associative relations between the selected objects will be lost"? Is it any different than if I was to Copy and Paste as Block as done normally, giving an $A* block?

This is more complicated than I originally thought.

Code: [Select]

; (mapcar 'entdel ssst)
; replaced with

(ENTMAKE EEE
)
(COMMAND "_.ERASE" SSST "")
)

Updated the code above to remove the items selected.

[like_citrus]

Thank you again.