Topic: Delete Unlocked Layers

[rodolfo_palma]

Hello everyone!

I need help with an autolisp code that delete all unlocked layers presents in the drawing.

With normal commands I probably could do this with LAYDEL, but i need include this inside another code, so this need to be done in autolisp.

Any ideas?

Thanks!
R.Palma

[JohnK]

My VisualLisp contribution.

Code - Auto/Visual Lisp: [Select]

1. (defun My-Unlocked-Layer-Delete ( / *acadobject* *activedocument* )
2.   (vl-load-com)
3.   (setq *acadobject*
4.          (cond
5.            (*acadobject*)
6.            ((vlax-get-acad-object)))
7.       *activedocument*
8.          (cond
9.            (*activedocument*)
10.            ((vla-get-activedocument *acadobject*))) )
11.   (vlax-for item (vla-get-layers *activedocument*)
12.     ;; If layer is not locked, and not layer 0.
13.     (if (and (eq (vla-get-lock item) :vlax-false)
14.              (not (eq (vla-get-name item) "0")))
15.       (vlax-invoke item 'Delete))) )

[rodolfo_palma]

Thanks for the help John Kaul.

But when I'm trying to run it, this error appears:

; error: AutoCAD.Application: Object is referenced by other object(s)

[JohnK]

Thanks for the help John Kaul.

But when I'm trying to run it, this error appears:

; error: AutoCAD.Application: Object is referenced by other object(s)

That would be caused because the current layer is unlocked (and thus being deleted). The following adds the current layer check as part of the conditional check (and doesn't try to delete it, even if it is unlocked). You should be checking and changing the current layer in your code -i.e. having that check part of a utilitiy routine like this is not the best practice.

The code is still strictly VisualLisp.

Code - Auto/Visual Lisp: [Select]

1. (defun My-Unlocked-Layer-Delete ( / *acadobject* *activedocument* )
2.   (vl-load-com)
3.   (setq *acadobject*
4.          (cond
5.            (*acadobject*)
6.            ((vlax-get-acad-object)))
7.       *activedocument*
8.          (cond
9.            (*activedocument*)
10.            ((vla-get-activedocument *acadobject*))) )
11.   (vlax-for item (vla-get-layers *activedocument*)
12.     ;; If layer is not locked, current, and not layer 0.
13.     (if (and (eq (vla-get-lock item) :vlax-false)
14.              (not (eq (vla-get-name item) "0"))
15.              (not
16.                 (eq
17.                     (vla-get-name (vlax-get-property *activedocument* 'ActiveLayer))
18.                     (vla-get-name item))))
19.         (vlax-invoke item 'Delete))) )
20.  

[Lee Mac]

A layer may only be deleted if it is not referenced by any entities (graphical or non-graphical), as such, you'll need to iterate over the drawing database (including entities nested within all block definitions and also AcDbBlockBegin entities), and either reassign or delete those entities which reference the layer, before deleting the layer definition itself.

[JohnK]

We in the United States of America invented the English language; you guys from across the pond should think about adopting it as well because after reading your post I wish you were using English when you constructed your reply.

...that sounds like a lot of work! The reassigning would be a task of another sub routine--I hope, because I wouldn't know how to do that (I don't even *open* AutoCAD much these days).

[ronjonp]

Here's a quick one ( slow code ) that tries to delete everything then purges the drawing to remove the layers.

Code - Auto/Visual Lisp: [Select]

1. (defun c:foo (/ d er i n)
2.   ;; RJP » 2020-08-05
3.   (mapcar 'set '(er n) '(0 0))
4.   (setq i (vla-get-count (vla-get-layers (setq d (vla-get-activedocument (vlax-get-acad-object))))))
5.   (vlax-for b1 (vla-get-blocks d)
6.     ;; If it's not an xref
7.     (if (= 0 (vlax-get b1 'isxref))
8.       (vlax-for b2 b1
9.         (if (vl-catch-all-error-p (vl-catch-all-apply 'vla-delete (list b2)))
10.           (setq er (1+ er))
11.           (setq n (1+ n))
12.         )
13.       )
14.     )
15.   )
16.   (repeat 3 (vla-purgeall d))
17.   (alert (strcat (itoa er)
18.                  " errors deleting objects...\n"
19.                  (itoa n)
20.                  " objects were deleted...\n"
21.                  (itoa (- i (vla-get-count (vla-get-layers d))))
22.                  " layers purged..."
23.          )
24.   )
25.   (princ)
26. )

[rodolfo_palma]

I apologize for english mistakes.. I'm trying my best here, hehe.

Thanks for all the replies, I could learn a lot from them.

I discover my mistakes... I was trying to run this code in a Civil3d template. The layers are impossible to delete, since they are referenced by non-graphical entities (Civil3d styles).
Lee Mac was absolutely right! hehe.

My intention with this code is to keep in the drawing only the layers that are in use by graphical entities.
My knowledge is very limited, but what I got so far is this:

Code - Auto/Visual Lisp: [Select]

1. (defun c:lapurge ( / oldecho obj i la la_lst e acadobj activedoc lay la_name)
2.  
3.         (vl-load-com)
4.         (setvar "clayer" "0")
5.         (setq oldecho (getvar "cmdecho"))
6.         (setvar "cmdecho" 0)
7.         (setvar "nomutt" 1)
8.         (command "._UNDO" "_Begin")
9.  
10. ;******************************************************************************
11. ; Lock Layers in use
12.  
13.         (setq obj (ssget "X"))
14.         (repeat (setq i (sslength obj))
15.                 (if (not (member (setq la (cdr (assoc 8 (entget (ssname obj (setq i (1- i))))))) la_lst))
16.                         (progn
17.                                 (setq   e (entget (tblobjname "LAYER" la))
18.                                                 la_lst (cons la la_lst))
19.                                 (entmod (subst (cons 70 4) (assoc 70 e) e))
20.                         )
21.                 )
22.         )
23.  
24. ;******************************************************************************
25. ; Delete layers not used
26.  
27.         (vlax-for lay (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object)))
28.                 (if     (and (eq (vla-get-lock lay) :vlax-false)
29.             (not (eq (vla-get-name lay) "0")))
30.                                 (progn
31.                                         (setq la_name (vlax-get-property lay 'Name))
32.                                         (command "._laydel" "N" la_name "" "Y")
33.                                 )
34.                 )
35.         )
36.                        
37. ;******************************************************************************
38. ; Unlock all layers and restore variables
39.  
40.         (command "._layer" "U" "*" "")
41.         (command "._UNDO" "_End")
42.         (setvar "cmdecho" oldecho)
43.         (setvar "nomutt" 0)
44.         (princ)
45.        
46. )
47.