Topic: Add text strings that have ft. & inches

[BillB]

O.k.,,I have looked and searched and looked some more,,but I can not find a lisp that would do the following. I have several (alot) of sheets that have text called out in lineal feet of material in feet-inches, would like to be able to add these all up (text) and come up with a total sum. Have come up with a couple of lisps but they can't handle the inch or fractions of an inch. was wondering if this could be done.

I alway appreciate your help,,,many thanks

BillB

[whdjr]

How is your text displayed?
Is it text? mtext? attribute?
Can you give a screen shot?

[BillB]

Ahhh,,,sorry,,duh,,,will be dtext and it looks like for example  18'-4",,,no spaces. oh, I run Acad 2002 w/XP Pro

[Keith™]

Code: [Select]


(defun c:addvals ( / index repval ss2add total)
  (setq ss2add (ssget)
        index  0
        repval (sslength ss2add)
total 0
  )
  (repeat repval
    (setq total (+ total (distof (cdr (assoc 1 (entget (ssname ss2add index)))))))
    (setq index (1+ index))
  )
  (alert (strcat "Total is: " (rtos total)))
)


[BillB]

Hey,,,thanks Keith,,,works good except if I pick around 15 text strings I get this
"; error: bad argument type: numberp: nil "
Not sure why

BillB

[Keith™]

Chances are you have selected a bit of text that is either not entirely an architectural length, is mtext, or has some other formatting code such as underlining etc.

[CAB]

Yea, just add some error checking & it will overlook most items.

Code: [Select]

(defun c:addvals (/ ss ename total num msg)
  (setq ss    (ssget '((0 . "TEXT")))
        i     -1
        total 0
  )
  (if ss
       (while (setq ename (ssname ss (setq i (1+ i))))
         (if (setq num (distof (cdr (assoc 1 (entget ename)))))
           (setq total (+ total num))
         )
       )
  )
  (cond
    ((null ss)
     (setq msg "    Nothing Selected"))
    ((zerop total)
     (setq msg "      Zero Total"))
    (t
     (setq msg (strcat "   Total is: " (rtos total))))
  )
  (alert msg)
  (princ)
)

[Keith™]

Nice addition CAB ... this program was actually part of a larger routine that I wrote many years ago. In the larger program I had error checking and the data being passed was known. The addition of error checking here will solve most of the problems.

[CAB]

Thanks Keith, I fingered as much.

[BillB]

Hey guys,,,thanks,,seems to work great
except when you have more then one
string that have the same values,,,it
won't count it,,any ideas?

BillB

[BillB]

Oops,,,sorry guys,,,my fault,,,does work,,was a problem with my text,,,had on at 85'-0" and one at 85'-0',,note the dual feet on last one,,,again sorry,,,great job, will come in real handy.

Thanks again

BillB

[ELOQUINTET]

anyway to get this to work with dimension text by any chance  

[Keith™]

Dan I think there is one arouund here somewhere ... I'll see what I can find..