Topic: How to truly close Excel

[CincyJeff]

If I open, read/write, quit Excel, it stays open under Processes in Task Manager. Is there any way to actually close the application. The following code leaves Excel open. I don't like the fact that the process remains open.

Code: [Select]

(defun XCELTEST (/ *excelapp* file actwb )
  (setq file "C:\\Temp\\TEST.xlsm")
  (setq *excelapp* (vlax-get-or-create-object "Excel.Application"))
  (vlax-for WorkBook (vlax-get-property *excelapp* "WorkBooks")
    (if (= (vlax-get-property WorkBook "Name") file)
      (setq actwb (vlax-invoke-method WorkBook "Activate"))
    ) ;_ end of if
  ) ;_ end of vlax-for
  (if (not actwb)
    (setq actwb
           (vlax-invoke-method
             (vlax-get-property *excelapp* 'WorkBooks)
             'open
             file
           ) ;_ end of vlax-invoke-method
    ) ;_ end of setq
  ) ;_ end of if
  (vlax-invoke-method actwb 'close)
  (vlax-invoke-method *excelapp* 'quit)
  (vlax-release-object *excelapp*)
) ;_ end of defun

[VovKa]

(gc)

[CincyJeff]

VovKa,
That works for the simple program included in the original post, but if I run a larger routine that closes Excel the same way, including (gc) after the release object call, which was already being called, Excel still stays open in Task Manager. Any ideas?

[VovKa]

(gc)(gc) ?

[kpblc]

I think there is not the best way to use vlax-get-or-create-object: in this case you can try to use existing Excel application. Change it to vlax-create-object.
And about (gc): try to use somthing like

Code - Auto/Visual Lisp: [Select]

1. (defun f1()
2. (f2)
3. (gc)
4. )
5.  
6. (defun f2()
7. ;; Excel operations
8. )

[CincyJeff]

kpblc,
I tried vlax-create-object instead of get-or-create with the same result, even with the extra (gc) after the function call. For me, Excel remains open.
I also tried the double (gc) and not running the macro in case it has an effect, no difference.
I'll do some further testing to see if saving the file makes a difference.


Windows 10
Office 365
AutoCAD 2020 1.2

[kpblc]

I think Windows won't close any application at time you request it. This task will take some time. Perhaps you have to take some time to completely close external application.

[MP]

You can kill stubborn windows processes instantly but you have to use this ability with good judgement. Additionally, the sample code I penned in that ^ thread is wild-carded - it will kill all processes matching the passed process name spec - whereas it’s more likely you aim to kill a specific process (pid) - i.e. an excel instance you spawned - rather than all excel instances. Also noting excel supports mdi so it’s possible more than 1 excel workbook is open and may need to be saved or abandoned (if dirty). It’s not difficult to determine all this but you’ll have to do a bit of research to determine same as I’m without the benefit of free time to do it for you. Anyways ... cheers.

[57gmc]

Excel has always had the problem that it doesn't properly release memory for objects it uses. You have to explicitly release the memory by setting your variable to nil. I don't think (gc) is working because it only releases "unused" memory. In the case of Excel, your variables are still "in use" even though they have gone out of scope.  I haven't done this in lisp, but in COM/VBA, you have to release memory of your variables in reverse order in which you created them. For example, you can't set a workbook object to nil before setting a sheet object to nil because the workbook object holds a pointer to the sheet object. Typically, you would set to nil in the following order 1. sheet object, 2. workbook object, 3. application object.

[CincyJeff]

kpblc,
I've let it go for minutes and it still doesn't close.

57gmc,
I was already setting my pointers to nil, just not in the sample program I posted, and it still doesn't close.

All,
Instead of putting the close routine under a separate defun, I placed it in the main program and it now closes Excel as it should. It's not as clean as I would like from my perspective, but I'd rather have Excel close completely than have a clean program. Thanks for all of the input.

[Stefan]

This is what I use.
I think the catch is to also close the Workbooks before attempting to quit excel app.

Code - Auto/Visual Lisp: [Select]

1. (if
2.   (and
3.     (setq file (getfiled "Open excel file" (getvar 'dwgprefix) "xlsx;xls" 2))
4.     (cond
5.       ((setq excel (vlax-get-object "Excel.Application")))
6.       ((setq excel (vlax-create-object "Excel.Application")) (setq new_app T))
7.     )
8.  
9.     (setq wbs (vlax-get-property  excel "workbooks"))
10.  
11.     (cond
12.      ((progn
13.         (setq wb (vl-catch-all-apply
14.                    'vlax-get-property
15.                      (list
16.                       wbs
17.                       "item"
18.                       (strcat (vl-filename-base file) (vl-filename-extension file))
19.                      )
20.                   )
21.        )
22.        (if (vl-catch-all-error-p wb)
23.          (setq wb nil)
24.          wb
25.        )
26.       )
27.      )
28.      ((setq wb (vlax-invoke wbs 'open file)) (setq new_file T))
29.     )
30.   )
31.   (progn
32.    ...do your stuff...
33.   )
34. )
35.  
36. (if
37.   new_app
38.   (progn
39.     (vlax-invoke-method wb   "close")
40.     (vlax-invoke-method wbs  "close")
41.     (vlax-invoke-method excel "quit")
42.   )
43.   (if
44.     new_file
45.     (vlax-invoke-method wb  "close")
46.   )
47. )
48.  
49. (mapcar '(lambda (x) (vl-catch-all-apply 'vlax-release-object (list x))) (list excel wbs wb))