Topic: Draw line after choosing a color

[jlogan02]

It'll draw the line but not set the color. The numbers indicate AutoCAD color numbers.
Sooo...choose the color and draw the line.

Code - Auto/Visual Lisp: [Select]

1. (defun c:Hline (/ hcol)
2.  (initget 1 "1 56 136 191")
3.   (setq hcol (getkword "\nEnter COLOR [1/56/136/191]: "))
4.    (cond
5.      ((eq hcol "1") 1)
6.      ((eq hcol "56") 56)
7.      ((eq hcol "136") 136)
8.      ((eq hcol "191") 191)
9.      (T hcol)
10.       )
11.    (command "_Line" pause hcol)
12.    (princ)
13.  )

[ronjonp]

Try the code below. You cannot just put the color into the line command and expect it to know what to do with it.

Code - Auto/Visual Lisp: [Select]

1. (defun c:hline (/ hcol p1 p2)
2.   ;; RJP » 2019-03-27
3.   (initget 1 "1 56 136 191")
4.   (if (setq hcol (getkword "\nEnter COLOR [1/56/136/191]: "))
5.     (while (and (or p1 (setq p1 (getpoint "\nSpecify start point: ")))
6.                 (setq p2 (getpoint p1 "\nSpecify next point: "))
7.            )
8.       (entmakex (list '(0 . "line") (cons 10 p1) (cons 11 p2) (cons 62 (atoi hcol))))
9.       (setq p1 p2)
10.     )
11.   )
12.   (princ)
13. )

Line command:

Command: LINE
Specify first point:
Specify next point or [Undo]:
Specify next point or [Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:

[BIGAL]

You can use -color prior to line call then dont need to entmake.

Code: [Select]

(defun test (  / oldcol hcol p1 p2)
(initget 1 "1 56 136 191")
  (setq hcol (getkword "\nEnter COLOR [1/56/136/191]: "))
  (setq oldcol (getvar 'cecolor))
  (setvar 'cecolor" (atoi hcol))
  (while (and (or p1 (setq p1 (getpoint "\nSpecify start point: ")))
(setq p2 (getpoint p1 "\nSpecify next point: "))
   )
      (command "line" p1 p2 "")
      (setq p1 p2)
    )
  (setvar 'cecolor oldcol)
  (princ)
)
(test)

My version of initget look at image uses a library multi button lsp

[jlogan02]

Thanks guys, both are right in line with what I was thinking. I need to "remember" last input and do some layer creation stuff, but this gets me closer.

Thanks again.