Author Topic: How to: hatch multiple selected items individually  (Read 3513 times)

0 Members and 1 Guest are viewing this topic.

ScottMC

  • Newt
  • Posts: 191
How to: hatch multiple selected items individually
« on: February 28, 2020, 04:56:28 PM »
Is there a lsp already written to make this work? By hand using "mu" just takes too long. I'll try with help using examples of similar. Did a micro-theswamp search with no-show. Thanks   :uglystupid2:

BIGAL

  • Swamp Rat
  • Posts: 1398
  • 40 + years of using Autocad
Re: How to: hatch multiple selected items individually
« Reply #1 on: March 01, 2020, 06:03:28 PM »
The brain fades some times there is a variable you set and hatch will be individual.

Do normal hatch and there is an option for separate.
A man who never made a mistake never made anything

MP

  • Seagull
  • Posts: 17750
  • Have thousands of dwgs to process? Contact me.
Re: How to: hatch multiple selected items individually
« Reply #2 on: March 01, 2020, 09:10:55 PM »
http://autode.sk/2Tv6BEh

Controls whether a single hatch object or separate hatch objects are created when operating on several closed boundaries.

Type:          Integer
Saved in:      Registry
Initial value: 0

0 A single hatch object is created
1 Separate hatch objects are created
Engineering Technologist • CAD Automation Practitioner
Automation ▸ Design ▸ Drafting ▸ Document Control ▸ Client
cadanalyst@gmail.comhttp://cadanalyst.slack.comhttp://linkedin.com/in/cadanalyst

BIGAL

  • Swamp Rat
  • Posts: 1398
  • 40 + years of using Autocad
Re: How to: hatch multiple selected items individually
« Reply #3 on: March 01, 2020, 11:01:13 PM »
Should be this HPSEPERATE
A man who never made a mistake never made anything

ScottMC

  • Newt
  • Posts: 191
Re: How to: hatch multiple selected items individually
« Reply #4 on: March 02, 2020, 02:57:28 PM »
Had it in my library and now want to thank whoever wrote it!!
Anybody know the author? Imagine this for region separation..

Code: [Select]
(defun c:hh ( / *error* _HatchIt _HatchItSub version ss i space )
(princ "\n Individually Hatch ALL Pline and Region..")
    (cond
        (   (> 15 (setq version (atoi (getvar "acadver"))))
            ;;  shreik! AutoCAD 14 and older
            (princ "Upgrade your AutoCAD mang!\n")
            (defun *error* (x) (princ))
            (exit)
        )
        (   (< 15 version)
            ;;  AutoCAD 2004+
            (defun _HatchItSub ( space )
                (vlax-invoke
                    space
                   'AddHatch
                    acHatchStyleNormal ;; pattern type             
                    "Solid"           ;; pattern name
                    :vlax-false        ;; associativity
                    AcHatchObject      ;; hatch object type
                )
            )
        )
        (   ;;  AutoCAD 2000 / 2002
            (defun _HatchItSub ( space )
                (vlax-invoke
                    space
                   'AddHatch
                    acHatchStyleNormal ;; pattern type             
                    "Solid"           ;; pattern name
                    :vlax-false        ;; associativity
                )
            )
        )   
    )

    (defun _HatchIt ( space object / hatch err )
        (setq err
            (vl-catch-all-apply
               '(lambda ()
                    (setq hatch (_HatchItSub space))
                    (vlax-invoke
                        hatch
                       'AppendOuterLoop
                       (list object)
                    ) 
                    (vlax-invoke hatch 'Evaluate)
                ) 
            ) 
        )
        (if (vl-catch-all-error-p err)
            (princ
                (strcat
                    "Entity handle:"
                    (vla-get-handle object)
                    " caused this error: "
                    (vl-catch-all-error-message err)
                )
            ) 
        ) 
    )
   
    (cond
        (   (setq ss
                (ssget
                   '(   (0 . "lwpolyline,polyline,region")
                        (-4 . "&")
                        (70 . 1)
                    )
                )
            )
            (setq space
                (vlax-get-property
                    (vlax-get-property
                        (vlax-get-acad-object)
                       'ActiveDocument
                    )
                    (if (eq 1 (getvar "cvport"))
                       'PaperSpace
                       'ModelSpace
                    )
                )
            ) 
            (repeat (setq i (sslength ss))
                (_HatchIt
                    space
                    (vlax-ename->vla-object
                        (ssname ss (setq i (1- i)))
                    )
                )
            )
        )
    )
   
    (princ)

)

