Topic: How to display an end point

[lamarn]

Super ! thanks mr. Lee
updated my code in the above.
This doesn't work..(?)

(cond
..
 (= "ARC" (cdr (assoc 0 (setq enx (entget ent))))))

[Lee Mac]

I would suggest studying the documentation for the cond function - you are using the wrong syntax.

[lamarn]

Got it to work, except the properties don't show.
*edit: it does now*

Code: [Select]


(defun c:showSE (/ ent enx)

 (load "GrTextV1-1.lsp") ; Lee Mac

  ;; Display GrText  -  Lee Mac
  ;; pnt  -  cursor point in UCS
  ;; vec  -  GrText vector list
  ;; col  -  Text Colour (ACI Colour)
  ;; xof  -  x-offset from cursor in pixels
  ;; yof  -  y-offset from cursor in pixels
  (if (and (setq ent (car (entsel "\nSelect a (poly)line: ")))
   (or
     (= "LWPOLYLINE" (cdr (assoc 0 (setq enx (entget ent)))))
     (= "LINE" (cdr (assoc 0 (setq enx (entget ent)))))
     (= "ARC" (cdr (assoc 0 (setq enx (entget ent)))))
     (= "SPLINE" (cdr (assoc 0 (setq enx (entget ent)))))
     (= "POLYLINE" (cdr (assoc 0 (setq enx (entget ent)))))
   )
      )
    (progn

      (LM:grx (trans (cdr (assoc 10 enx)) ent 0) 5 3)
      (LM:grx (trans (cdr (assoc 10 (reverse enx))) ent 0) 5 1)
      (setq ptS (vlax-curve-getStartPoint ent))
      (setq ptE (vlax-curve-getEndPoint ent))
      (LM:grx ptS 5 3)
      (LM:grx ptE 5 1)
      (LM:DisplayGrText ptS (LM:GrText (strcat "S")) 3 10 -25)
      (LM:DisplayGrText ptE (LM:GrText (strcat "E")) 1 10 -25)
      (setq ptS nil)
      (setq ptE nil)
      (sssetfirst nil (ssadd ent (ssadd)))
    )
   
  )
 ; (princ)
)


[ronjonp]

Instead of the command call, use this:

Code: [Select]

(sssetfirst nil (ssadd ent (ssadd)))

[lamarn]

Thank you ronjomp!

[ronjonp]

You're welcome

[dubb]

Got it to work, except the properties don't show.
*edit: it does now*

Looks beautiful!

[roy_043]

@Hans:
IMO these lines can be removed:

Code: [Select]

      (LM:grx (trans (cdr (assoc 10 enx)) ent 0) 5 3)
      (LM:grx (trans (cdr (assoc 10 (reverse enx))) ent 0) 5 1)And there are some issues regarding coordinate systems.

[lamarn]

You're right, Roy.
It's only noice in my case.
Thanks for improvements!

[Grrr1337]

Hans, you could shorten the evaluations within the and function:

Code: [Select]

(and
  (setq ent (car (entsel "\nSelect a (poly)line: ")))
  (member (cdr (assoc 0 (setq enx (entget ent)))) '("LWPOLYLINE" "LINE" "ARC" "SPLINE" "POLYLINE"))
  (not (vlax-curve-isClosed ent)) ; so it will be an open curve
)

[lamarn]

Aha. Member! A lot more professional .. credits to yo all

[roy_043]

@Lee:
I wonder if your LM:grx function is correct. Shouldn't it be?:

Code: [Select]

;; grX  -  Lee Mac
;; p - [lst] WCS point at which to display 'X'
;; s - [int] size of point (in pixels)
;; c - [int] ACI colour of point
;; Returns supplied WCS point.

(defun LM:grx (p s c / -s r q)
  (setq r  (/ (getvar 'viewsize) (cadr (getvar 'screensize)))
        q  (trans p 0 1) ; <------- Modified
        -s (- s)
  )
  (grvecs
    (list c
    (list -s -s)
    (list s s)
    (list -s (1+ -s))
    (list (1- s) s)
    (list (1+ -s) -s)
    (list s (1- s))
    (list -s s)
    (list s -s)
    (list -s (1- s))
    (list (1- s) -s)
    (list (1+ -s) s)
    (list s (1+ -s))
    )
    (list
      (list r 0. 0. (car q))
      (list 0. r 0. (cadr q))
      (list 0. 0. r (caddr q)) ; <------- Modified
      (list 0. 0. 0. 1.)
    )
  )
  p
)
Something similar applies to the LM:displaygrtext function that Hans uses in his code.

[Lee Mac]

@Lee:
I wonder if your LM:grx function is correct. Shouldn't it be?:

Code: [Select]

< ... >
Something similar applies to the LM:displaygrtext function that Hans uses in his code.

No, as the vector graphics should be displayed relative to the display (DCS), regardless of UCS/View.

[roy_043]

Thanks for your answer Lee. Hans has started a related thread on the BricsCAD forum and it seems that BC is incompatible here:

There is a known incompatible behavior with the (grvecs) function in BricsCAD. On Acad it accepts DCS coordinates, in BricsCAD UCS.

[Lee Mac]

Thanks for your answer Lee. Hans has started a related thread on the BricsCAD forum and it seems that BC is incompatible here:

There is a known incompatible behavior with the (grvecs) function in BricsCAD. On Acad it accepts DCS coordinates, in BricsCAD UCS.

Thanks Roy - that clears things up.