Topic: trigger a lisp command after "plotting"

[dubb]

is there a way to trigger another lisp command after running the plot command?

[Jeff_M]

Sure, use the :vlr-commandended event of the Editor reactor and watch for the "Plot" command command.

[dubb]

HUH..?..IM UNFAMILIAR ON HOW TO USE THESE REACTORS...

[Jeff_M]

OK, I couldn't recall if you had worked with reactors before. Here's an example for you:

Code: [Select]


(or jmm:plot_reactor
    (setq jmm:plot_reactor (vlr-editor-reactor nil '((:vlr-commandEnded . jmm:cmdEnd)))))

(defun jmm:cmdEnd (calling cmd)
  (princ ".....made it here....");remove this, just for testing....
  (cond ((eq "PLOT" (strcase (car cmd))) (jmm:testlisp))
;you could add other commands to track and do other things here
)
  (princ)
  )

(defun jmm:testlisp ()
  (princ "Command was PLOT")
  ;modify the line above to call the desired lisp
  ;NOTE! The lisp you call must NOT use the Command function!
  )

[dubb]

oOO..MAN..that worked perfect..thanks Jeff

[daron]

Just make sure you obey the NO COMMAND in the lisp you put that in.

[JohnK]

" (or jmm:plot_reactor
    (setq jmm:plot_reactor (vlr-editor-reactor nil '((:vlr-commandEnded . jmm:cmdEnd))))) "

...Nice trick Jeff.


Edit: Darn button!?

Thats "clean" I like that.