Topic: How to change normal Z of a center of circle in Autocad?

[Vikram]

I have a drawing in which "normal Z" of the center of circles is -1. Thats why the coordinates became negative in ASCII dxf format text file. I want to change the normal Z to 1.
Note:  There difference between Normal Z and Center Z. We get normal Z for only circles.
I was able o change the the Z coordinate to 0 but the normal Z is still -1.
Format is like Normal X=0 Normal Y=0 and Normal Z=-1

I did elevating Z to 0. Tried changing UCS to world but not helping/ I have attached the sample drawing for reference. Any auotlisp will also help!

[roy_043]

Try:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun KGA_Conv_Pickset_To_ObjectList (ss / i ret)
4.   (if ss
5.     (repeat (setq i (sslength ss))
6.       (setq ret (cons (vlax-ename->vla-object (ssname ss (setq i (1- i)))) ret))
7.     )
8.   )
9. )
10.  
11. (defun c:CorrectNormals ( / doc ss)
12.   (setq doc (vla-get-activedocument (vlax-get-acad-object)))
13.   (vla-endundomark doc)
14.   (vla-startundomark doc)
15.   (if (setq ss (ssget "_X" '((0 . "CIRCLE") (210 0.0 0.0 -1.0))))
16.     (foreach obj (KGA_Conv_Pickset_To_ObjectList ss)
17.       (vlax-put obj 'normal '(0.0 0.0 1.0))
18.     )
19.   )
20.   (vla-endundomark doc)
21.   (princ)
22. )

EDIT: added (vl-load-com).

[Vikram]

Thanks for the lisp! But unfortunately I'm using Intellicad and its is throwing me the error of "Bad argument Type"

[snownut2]

The subject title says you are looking for AutoCAD help? 

[Lee Mac]

Assuming that you don't want the visual position of the circles to change, I would suggest the following:

Code - Auto/Visual Lisp: [Select]

1. (defun c:test ( / c i n s x )
2.     (if (setq s (ssget "_X" '((0 . "CIRCLE") (210 0.0 0.0 -1.0))))
3.         (repeat (setq i (sslength s))
4.             (setq i (1- i)
5.                   x (entget (ssname s i))
6.                   n (assoc 210 x)
7.                   c (assoc 010 x)
8.             )
9.             (entmod (subst (cons 10 (trans (cdr c) (cdr n) 0)) c (subst '(210 0.0 0.0 1.0) n x)))
10.         )
11.     )
12.     (princ)
13. )

[roy_043]

@Vikram:
Is there an online overview of the Lisp functions and features supported by IntelliCAD?

@Lee Mac:
I also considered translating the center point but in this situation it appears to not be required.

[Vikram]

Hey @Lee Mac it worked!
Thanks for the help!
If you want to see Intellicads lisp compatibility you can check here http://help.caddit.net/progecad.php?kb=IDR_LISP_B100

Again thanks for helping me!