« Last Edit: March 04, 2020, 09:15:42 AM by ScottMC »

ronjonp

  • Needs a day job
  • Posts: 7526
Re: How to: hatch multiple selected items individually
« Reply #5 on: March 04, 2020, 12:48:51 PM »
Had it in my library and now want to thank whoever wrote it!!
Anybody know the author? Imagine this for region separation..

....
Maybe this guy: http://www.theswamp.org/index.php?topic=55796.msg598563#msg598563

Windows 11 x64 - AutoCAD /C3D 2023

Custom Build PC

Lee Mac

  • Seagull
  • Posts: 12906
  • London, England
Re: How to: hatch multiple selected items individually
« Reply #6 on: March 04, 2020, 02:30:42 PM »
Had it in my library and now want to thank whoever wrote it!!
Anybody know the author? Imagine this for region separation..

....
Maybe this guy: http://www.theswamp.org/index.php?topic=55796.msg598563#msg598563

The code has MP written all over it  :-)

ronjonp

  • Needs a day job
  • Posts: 7526
Re: How to: hatch multiple selected items individually
« Reply #7 on: March 04, 2020, 03:08:00 PM »
Had it in my library and now want to thank whoever wrote it!!
Anybody know the author? Imagine this for region separation..

....
Maybe this guy: http://www.theswamp.org/index.php?topic=55796.msg598563#msg598563

The code has MP written all over it  :-)
Yeah .. this line queued me:
Code - Auto/Visual Lisp: [Select]
  1. (princ "Upgrade your AutoCAD mang!\n")
  :-D

Windows 11 x64 - AutoCAD /C3D 2023

Custom Build PC

ScottMC

  • Newt
  • Posts: 191
Re: How to: hatch multiple selected items individually
« Reply #8 on: March 04, 2020, 09:11:04 PM »
Again, Thanks to MP. This also inspires me to learn what else is actually possible! Lee Mac is so helpful by including the 'comments' with the code. Helps it to: sink-it-into-my-thick-skull. Keep up the good work y'all.

ScottMC

  • Newt
  • Posts: 191
Re: How to: hatch multiple selected items individually
« Reply #9 on: November 14, 2020, 12:48:03 AM »
Again, Thanks to MP. This also inspires me to learn what else is actually possible! Lee Mac is so helpful by including the 'comments' with the code. Helps it to: sink-it-into-my-thick-skull. Keep up the good work y'all.
Who knows how to set scale for that Hatch created? I'll keep looking but know there must be a way in the vlax-invoke but.. Thanks much guys.
------------------------------------------------------------------------
Code: [Select]
(defun c:hh ( / *error* _HatchIt _HatchItSub version ss i space ) ;; https://www.theswamp.org/index.php?topic=6412.msg78804#msg78804
(princ "\n Individually Hatch Objects..") ;; Author: https://www.theswamp.org/index.php?action=profile;u=160   <--- "MP"
    (cond
        (   (> 15 (setq version (atoi (getvar "acadver"))))
        ;;  shreik! AutoCAD 14 and older
        ;; https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/hatch-scale/td-p/2359278
        ;;  acquired scale tool..line: 64/65
            ;;(princ "Upgrade your AutoCAD mang!\n")
            (defun *error* (x) (princ))
            (exit)
        )
       
        (   (< 15 version)
            ;;  AutoCAD 2004+
            (defun _HatchItSub ( space )
                (vlax-invoke
                    space
                   'AddHatch
                    acHatchStyleNormal ;; pattern type             
                    "ANSI31"           ;; pattern name
                    :vlax-false        ;; associativity
                    AcHatchObject      ;; hatch object type
                )
            )
        )
        (   ;;  AutoCAD 2000 / 2002
            (defun _HatchItSub ( space )
                (vlax-invoke
                    space
                   'AddHatch
                    acHatchStyleNormal ;; pattern type                     
                    "ANSI31"       ;; pattern name
                    :vlax-false        ;; associativity
                 )
            )
        )   
    )

    (defun _HatchIt ( space object / hatch err )
        (setq err
            (vl-catch-all-apply
               '(lambda ()
                    (setq hatch (_HatchItSub space))
                    (vlax-invoke
                        hatch
                       'AppendOuterLoop
                       (list object)
                    )           
                      ;;
                    (vlax-invoke hatch 'Evaluate)
                ) 
            ) 
        )
        (if (vl-catch-all-error-p err)
            (princ
                (strcat
                    "Entity handle:"
                    (vla-get-handle object)
                    " caused this error: "
                    (vl-catch-all-error-message err)
                )
            ) 
        ) 
        (setq object (vlax-ename->vla-object (entlast)))  ;; added this from Jeff_Mishler and got the scale option
        (vlax-put object 'PatternScale 5.0)                        ;; works better for me at "5.0"
    )
   
    (cond
        (   (setq ss
                (ssget
'(   (0 . "CIRCLE,ELLIPSE,*POLYLINE,REGION") ;; update 5.3.20
                    (-4 . "<NOT")
                        (-4 . "<AND")
                            (0 . "POLYLINE") (-4 . "&") (70 . 80)
                        (-4 . "AND>")
                    (-4 . "NOT>")
                )
                   ; '(   (0 . "circle,*polyline,region")
                        ; (-4 . "&")
                        ; (70 . 1)
                    ; )
                )
            )
            (setq space
                (vlax-get-property
                    (vlax-get-property
                        (vlax-get-acad-object)
                       'ActiveDocument
                    )
                    (if (eq 1 (getvar "cvport"))
                       'PaperSpace
                       'ModelSpace
                    )
                )
            ) 
            (repeat (setq i (sslength ss))
                (_HatchIt
                    space
                    (vlax-ename->vla-object
                        (ssname ss (setq i (1- i)))
                    )
                )
            )
        )
    )
   
    (princ)

)
« Last Edit: November 17, 2020, 02:09:51 PM by ScottMC »

