Topic: LISP command broke in 2020....

[cyclops]

This demolayer.lsp works in 2018, no go in 2020, can someone help?

The error is -->  ;error: no function definition: VLAX-ENAME->VLA-OBJECT

Thanks for the help in advance.
Cyclops
    ||
    ||
   \  /
    V

Code - Auto/Visual Lisp: [Select]

1. ;;DemoLayer.LSP - Changes picked objects to layer with -DEMO suffix.
2. ;;Bill Kramer 2008
3. ;;
4. ;; Visual LISP Example utility to change objects selected. This example
5. ;; changes the layer name of the selected objects (appends "-DEMO") and
6. ;; duplicates the layer definition if needed for the new layer.
7. ;;
8. (vl-load-com)
9. (defun C:DemoLayer ( / SS CNT LYR vEN EN LyrNew LyrTab oLayers)
10.   (prompt "\nChange selected objects layer by appending -DEMO to name.")
11.   (setq SS (ssget))
12.   (if (and SS (> (sslength SS) 0))
13.     (progn
14.       (setq oLayers ;;get layer table link
15.              (vla-get-layers
16.                (vla-get-activedocument
17.                  (vlax-get-acad-object))))
18.       ;;
19.       ;;Got the objects, now stream through them
20.       (repeat (setq CNT (sslength SS))
21.         ;;
22.         (setq En (ssname SS (setq CNT (1- CNT))) ;;Entity name from set
23.               vEN (vlax-ename->vla-object En) ;;entity object reference
24.               LYR (vla-get-layer vEN);;get the layer name
25.               )
26.         ;;check to see if -DEMO already there
27.         (if (not (wcmatch LYR "*-DEMO")) ;;layer name already -DEMO type?
28.           (progn
29.             ;;
30.             ;; No, first check to see if the layer with -DEMO already exists
31.             ;;
32.             (if (not (tblsearch "LAYER" (strcat LYR "-DEMO")))
33.               (progn ;;add the new layer
34.                 (setq LyrNew (vla-add oLayers (strcat LYR "-DEMO"))
35.                       LyrTab (vla-item oLayers LYR)
36.                       )
37.                 ;; Clone the properties
38.                 (vla-put-linetype LyrNew (vla-get-linetype LyrTab))
39.                 (vla-put-truecolor LyrNew (vla-get-truecolor LyrTab))
40.                 (vla-put-freeze LyrNew (vla-get-freeze LyrTab))
41.                 (vla-put-layeron LyrNew (vla-get-layeron LyrTab))
42.                 (vla-put-lineweight LyrNew (vla-get-lineweight LyrTab))
43.                 (vla-put-lock LyrNew (vla-get-lock LyrTab))
44.                 (vla-put-material LyrNew (vla-get-material LyrTab))
45.                 ;(vla-put-plotstylename LyrNew (vla-get-plotstylename LyrTab))   ;<-----------
46.                 )) ;;end layer add
47.             ;;
48.             ;; Update the layer name of the object
49.             (vla-put-layer vEN (strcat LYR "-DEMO"))
50.             )) ;;end if -DEMO already there
51.         ) ;;end REPEAT
52.       )) ;;end SS test
53.   (princ)
54.   )
55.  

[kpblc]

Try to add (vl-load-com) to your code.
Ooops. I didn't check the code. You done it.
I got this error in case on broken install of ACAD. Maybe full reinstall could help you?

[ronjonp]

I had the same issue on the first install of 2021 .. I removed it, then reinstalled and did not migrate profiles.

[Dlanor]

https://knowledge.autodesk.com/support/autocad/troubleshooting/caas/sfdcarticles/sfdcarticles/Error-no-function-definition-VLAX-ENAME-VLA-OBJECT-when-running-LISP-base-function-in-AutoCAD.html

[d2010]

If you pay me, then I can translate your-program, into 100%autolisp(for AutoCAD ver2004+ or better),
 no more (vl-load-com). If idyes then you send PM at       MessageBox(Wnd: Integer; Text: PChar)

RE: The error is -->  ;error: no function definition: VLAX-ENAME->VLA-OBJECT