Topic: Finding Start and Last point

[Craig]

Anyone have a good idea on getting a LWPOLYLINEs first and last point? Example

Code: [Select]

Coordinates = (463.169 705.026 1534.87 705.026 1534.87 1135.03)
This PLINE has 3 vertices and I want the last point. This would apply to LWPOLYLINEs that have multiple vertices as well.

I know I can get the first point using

Code: [Select]

(list
(nth 0
    (vlax-safearray->list
      (vlax-variant-value
(vlax-get-property en_obj 'Coordinates)
      )
    )
)
(nth 1
    (vlax-safearray->list
      (vlax-variant-value
(vlax-get-property en_obj 'Coordinates)
      )
    )
)
     )
It's really the last one I'm after since the last nth might change on each PLINE selected.

[whdjr]

Returns the endpoint (in WCS) of the curve  
(vlax-curve-getEndPoint curve-obj)

Arguments

curve-obj

The VLA-object to be measured.

Return Values

A 3D point list representing an endpoint, if successful, otherwise nil.

Examples

Get the endpoint of the ellipse used to demonstrate vlax-curve-getArea:

_$ (vlax-curve-getEndPoint ellipseObj)

(2.0 2.0 0.0)

[whdjr]

Returns the start point (in WCS) of the curve  
(vlax-curve-getStartPoint curve-obj)

Arguments

curve-obj

The VLA-object to be measured.

Return Values

A 3D point list representing the start point, if successful, otherwise nil.

Examples

Get the start point of the ellipse used to demonstrate vlax-curve-getArea:

_$ (vlax-curve-getStartPoint ellipseObj)

(2.0 2.0 0.0)

For an ellipse, the start points and endpoints are the same.
Obtain the start point of the spline used to demonstrate vlax-curve-getDistAtParam:

_$ (vlax-curve-getStartPoint splineObj)

(1.73962 2.12561 0.0)

[Kerry]

You could Use the curve methods,

but to answer the list question, Perhaps this will help

Code: [Select]


(setq tmp (reverse (vlax-safearray->list  .....
(setq 2dVertexPoint (list (cadr tmp)(car tmp))

[Jürg Menzi]

Visit my homepage -> Free Stuff and search for 'VxGetEndPoints'

Cheers

[whdjr]

But to answer the original question:

Anyone have a good idea on getting a LWPOLYLINEs first and last point?

and because he already had the polyline object:

Code: [Select]

(vlax-curve-getstartpoint en_obj)
(vlax-curve-getendpoint en_obj)
You don't have to deal with the lists.

[Jeff_M]

And here's another way of doing this, skipping the use of the (vlax-curve) functions. This is handy to know since the curve functions are not easily available in VBA, but this methodolgy will work.

Code: [Select]


;for testing, select pline
(setq pline (vlax-ename->vla-object (car (entsel "\nSelect pline: "))))
;get the startpoint, the coordinate property doesn't like the (vlax-get) way of obtaining the data
(setq stPt (vlax-safearray->list (vlax-variant-value (vla-get-coordinate pline 0))))
;find # of vertices, O based...note that the coordinates property works fine with (vlax-get)
(setq vert# (1- (/ (length (vlax-get pline 'coordinates)) 2)))
;get the endpoint
(setq endPt (vlax-safearray->list (vlax-variant-value (vla-get-coordinate pline vert#))))

[Craig]

Code: [Select]

(vlax-curve-getstartpoint en_obj)
(vlax-curve-getendpoint en_obj)
You don't have to deal with the lists.

Thanks Will, that couldn't be any easier. Learning this stuff bit by bit and those two lines beat my six lines.  

[Jeff_M]

Thanks Will, that couldn't be any easier. Learning this stuff bit by bit and those two lines beat my six lines.  

And to help with the learning a little......the (vlax-curve-) functions work with many types of objects:
Line, Arc, LWPline, Pline, Spline, 3DPline, Ellipse, Circle.

Furthermore, you don't need to convert to/from a vla-object to use them. You can send EITHER a valid <ename> OR vla-object  

[CAB]

The vlax-curve function is a very powerful tool.

But for those wanting plain lisp..

Code: [Select]

;;  Returns the ends of LWPline
;;  No error checking
;;  Expects an entity name
(defun pline_ends (ent / elst)
  (setq elst (entget ent))
  (list (cdr (assoc 10 elst))
        (cdr (assoc 10 (reverse elst))))
)

[daron]

Also, don't forget this fine tutorial entitled Relaxed curves, given by our own SMadsen.

[whdjr]

Also, don't forget this fine tutorial entitled Relaxed curves, given by our own SMadsen.

AHA!  You found it!

I was looking for that earlier Daron.  I'm glad you found that and posted it.  It's a good read and awesome learning tool.

[daron]

It's pretty easy. It's on the second page of the "Teach Me" forum. That is a prime example of the purpose of the Teach Me forum.