d2010

  • Bull Frog
  • Posts: 323
Re: How to: hatch multiple selected items individually
« Reply #10 on: November 14, 2020, 01:00:41 PM »
Again, Thanks to MP. This also inspires me to learn what else is actually possible! Lee Mac is so helpful by including the 'comments' with the code. Helps it to: sink-it-into-my-thick-skull. Keep up the good work y'all.
Code - Auto/Visual Lisp: [Select]
  1.  (setq acad_iso11w100-extmin 41 acad_iso11w100-extmax 59089)
  2.  (setq acad_isoQsortTime 00:00.00)
  3.  (setq runiftry11w100 (list (cons "0x0000" "https://youtu.be/Ly6mVkU5OGE")
  4.  (cons "0x4DFA"  "cons");;County.xml=10
  5.  (cons "0xB2A2"  "vlax-invoke");;County.xml=4
  6.  (cons "0x066C"  "read");;County.xml=4
  7.  (cons "0x2ABB"  "append");;County.xml=3
  8.  (cons "0xB77E"  "reverse");;County.xml=2
  9.  (cons "0x4E37"  "getvar");;County.xml=2
  10.  (cons "0xD270"  "bs_dibpattern");;County.xml=1
  11.  (cons "0xBE4E"  "last");;County.xml=1
  12.  (cons "0x0CB3"  "if_int");;County.xml=1
  13.  (cons "0x920B"  "bs_hatched");;County.xml=1
  14.  (cons "0x6E00"  "alert");;County.xml=1
  15.  (cons "0x1C2B"  "setvar");;County.xml=1
  16.  (cons "0xE6D1"  "dfn_getx_readkey");;County.xml=1
  17.  (cons "0x0029"  "vlax-ename->vla-object");;County.xml=1
  18.  (cons "0x53FE"  "vla-get-handle");;County.xml=1
  19.  (cons "0x624B"  "strcase");;County.xml=1
  20.  (cons "0x2338"  "entmakex");;County.xml=1
  21.  (cons "0xD0B1"  "ssget");;County.xml=1
  22.  (cons "0x4C2D"  "sslength");;County.xml=1
  23.  (cons "0x48F2"  "ssname");;County.xml=1
  24.  (cons "0xE271"  "vl-catch-all-apply");;County.xml=1
  25.  (cons "0xB00F"  "vl-catch-all-error-p");;County.xml=1
  26.  (cons "0x9E77"  "grread");;County.xml=1
  27.  (cons "0x5F6D"  "vl-catch-all-error-message");;County.xml=1
  28.  (cons "0x46CA"  "wcmatch");;County.xml=1
  29.  (cons "0x898A"  "vl_load_com");;County.xml=1
  30.  (cons "0xB118"  "cadr");;County.xml=1
  31.  (cons "0x7EBC"  "atoi");;County.xml=1
  32. ))
  33. (setq getmypid (list "0x596B") setmypid "???")
  34. (defun jc_dup35(mypid loopwne / rom subf)
  35.    (setq getmypid setmypid setmypid (substr mypid 8) subf (cdr (assoc (strcat "0x" (substr mypid 3 4)) runiftry11w100)))
  36.    (setq rom (apply (read subf) loopwne))
  37. rom)
  38.  
  39.  (setq acad_isoQsortTimp 00:00.00)
  40.  (setq acad_isoSortTotal 00:00.00)
  41. ;;{$R dfn_cad_amain2}
  42.  
  43. (Defun C:q2()
  44.   (setq;|a1383|;
  45.          dfn_pp_v1chkR nil)  
  46.   (pp_scotthactch_app)
  47. )
  48.  
  49. (Defun asserte(mssg / $rr)
  50.   (setq;|a1982|;
  51.          acad__assertNo (+ acad__assertNo 1)) (if (/= mssg nil) (setq;|a2024|;
  52.          erprv erlsp
  53.          erlsp mssg))
  54. erlsp)
  55.  
  56. (Prompt "\nCommand.com=Q2[enter]\n")
  57. (Defun pp_scotthactch_app( / )
  58.    (setq acad__assertNo 0)
  59.  
  60.   ;;{$R (call_copy_source)}
  61. ;------------------------;$
  62.  (setq scott (getreal (strcat "\nGive-me HpScale <" (rtos (getvar "HpScale")) ">=")))
  63. ;------------------------
  64.   ;;{$R (call_copy_source)}
  65. ;------------------------;$
  66.  (if (/= scott nil) (setvar "HpScale" (abs scott)))
  67. ;------------------------
  68.   ;;{$R (call_copy_source)}
  69. ;------------------------;$
  70.  (setq _ax "Y")
  71. ;------------------------
  72.   ;;{$R (call_copy_source)}
  73. ;------------------------;$
  74.  (setq dbhatch.h (list "SOLID" "ANGLE" "ANSI31" "ANSI32" "ANSI33" "ANSI34"
  75. ;------------------------
  76.   ;;{$R (call_copy_source)}
  77. ;------------------------;$
  78.                  "ANSI35" "ANSI36" "ANSI37" "ANSI38" "MUDST" "ZIGZAG"))
  79. ;------------------------
  80.   ;;{$R (call_copy_source)}
  81. ;------------------------;$
  82.  (setq color.stb 10 monostb "\nRotateHatch(y-yes)(n-no)(x-exit)?:")
  83. ;------------------------
  84.   ;;{$R (call_stas)}
  85. ;------------------------Dmicall dfn_getx_readkey
  86.   (setq _ax (dfn_getx_readkey "[YNX]" monostb))
  87. ;------------------------
  88.   ;;{$R (call_copy_source)}
  89. ;------------------------;$
  90.  (while (/= _ax "X") (progn
  91. ;------------------------
  92.   ;;{$R (call_stas)}
  93. ;------------------------Stdcall pp_hatcharea
  94.   (setq _ax (pp_hatcharea ))
  95. ;------------------------
  96.   ;;{$R (call_stas)}
  97. ;------------------------Dmicall dfn_getx_readkey
  98.   (setq _ax (dfn_getx_readkey "[YNX]" monostb))
  99. ;------------------------
  100.   ;;{$R (call_copy_source)}
  101. ;------------------------;$
  102.  ))
  103. ;------------------------
  104.  ;;{$R dfn_cad_amain_callend2}
  105.  
  106.   (princ "\nEnd")  
  107. T)
  108. ;(User Labels)
  109. ;()))
  110.  
  111.  
  112.  
  113.  
  114.  
  115.  
  116.   ;;{$R dfn_getx_readkey}
  117.  
  118. ;;Inf:Wait until press keys k
  119. ;;Inp:k574:keys =("".none)
  120. ;;rem:    m469=(nil.none)(else.prompt message)
  121. ;;Out:rr:char('A'..'Z')
  122. ;;Err: "t469errorStr". invalid type of variabile t469, must be STR
  123. /ByA:DragneAdrian
  124.  
  125.    
  126. (defun dfn_getx_readkey(k574 t469 / retc kbd msg two chk lei tip)
  127.    (setq;|a8667|;
  128.          retc (chr 0)
  129.          tip (quote STR)
  130.          kbd (if (/= (type k574) tip) "" k574)
  131.          msg (if (/= (type t469) tip) "\nt469errorStr:" t469)) (prompt msg) (progn (setq;|a8805|;
  132.          chk (if (>  (strlen kbd) 1) 0 1)) (while (=  chk 0) (progn  (setq;|a8861|;
  133.          two 0) (while (/= two 2) (setq;|a8899|;
  134.          lei (jc_dup35 "0x9E77:C001" (list ))
  135.          two (car lei)) (setq;|a8947|;
  136.          retc (jc_dup35 "0x624B:C002" (list  (chr (jc_dup35 "0xB118:C003" (list  lei)))))) (setq;|a8987|;
  137.          chk (if (/= kbd "") (if (jc_dup35 "0x46CA:C004" (list  retc kbd)) 1 0) 0)))))) (princ retc)
  138. retc)
  139.  
  140.  
  141.  
  142. (setq gelibver nil)
  143. (defun pp_hatcharea( / sos ssh ida nrg)
  144.    (setq;|a12125|;
  145.          gelibver (jc_dup35 "0x7EBC:C006" (list  (jc_dup35 "0x4E37:C007" (list  "ACADVER"))))) (if (>  15.0 gelibver) (progn  (jc_dup35 "0x6E00:C008" (list  (strcat "Upgrade your AutoCAD mang!\n" readme.txt))) exit)) (jc_dup35 "0x898A:C009" (list )) (setq;|a12223|;
  146.          ssh (jc_dup35 "0xD0B1:C010" (list  (list (jc_dup35 "0x4DFA:C011" (list  0 "LWPOLYLINE,POLYLINE,REGION")) (jc_dup35 "0x4DFA:C012" (list  (- 4) "&")) (jc_dup35 "0x4DFA:C013" (list  70 1)))))) (setq;|a12321|;
  147.          ida (- (jc_dup35 "0x4C2D:C014" (list  ssh)) 1)) (progn (while (>= ida 0) (setq;|a12373|;
  148.          nrg (jc_dup35 "0x48F2:C015" (list  ssh ida))) (jc_dup35 "0xD270:C016" (list  con_cespace (jc_dup35 "0x0029:C017" (list  nrg)))) (setq;|a12433|;
  149.          ida (- ida 1))))
  150. $rr)
  151.  ;;{$E}
  152.  
  153. (Defun dfn_enamk_line(p1 p2 la color lt / $rr nfl)
  154.    (if (=  color nil) (setq;|a15298|;
  155.          color 256)) (setq;|a15326|;
  156.          la (if (>  la "") la (jc_dup35 "0x4E37:C018" (list  "CLAYER")))
  157.          p1 (jc_dup35 "0x2ABB:C019" (list  (list 10) p1))
  158.          p2 (jc_dup35 "0x2ABB:C020" (list  (list 11) p2))
  159.          nfl (list (jc_dup35 "0x4DFA:C021" (list  0 "LINE")) (jc_dup35 "0x4DFA:C022" (list  100 "AcDbEntity")) (jc_dup35 "0x4DFA:C023" (list  8 la)) (jc_dup35 "0x4DFA:C024" (list  100 "AcDbLine")) p1 p2 (jc_dup35 "0x4DFA:C025" (list  62 color)))) (if (>  lt "") (setq;|a15618|;
  160.          nfl (jc_dup35 "0x2ABB:C026" (list  nfl (list (jc_dup35 "0x4DFA:C027" (list  6 lt))))))) (setq;|a15674|;
  161.          $rr (jc_dup35 "0x2338:C028" (list  nfl))) (princ)
  162. $rr)
  163.  ;;{$E}
  164.   ;;{$R bs_dibpattern}
  165. (defun bs_dibpattern(setPatternSpace object / err mop hatch)
  166.    (setq;|a16824|;
  167.          err (jc_dup35 "0xE271:C029" (list  (jc_dup35 "0x066C:C030" (list  "bs_pattern")) (list setPatternSpace object)))) (if (jc_dup35 "0xB00F:C031" (list  err)) (princ (strcat "Entity handle:" (jc_dup35 "0x53FE:C032" (list  object)) " caused this error: " (jc_dup35 "0x5F6D:C033" (list  err)))))
  168. )
  169.  ;;{$E}
  170.   ;;{$R vl_load_com}
  171.  
  172. (defun vl_load_com(/ $rr)
  173.  (if (null con_modspace)  (progn (vl-load-com) (prompt "\n\n")
  174.  (setq vlax_true :Vlax-True
  175.        vlax_false :Vlax-False
  176.        kHomeRegistry "HKEY_CURRENT_USER\\Software\\Autodesk\\AutoCAD")
  177.  (setq con_acadapp (vlax-get-acad-object))
  178.  (setq con_acdoc (vla-get-activedocument con_acadapp))
  179.  (setq con_acdocUtility (vla-get-utility con_acdoc))
  180.  (setq con_modspace (vla-get-modelspace con_acdoc))
  181.  (setq con_cespace (vlax-get-property con_acdoc
  182.           (if (zerop (getvar "CVPORT")) (read "PaperSpace") (read "ModelSpace"))))
  183.  ;; set a reference to the current model space
  184.   ))
  185. )
  186.  
  187. (defun bs_hatched(pspworkspace setver_quiet / $rr ave rcl)
  188.    (if (=  _ax "Y") (setq;|a20301|;
  189.          rcl (jc_dup35 "0xBE4E:C034" (list  dbhatch.h))
  190.          dbhatch.h (jc_dup35 "0x4DFA:C035" (list  rcl (jc_dup35 "0xB77E:C036" (list  (cdr (jc_dup35 "0xB77E:C037" (list  dbhatch.h)))))))) (progn  (setq;|a20391|;
  191.          rcl "Solid"
  192.          color.stb (+ color.stb 1)
  193.          color.stb (if (>  color.stb 250) 10 color.stb)) (jc_dup35 "0x1C2B:C038" (list  "CECOLOR" (itoa color.stb))))) (setq;|a20489|;
  194.          ave (jc_dup35 "0x0CB3:C039" (list  setver_quiet 15))) (if (>  ave 15) (setq;|a20539|;
  195.          $rr (jc_dup35 "0xB2A2:C040" (list  pspworkspace (jc_dup35 "0x066C:C041" (list  "AddHatch")) acHatchStyleNormal rcl vlax_false AcHatchObject))) (setq;|a20611|;
  196.          $rr (jc_dup35 "0xB2A2:C042" (list  pspworkspace (jc_dup35 "0x066C:C043" (list  "AddHatch")) acHatchStyleNormal rcl vlax_false))))
  197. $rr)
  198.  ;;{$E}
  199.  
  200. (defun bs_pattern(spc obiect / $rr)
  201.    (setq;|a21709|;
  202.          $rr (jc_dup35 "0x920B:C044" (list  spc gelibver))) (jc_dup35 "0xB2A2:C045" (list  $rr (jc_dup35 "0x066C:C046" (list  "AppendOuterLoop")) (list obiect))) (jc_dup35 "0xB2A2:C047" (list  $rr (quote Evaluate)))
  203. $rr)
  204.  ;;{$E}
  205.  
  206.   ;;{$R if_int}
  207.     ;;inf: (type(a025)==quote(int))
  208.     ;;Out:rr(1.is Integer)(nil.else)
  209.     ;;ByA:DragneAdrian2015
  210.  
  211. (defun if_int(a025 default / $ri guru)  ;_ASSERT_OK
  212.    (setq;|a23091|;
  213.          guru (quote INT)
  214.          $ri (if (=  (type a025) (quote SYM)) (eval a025) a025)
  215.          $ri (if (/= (type $ri) guru) default $ri))
  216. $ri)
  217.  ;;{$E}
  218.  
  219. ;L
  220.  ;;{$R dfn_cad_amain_eof2}
  221. (prompt "\nCommand.com: Q2[enter]\n")
  222. ;;</dfn_cad_amain_eof2>
  223. (setq readme.txt "How to: hatch multiple selected items individually
  224. Is there a lsp already written to make this work? By hand using ~mu~ just takes too long. I'll try with help u
  225. «zlib=../cl_aclayer/enthatch/2020/pp_scotthactch.vlax»")
  226.  


« Last Edit: November 15, 2020, 09:55:50 AM by d2010 »