Topic: Update countdown text

[Augusto]

Hello guys!

I'm trying to countdown, but the text does not update. 
Could someone tell me the reason?

Thank you.
Luís Augusto

Code: [Select]

(defun c:countdown

  (/
    start
    time
    insertionPoint
    textString
    height
    textObj
    acadObj
    doc
    modelSpace
  )

  (setq acadObj (vlax-get-acad-object))
  (setq doc (vla-get-ActiveDocument acadObj))
  (setq modelSpace (vla-get-ModelSpace doc))
  (setq insertionPoint (vlax-3d-point 0 0 0)
textString "Time Remaining: 00 seconds."
height        0.5
  )

  (setq textObj     (vla-AddText modelSpace textString insertionPoint height)
timeCounter (*
      30 ;Seconds
      1000.
    )
start     (getvar 'MILLISECS)
  )

  (while (setq time_elapse (< (- (getvar 'MILLISECS) start) timeCounter))
    ;(grread t)
    (or
      (/= textString
  (setq textString (vla-get-textstring textObj))
      )
      (and
(vla-put-textstring
  textObj
  (strcat
    "\nTime Remaining: "
    (rtos (fix(/ (- timeCounter (- (getvar 'MILLISECS) start)) 1000.)) 2 0)
    " seconds"
  )
)
(vla-update textObj)
      )
    )
  )
  (princ)
)
(vl-load-com)


[Augusto]

By implementing the command (grread t) within the loop, the text refreshes when you move the mouse.
Is there another way to do it? 

http://www.theswamp.org/index.php?topic=49381.0

[ribarm]

Untested, but IMHO it should work...

Code: [Select]

(defun c:countdown
  (/
    start
    time
    insertionPoint
    textString
    height
    textObj
    acadObj
    doc
    modelSpace
  )

  (vl-load-com)

  (setq acadObj (vlax-get-acad-object))
  (setq doc (vla-get-ActiveDocument acadObj))
  (setq modelSpace (vla-get-ModelSpace doc))
  (setq insertionPoint (vlax-3d-point 0 0 0)
        textString "Time Remaining: 00 seconds."
        height 0.5
  )

  (setq textObj (vla-AddText modelSpace textString insertionPoint height)
        timeCounter (*
                       30 ;Seconds
                       1000.
                    )
        start (getvar 'MILLISECS)
  )

  (while (< (- (getvar 'MILLISECS) start) timeCounter)
    (if (/= (setq textString
          (strcat
            "Time Remaining: "
            (itoa (fix (/ (- timeCounter (- (getvar 'MILLISECS) start)) 1000.)))
            " seconds."
          ))
          (vla-get-textstring textObj)
        )
      (progn
        (vla-put-textstring textObj textString)
        (vla-update textObj)
      )
    )
  )
  (alert "Time limit over...")
  (princ)
)


[Augusto]

Untested, but IMHO it should work...

 'vla-put-textstring returns nil

Sorry guys.
I think I need to have a beer. Cheers! 

Thank you very much again ribarm

[ribarm]

Cheers...
:beer: