Topic: Delete Invisible Dynamic Blocks ==> Error Message

[Bluebird1973]

Hi,

I use this code with AutoCAD 2016 and it work perfect but we get the AutoCAD 2018 and the last few days I receive this message:

** Error: Automation Error. Description was not provided. **

Code: [Select]

(defun c:delinvb (/ acdoc ss i sset nme Blockdefinition)
  (vl-load-com)
  (setq acdoc (vla-get-activedocument
                (vlax-get-acad-object)
              )
  )
  (if (setq ss (ssget "_:L" '((0 . "INSERT"))))
    (repeat
      (setq i (sslength ss))
      (setq sset (ssname ss (setq i (1- i))))
      (setq nme (cdr (assoc 2 (entget sset))))
      (setq Blockdefinition (vla-item (vla-get-blocks acdoc) nme))
      (if
        (and
          (eq :vlax-false (vla-get-isxref Blockdefinition))
          (eq :vlax-false (vla-get-islayout Blockdefinition))
        )
          (vlax-for x Blockdefinition
       (if(=(vla-get-Visible  x) :vlax-false)
        (vla-delete x)
    )
)
      )
    )
    (princ)
  )
  (vla-regen acdoc acAllViewports)
  (princ)
)


Could somebody help me to figure out what happens ?

(I found this code here http://www.theswamp.org/index.php?topic=32681.msg495238#msg495238)

Kind regards
Bluebird1973

[ronjonp]

Try this:

Code - Auto/Visual Lisp: [Select]

1. (defun c:foo (/ a c d n)
2.   ;; RJP » 2018-08-02
3.   ;; Deletes objects in blocks that are not visible
4.   (vlax-for l (vla-get-layers (setq d (vla-get-activedocument (vlax-get-acad-object))))
5.     (cond ((= -1 (vlax-get l 'lock)) (vlax-put l 'lock 0) (setq a (cons l a))))
6.   )
7.   (vlax-for b (vla-get-blocks d)
8.     (if (and (= 0 (vlax-get b 'islayout))
9.              (= 0 (vlax-get b 'isxref))
10.              (not (wcmatch (setq c (vla-get-name b)) "*|*"))
11.         )
12.       (vlax-for o b
13.         (cond ((and (vlax-write-enabled-p o) (= 0 (vlax-get o 'visible)))
14.                (setq n (vla-get-objectname o))
15.                (vla-delete o)
16.                (print (strcat "Deleting: " n " from " c))
17.               )
18.         )
19.       )
20.     )
21.   )
22.   (foreach l a (vlax-put l 'lock -1))
23.   (vla-regen d acallviewports)
24.   (princ)
25. )
26. (vl-load-com)