Topic: Quick Block modification

[asami486]

Hi.
I Just wanna to add one function.
I want to use not the default block name "MyBlock" BUT a block name that I enter.
Please Help Me!

Code: [Select]

;;; Quick Block
  ;;; Tharwat 11. May. 2012 ;;
  ;;; http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/quick-block/td-p/3454228
  ;;; Modified by HasanCAD and Grrr1337 (in theswamp)
  ;;; https://www.theswamp.org/index.php?topic=52634.0

(defun c:B (/ selectionset insertionpoint number Blockname mn mx pnts)
  (vl-load-com)
  (defun LM:ssboundingbox ( sel / idx llp ls1 ls2 obj urp ) ; Lee mac
    (repeat (setq idx (sslength sel))
        (setq obj (vlax-ename->vla-object (ssname sel (setq idx (1- idx)))))
        (if (and (vlax-method-applicable-p obj 'getboundingbox)
                 (not (vl-catch-all-error-p
(vl-catch-all-apply 'vla-getboundingbox (list obj 'llp 'urp)))))
            (setq ls1 (cons (vlax-safearray->list llp) ls1)
                  ls2 (cons (vlax-safearray->list urp) ls2))))
 
    (if (and ls1 ls2)
        (mapcar '(lambda ( a b ) (apply 'mapcar (cons a b))) '(min max) (list ls1 ls2))))
 
    (if (setq selectionset (ssget "_:L-I"))
    (progn
      (setq number    1
            Blockname (strcat "MyBlock" (itoa number))
      )
      (while (tblsearch "BLOCK" Blockname)
        (setq Blockname
               (strcat "MyBlock" (itoa (setq number (1+ number))))
        )
      )
      (or ; why? - select XLINE/RAY/POINT entity
        (setq insertionpoint (getpoint "\n Specify insertion point <Press any key for Center>: "))
        (and
          (setq insertionpoint (LM:ssboundingbox selectionset))
          (setq insertionpoint (apply 'mapcar (cons '(lambda (a b) (/ (+ a b) 2.))  insertionpoint))) ; thanks for this, Lee Mac
        )
        (setq insertionpoint (getpoint "\nYou must specify an insertion point <exit>: "))
      ); or
 
      (command "_.-Block" Blockname insertionpoint selectionset "")
      (command "_.-insert" Blockname insertionpoint "" "" "")
    )
    (princ)
  )
  (princ)
)



[ronjonp]

Try this:

Code - Auto/Visual Lisp: [Select]

1. ;;; Quick Block
2. ;;; Tharwat 11. May. 2012 ;;
3. ;;; http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/quick-block/td-p/3454228
4. ;;; Modified by HasanCAD and Grrr1337 (in theswamp)
5. ;;; https://www.theswamp.org/index.php?topic=52634.0
6.  
7. (defun c:b (/ selectionset insertionpoint number blockname mn mx pnts)
8.   (vl-load-com)
9.   (defun lm:ssboundingbox (sel / idx llp ls1 ls2 obj urp) ; Lee mac
10.     (repeat (setq idx (sslength sel))
11.       (setq obj (vlax-ename->vla-object (ssname sel (setq idx (1- idx)))))
12.       (if
13.         (and
14.           (vlax-method-applicable-p obj 'getboundingbox)
15.           (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-getboundingbox (list obj 'llp 'urp))))
16.         )
17.          (setq ls1 (cons (vlax-safearray->list llp) ls1)
18.                ls2 (cons (vlax-safearray->list urp) ls2)
19.          )
20.       )
21.     )
22.     (if (and ls1 ls2)
23.       (mapcar '(lambda (a b) (apply 'mapcar (cons a b))) '(min max) (list ls1 ls2))
24.     )
25.   )
26.   (if (and (setq blockname (getstring "\nEnter Block Name: "))
27.            (snvalid blockname)
28.            (setq selectionset (ssget "_:L-I"))
29.       )
30.     (progn
31.       (setq number 0)
32.       (while (tblsearch "BLOCK" blockname)
33.         (setq blockname (strcat blockname (itoa (setq number (1+ number)))))
34.       )
35.       (or                               ; why? - select XLINE/RAY/POINT entity
36.         (setq insertionpoint (getpoint "\n Specify insertion point <Press any key for Center>: "))
37.         (and
38.           (setq insertionpoint (lm:ssboundingbox selectionset))
39.           (setq insertionpoint (apply 'mapcar (cons '(lambda (a b) (/ (+ a b) 2.)) insertionpoint)))
40.                                         ; thanks for this, Lee Mac
41.         )
42.         (setq insertionpoint (getpoint "\nYou must specify an insertion point <exit>: "))
43.       )                                 ; or
44.       (command "_.-Block" blockname insertionpoint selectionset "")
45.       (command "_.-insert" blockname insertionpoint "" "" "")
46.     )
47.     (princ)
48.   )
49.   (princ)
50. )

[asami486]

Thank you So much.   

[ronjonp]

You're welcome!