Topic: Challenge: Matrix Code Scroll

[Dommy2Hotty]

I'm trying to make a Matrix-style code scroll.  I use a half screen text window (for the command line) and I'd like to make it look like the Matrix code when I walk away from my desk (either by a manual start or an idle reactor).

Here's what I have so far as a test (proof of concept, the characters I used are just placeholders for now):

Code: [Select]

(defun c:Matrix ()
  (setq Line1 "\n ,<  ^>~  #\|~~   *  *   *")
  (setq Line2 "\n ~~   *  *   * 8?  @!")
  (setq Line3 "\n 8?  @! ,<  ^>~  #\|")
  (repeat 5000
    (princ Line1)
    (princ Line2)
    (princ Line3)
    )
  (princ)
  )
Problems:  Runs too fast and is over in 2 seconds.

Ready...

Set...

Go!!!

[MP]

Code: [Select]

(defun c:Matrix ( / _Random _Foo _Bar olderr )

    (defun _Random ( seed )

        ;;  Original version attributable to Paul Kahut who translated an
        ;;  algorythm from a Visual C 4.1 library. Generates a pseudo
        ;;  random integer, 0-32767. Pass an integer to seed the generator
        ;;  expressly, otherwise seed using the timer (seed code by MP).
        ;;  Sample calls: (_Random nil) >> 14591 (_Random 42) >> 175
        ;;  *WILL GENERATE THE SAME SEQUENCE FOR A GIVEN SEED* << a good
        ;;  or bad thing depending upon your persective.

        (boole 1 32767
            (   /
                (setq *random:seed*
                    (+
                        (*  214013
                            (fix
                                (cond
                                    ((numberp seed) seed)
                                    ((numberp *random:seed*) *random:seed*)
                                    ((getvar "millisecs"))
                                )
                            )
                        )
                        2531011
                    )
                )
                65536
            )
        )
    )

    (defun _Foo ( )
        (   (lambda ( i j / b )
                (repeat (1+ j)
                    (setq
                        b (cons (if (zerop (logand i (expt 2 j))) 0 1) b)
                        j (1- j)
                    )
                )
                (reverse b)
            )
            (_Random nil)
            15   
        )           
    )
   
    (defun _Bar ( )
        (mapcar 'princ (append (_Foo) (_Foo) (_Foo) (_Foo)))
        (princ "\n")
        (princ)
    )
   
    (setq olderr *error*)
   
    (defun *error* ( m ) (setq *error* olderr) (princ))

    (_Random 42)

    (while t (_Bar))

    (princ)

)
Hit [Esc] to stop.

[Dommy2Hotty]

Hit [Esc] to stop.

AWESOME!!! That works for me!!!

Thanks, MP!

[MP]

Modified, looks better.

[Dommy2Hotty]

Modified, looks better.

I never saw the original, although I've searched.

Here's on my machine:

[Dommy2Hotty]

(_Random 42)

The answer to life, the universe, everything...

[Mark]

Code: [Select]

(defun c:Matrix ( / _Random _Foo _Bar olderr )
)Hit [Esc] to stop.

crash and burn on C3D2017 lol

[Lee Mac]

Another -

Code: [Select]

(defun c:matrix ( / c w )
    (setq c (getvar 'cmdecho)
          w 64
    )
    (setvar 'cmdecho 0)
    (vl-catch-all-apply
       '(lambda ( / l )
            (while t
                (setq l nil)
                (repeat (LM:randrange 0 w) (setq l (cons " " l)))
                (repeat (- w (length l))   (setq l (cons (strcat "\\U+30" (LM:dec->hex (LM:randrange 65 255))) l)))
                (princ (apply 'strcat (cons "\n" (LM:shuffle l))))
                (princ)
                (vl-cmdf "_.delay" 50)
            )
        )
    )
    (setvar 'cmdecho c)
    (princ)
)

(defun LM:shuffle ( l / i n r )
    (repeat (setq n (length l))
        (setq r (cons (nth (setq i (LM:randrange 0 (setq n (1- n)))) l) r)
              l (LM:removenth i l)
        )
    )
    r
)
 
(defun LM:removenth ( n l )
    (if (and l (< 0 n))
        (cons (car l) (LM:removenth (1- n) (cdr l)))
        (cdr l)
    )
)

(defun LM:dec->hex ( n )
    (cond
        (   (< n 10) (itoa n))
        (   (< n 16) (chr (+ n 55)))
        (   (strcat  (LM:dec->hex (/ n 16)) (LM:dec->hex (rem n 16))))
    )
)

;; Rand  -  Lee Mac
;; PRNG implementing a linear congruential generator with
;; parameters derived from the book 'Numerical Recipes'

(defun LM:rand ( / a c m )
    (setq m   4294967296.0
          a   1664525.0
          c   1013904223.0
          $xn (rem (+ c (* a (cond ($xn) ((getvar 'date))))) m)
    )
    (/ $xn m)
)

;; Random in Range  -  Lee Mac
;; Returns a pseudo-random integral number in a given range (inclusive)

(defun LM:randrange ( a b )
    (+ (min a b) (fix (* (LM:rand) (1+ (abs (- a b))))))
)

(princ)

[Dommy2Hotty]

Another

More matrix looking!  but...I can't stop it!

[MP]

Code: [Select]

(defun c:Matrix ( / *error* s )
    (defun *error* (x) (princ))
    (setq s (getvar "millisecs"))
    (while (princ "\n")
        (repeat 40
            (princ
                (strcat " \\U+6"
                    (itoa
                        (+ 100
                            (logand 899
                                (   /
                                    (setq s (+ (* 214013 s) 2531011))
                                    65536
                                )
                            )
                        )
                    )
                )
            )
        )
    )
)

[Lee Mac]

Nice 

A version for 'dingbats' 

Code: [Select]

(defun c:Matrix ( / *error* s )
    (defun *error* (x) (princ))
    (setq s (getvar "millisecs"))
    (while (princ "\n")
        (repeat 40
            (princ
                (strcat " \\U+27"
                    (itoa
                        (+ 10
                            (logand 89
                                (   /
                                    (setq s (+ (* 214013 s) 2531011))
                                    65536
                                )
                            )
                        )
                    )
                )
            )
        )
        (princ)
    )
)

[MP]

Fun!

[Dommy2Hotty]

Fun!

Very fun...I'm going to watch the code run later to learn a little bit more from you both! Thank you!

[MP]

Probably my fav ...

Code: [Select]

(defun c:Matrix ( / *error* s h l n )
    (defun *error* (x) (princ))
    (setq
        s  42
        h '("0" "1" "2" "3" "4" "5" "6" "7" "8" "9" "A" "B" "C" "D" "E" "F")
        l  (apply 'append (mapcar '(lambda (p) (mapcar '(lambda (s) (strcat p s)) h)) h))
        n  (length l)       
    )
    (while (princ "\n")
        (repeat 40
            (princ
                (strcat " \\U+28"
                    (setq h
                        (nth
                            (rem
                                (abs
                                    (   /
                                        (setq s (+ (* 214013 s) 2531011))
                                        65536
                                    )
                                )
                                n
                            )
                            l
                        )
                    )
                )
            )
        )
    )
)

[ronjonp]

Probably my fav ...

Code: [Select]

(defun c:Matrix ( / *error* s h l n )
    (defun *error* (x) (princ))
    (setq
        s  42
        h '("0" "1" "2" "3" "4" "5" "6" "7" "8" "9" "A" "B" "C" "D" "E" "F")
        l  (apply 'append (mapcar '(lambda (p) (mapcar '(lambda (s) (strcat p s)) h)) h))
        n  (length l)       
    )
    (while (princ "\n")
        (repeat 40
            (princ
                (strcat " \\U+28"
                    (setq h
                        (nth
                            (rem
                                (abs
                                    (   /
                                        (setq s (+ (* 214013 s) 2531011))
                                        65536
                                    )
                                )
                                n
                            )
                            l
                        )
                    )
                )
            )
        )
    )
)

Cool 

⡖ ⠋ ⣏ ⠏ ⠖ ⡦ ⡾ ⡼ ⠠ ⠓ ⣰ ⢽ ⡥ ⠶ ⣄ ⣵ ⡭ ⡟ ⡻ ⡰ ⡆ ⡄ ⣀ ⣿ ⠃ ⢕ ⡄ ⡙ ⠀ ⠝ ⣵ ⠹ ⡷ ⡨ ⣆ ⠶ ⢺ ⡆ ⡒ ⢚
⢵ ⣿ ⣾ ⢯ ⡪ ⡡ ⡘ ⣲ ⢋ ⢍ ⡅ ⣚ ⡓ ⣮ ⡙ ⢃ ⢶ ⢮ ⠤ ⡉ ⣳ ⠋ ⠗ ⡈ ⢻ ⠞ ⢽ ⡎ ⡾ ⡉ ⢗ ⠵ ⡕ ⣎ ⡷ ⣛ ⢋ ⣳ ⠅ ⠡
⢧ ⡋ ⣾ ⣓ ⣾ ⠨ ⣼ ⡨ ⡒ ⣵ ⢅ ⢏ ⡵ ⣖ ⡵ ⠤ ⢺ ⠜ ⢥ ⠘ ⢻ ⣥ ⠦ ⠕ ⡦ ⢈ ⡱ ⠭ ⢐ ⢼ ⢹ ⢹ ⡟ ⣲ ⢐ ⣪ ⡰ ⡭ ⢽ ⢊
⣖ ⢈ ⡞ ⢾ ⡟ ⣿ ⡄ ⠆ ⡿ ⢓ ⠥ ⣜ ⣛ ⣏ ⣵ ⠁ ⢑ ⣉ ⠅ ⢌ ⡪ ⡽ ⣑ ⠍ ⣴ ⢒ ⠞ ⡗ ⣡ ⠳ ⣃ ⡳ ⢒ ⠒ ⠖ ⠟ ⣴ ⠖ ⢃ ⠤
⠻ ⠖ ⡃ ⢊ ⠜ ⠄ ⠾ ⣂ ⡾ ⣞ ⢴ ⢾ ⢤ ⣌ ⣯ ⠄ ⡃ ⠹ ⠤ ⡒ ⣉ ⠌ ⠗ ⣖ ⣦ ⢜ ⠱ ⠅ ⢣ ⠊ ⡤ ⡇ ⡨ ⠠ ⠸ ⣺ ⣢ ⣱ ⢘ ⣟
⣔ ⡴ ⢣ ⢓ ⡄ ⣝ ⢕ ⠨ ⣭ ⣺ ⢚ ⢼ ⠡ ⠤ ⣖ ⢞ ⢃ ⣓ ⡏ ⢗ ⡀ ⠤ ⣵ ⠆ ⠺ ⢔ ⢯ ⡍ ⠂ ⣅ ⠥ ⠜ ⠼ ⡂ ⡎ ⠳ ⢍ ⠌ ⡇ ⢔
⡋ ⠰ ⢙ ⢰ ⠾ ⣀ ⡧ ⣡ ⡓ ⣍ ⡛ ⣂ ⢻ ⣓ ⣏ ⣠ ⠱ ⢆ ⣅ ⠙ ⢨ ⡝ ⣽ ⣓ ⡝ ⠍ ⣅ ⣌ ⢧ ⣬ ⠏ ⢂ ⠽ ⡑ ⠷ ⠽ ⢀ ⡃ ⠊ ⢍
⣏ ⡻ ⢒ ⣊ ⠓ ⢔ ⢋ ⢜ ⠇ ⣘ ⣲ ⣞ ⡉ ⠝ ⣅ ⡇ ⣠ ⣳ ⣇ ⣰ ⣤ ⢾ ⠫ ⠩ ⣌ ⡯ ⢍ ⣍ ⠶ ⣬ ⢅ ⣜ ⠽ ⢤ ⡢ ⣈ ⡕ ⣤ ⡀ ⣻
⡢ ⢸ ⣭ ⣢ ⣹ ⢭ ⠇ ⢦ ⡬ ⠂ ⡟ ⡖ ⣦ ⡩ ⣾ ⣁ ⠼ ⢓ ⡌ ⣗ ⡄ ⢻ ⣠ ⠘ ⢲ ⢦ ⠃ ⠻ ⣍ ⡚ ⣻ ⣞ ⡋ ⣞ ⡄ ⠺ ⣸ ⣋ ⡡ ⢀
⡕ ⠱ ⠶ ⢶ ⣟ ⣝ ⠅ ⢂ ⠀ ⣄ ⠾ ⢌ ⠖ ⠭ ⡢ ⡛ ⡗ ⡹ ⢶ ⠦ ⣑ ⢡ ⠌ ⣳ ⡪ ⠜ ⠏ ⠭ ⢊ ⠐ ⢖ ⣲ ⢾ ⢙ ⢍ ⣉ ⠮ ⠕ ⡾ ⡚
⣖ ⠊ ⣏ ⡐ ⡪ ⠞ ⢩ ⣿ ⢴ ⠔ ⠯ ⣩ ⡛ ⢗ ⣝ ⠋ ⢮ ⢯ ⢙ ⠄ ⢇ ⡯ ⡇ ⡺ ⠥ ⠽ ⣃ ⢺ ⠃ ⢉ ⣶ ⢞ ⢣ ⡭ ⠊ ⢴ ⡦ ⢱ ⡝ ⢜
⡄ ⡰ ⢗ ⢲ ⠈ ⣘ ⣕ ⣮ ⢧ ⣥ ⢟ ⣷ ⠷ ⣗ ⣦ ⠠ ⣢ ⠣ ⡽ ⠛ ⢎ ⡏ ⣈ ⠑ ⡃ ⣶ ⢴ ⣨ ⣍ ⠒ ⠘ ⣺ ⠺ ⡻ ⡪ ⢂ ⠱ ⢪ ⢣ ⢜
⣘ ⠼ ⣨ ⡾ ⣛ ⠬ ⡴ ⠗ ⢱ ⡕ ⣤ ⢢ ⡋ ⣼ ⡞ ⡻ ⡹ ⡓ ⠖ ⠴ ⠈ ⣉ ⡒ ⠞ ⠩ ⢵ ⢎ ⢒ ⣷ ⡫ ⠥ ⠳ ⣖ ⡓ ⢢ ⡎ ⢋ ⣨ ⠿ ⡟
⣀ ⣛ ⣿ ⡨ ⣮ ⣺ ⣠ ⢤ ⣍ ⡧ ⣦ ⣟ ⠢ ⡟ ⠙ ⠙ ⣀ ⢸ ⣭ ⣆ ⠳ ⣠ ⡈ ⣙ ⢡ ⢜ ⠙ ⠗ ⡰ ⡟ ⢚ ⣵ ⢑ ⢻ ⠒ ⢽ ⢹ ⣳ ⡲ ⡔
⢿ ⣀ ⡜ ⣌ ⣴ ⢤ ⡭ ⡩ ⡠ ⠸ ⢑ ⡅ ⡂ ⣑ ⢣ ⠄ ⢛ ⢦ ⢓ ⡪ ⡍ ⡽ ⠴ ⢱ ⠘ ⠀ ⣄ ⠕ ⣥ ⡌ ⠾ ⡒ ⣻ ⠮ ⡢ ⢉ ⡕ ⡅ ⢀ ⡤
⣣ ⢑ ⣸ ⡜ ⢓ ⣊ ⠯ ⢕ ⢓ ⡺ ⠪ ⢀ ⡸ ⣩ ⢤ ⣡ ⢭ ⢯ ⡢ ⠦ ⠍ ⡤ ⢌ ⡧ ⡅ ⠕ ⣰ ⠎ ⣡ ⡙ ⢵ ⢊ ⠡ ⡙ ⢊ ⡩ ⣧ ⣐ ⡦ ⢡
⡯ ⣠ ⣴ ⡲ ⣪ ⠚ ⡻ ⣧ ⡖ ⠮ ⡯ ⢪ ⢖ ⢚ ⠏ ⡛ ⠪ ⠅ ⡽ ⣬ ⣙ ⠅ ⢥ ⠿ ⢎ ⡧ ⠳ ⣘ ⡥ ⣓ ⠃ ⠐ ⠆ ⢝ ⠋ ⡷ ⣍ ⢉ ⡫ ⢙
⢛ ⢐ ⢶ ⡘ ⣹ ⣋ ⢟ ⣶ ⡚ ⢗ ⠽ ⡐ ⡆ ⣪ ⠗ ⢼ ⠬ ⡗ ⠚ ⣟ ⠶ ⣐ ⠬ ⢷ ⡤ ⣽ ⢅ ⣵ ⡵ ⢮ ⣰ ⠮ ⣊ ⢐ ⠥ ⣨ ⡂ ⢏ ⣪ ⠀
⡾ ⣃ ⠈ ⢁ ⢪ ⠢ ⠖ ⠷ ⢩ ⢝ ⢨ ⠧ ⡾ ⡄ ⢌ ⢋ ⠈ ⡆ ⢄ ⠿ ⠡ ⣿ ⢭ ⠡ ⡴ ⠽ ⠉ ⠓ ⡥ ⣿ ⠸ ⢿ ⣂ ⡼ ⠵ ⡓ ⠫ ⡧ ⠸ ⣪
⢾ ⡲ ⠂ ⡜ ⡯ ⠑ ⡉ ⠻ ⠼ ⢀ ⠆ ⢏ ⢒ ⣸ ⣇ ⠞ ⡺ ⡽ ⡁ ⢏ ⣗ ⠋ ⣲ ⢀ ⢿ ⠲ ⢒ ⢉ ⢡ ⠏ ⢓ ⣴ ⢴ ⠡ ⣌ ⢱ ⣗ ⡁ ⢿ ⢚
⡘ ⢳ ⣃ ⣥ ⡃ ⠎ ⠪ ⡰ ⡡ ⡘ ⠞ ⣩ ⣪ ⣄ ⢁ ⢅ ⠮ ⡥ ⣘ ⣗ ⡱ ⡞ ⠒ ⠪ ⠟ ⠕ ⠂ ⠠ ⠬ ⠬ ⣄ ⢹ ⡊ ⣨ ⠶ ⣦ ⢂ ⡆ ⠜ ⠾
⣆ ⠩ ⡛ ⢠ ⡷ ⣨ ⡅ ⠚ ⢰ ⣡ ⣳ ⣶ ⠴ ⣛ ⣛ ⡽ ⣩ ⡢ ⡸ ⠎ ⡦ ⠧ ⠧ ⣿ ⡕ ⠧ ⣳ ⢻ ⠌ ⡲ ⢤ ⠎ ⢢ ⣿ ⣭ ⠢ ⢪ ⠨ ⡐ ⣺
⢑ ⡤ ⢦ ⡣ ⠯ ⣱ ⢈ ⠼ ⡸ ⣿ ⣚ ⡬ ⡞ ⢩ ⠕ ⠂ ⡯ ⡶ ⠩ ⡔ ⡼ ⢱ ⡛ ⡱ ⣎ ⠢ ⣯ ⣨ ⡝ ⠊ ⠥ ⣯ ⣰ ⠿ ⠦ ⢃ ⢓ ⡿ ⢰ ⢴
⣋ ⣦ ⣬ ⠦ ⠔ ⣕ ⣬ ⡸ ⢾ ⠠ ⡓ ⣿ ⣰ ⠒ ⣙ ⡹ ⣀ ⢊ ⣚ ⠈ ⢙ ⠆ ⠍ ⣾ ⣃ ⢷ ⡴ ⢞ ⣎ ⡈ ⣪ ⠟ ⠹ ⠍ ⢶ ⡿ ⠙ ⣛ ⡪ ⢨
⢌ ⢖ ⢦ ⠀ ⣗ ⢠ ⡉ ⣷ ⠤ ⠮ ⡃ ⢆ ⢷ ⣤ ⣐ ⢡ ⢜ ⠪ ⢠ ⣰ ⢸ ⠽ ⣐ ⠵ ⠪ ⡬ ⡩ ⡘ ⠦ ⣲ ⡍ ⣆ ⢬ ⠜ ⠣ ⣳ ⣻ ⣀ ⡵ ⢎
⠷ ⣸ ⢄ ⢪ ⠣ ⠖ ⣗ ⡇ ⣘ ⡟ ⢃ ⠗ ⠪ ⡦ ⣸ ⡽ ⣵ ⣽ ⣯ ⡦ ⡻ ⡞ ⡼ ⠈ ⡫ ⣾ ⢚ ⣜ ⡂ ⡅ ⣭ ⠑ ⠯ ⠍ ⠁ ⢼ ⠆ ⣛ ⡶ ⣱
⡨ ⠡ ⣆ ⠀ ⣼ ⡔ ⠃ ⣽ ⠍ ⡉ ⣑ ⢝ ⣗ ⢎ ⢊ ⢨ ⣔ ⠟ ⢤ ⠨ ⠫ ⠨ ⢈ ⡉ ⡈ ⣈ ⠴ ⣻ ⡸ ⢗ ⢲ ⢕ ⡽ ⢡ ⣮ ⣯ ⠄ ⠊ ⢍ ⣟
⡺ ⢏ ⣯ ⣻ ⠈ ⣨ ⠠ ⣝ ⠔ ⡿ ⠪ ⡖ ⢉ ⢞ ⠿ ⣾ ⣶ ⢁ ⠁ ⣊ ⠰ ⣶ ⡲ ⢖ ⢿ ⢞ ⡍ ⡮ ⣢ ⠄ ⠌ ⡡ ⣥ ⡽ ⡼ ⠅ ⢽ ⡯ ⠜ ⣠
⣻ ⠧ ⠕ ⠖ ⠺ ⢗ ⢠ ⣸ ⣍ ⣚ ⡆ ⡕ ⣺ ⣉ ⡏ ⢧ ⢅ ⣍ ⢟ ⣉ ⠜ ⣶ ⠗ ⢺ ⢊ ⡺ ⢦ ⣣ ⣿ ⣱ ⣿ ⠘ ⠲ ⠡ ⢴ ⠧ ⢿ ⡋ ⠑ ⣾
⢪ ⢽ ⠋ ⠑ ⢭ ⢙ ⠞ ⡹ ⣘ ⣗ ⣋ ⠁ ⣜ ⢍ ⡷ ⠢ ⣁ ⢑ ⡮ ⠁ ⡦ ⡮ ⡦ ⣓ ⢞ ⡵ ⡉ ⢔ ⠑ ⢾ ⣻ ⠥ ⢷ ⢯ ⠐ ⠢ ⣞ ⠓ ⣁ ⠾
⣾ ⡚ ⢯ ⡿ ⠲ ⣧ ⢩ ⠮ ⣣ ⡢ ⠋ ⢓ ⡟ ⣺ ⣤ ⣥ ⠯ ⣖ ⠽ ⣪ ⢢ ⣾ ⣇ ⢭ ⡐ ⠙ ⣞ ⡪ ⣐ ⡍ ⢅ ⠈ ⢞ ⠽ ⢻ ⡯ ⣸ ⣏ ⡆ ⣿
⡇ ⢢ ⡐ ⠕ ⣔ ⢴ ⠔ ⡌ ⢻ ⢸ ⠸ ⢜ ⡏ ⠔ ⠤ ⣐ ⡪ ⢇ ⢎ ⣝ ⢮ ⢾ ⠹ ⠚ ⢩ ⠘ ⠿ ⢈ ⣹ ⡟ ⣦ ⣦ ⢺ ⡧ ⢚ ⢴ ⠫ ⡅ ⡳ ⢙
⡉ ⠩ ⣁ ⣊ ⣳ ⣾ ⡞ ⣇ ⣂ ⣃ ⠸ ⡽ ⢈ ⡒ ⠛ ⡑ ⣒ ⢜ ⣝ ⡾ ⠲ ⠬ ⠠ ⡅ ⠶ ⡷ ⠕ ⣽ ⣍ ⣈ ⣦ ⠂ ⠙ ⠠ ⡶ ⡃ ⢿ ⡐ ⡿ ⣈
⢍ ⣳ ⣴ ⡬ ⡡ ⠇ ⣡ ⠄ ⢺ ⢫ ⡎ ⣭ ⡗ ⣠ ⢎ ⢶ ⢍ ⣉ ⡘ ⡉ ⠞ ⠒ ⢸ ⣁ ⠽ ⢖ ⢐ ⡅ ⢎ ⢊ ⣟ ⣲ ⢰ ⠀ ⠥ ⡧ ⡅ ⣨ ⡦ ⣆
⡊ ⠆ ⡕ ⣳ ⡋ ⠾ ⣇ ⠒ ⢰ ⣎ ⠃ ⡷ ⡰ ⢣ ⡤ ⣳ ⢆ ⢃ ⣄ ⠌ ⡞ ⣉ ⠨ ⣌ ⢠ ⣠ ⣾ ⢾ ⠅ ⡾ ⢋ ⢡ ⢔ ⢫ ⣡ ⠢ ⣦ ⢙ ⢜ ⣻
⣗ ⠶ ⠒ ⣏ ⣾ ⡠ ⠧ ⣢ ⣙ ⠠ ⡲ ⠆ ⠡ ⣜ ⣂ ⣀ ⣪ ⡱ ⡼ ⢖ ⢧ ⡐ ⣛ ⡩ ⢅ ⣄ ⡭ ⢆ ⠀ ⠰ ⠆ ⠹ ⡓ ⢘ ⡅ ⡧ ⡜ ⡢ ⠊ ⠫
⢛ ⡞ ⠝ ⣊ ⣉ ⠅ ⠕ ⡡ ⣊ ⣾ ⢈ ⣙ ⣇ ⠘ ⣋ ⣋ ⡔ ⢮ ⣮ ⢨ ⡲ ⣳ ⣜ ⢎ ⠨ ⢦ ⠛ ⠜ ⠴ ⣑ ⢛ ⢐ ⣏ ⣂ ⣛ ⠷ ⠇ ⠸ ⡶ ⠟
⣖ ⠰ ⣴ ⠽ ⢍ ⠶ ⠗ ⣾ ⡻ ⣻ ⠚ ⣺ ⠔ ⢷ ⡸ ⡩ ⠀ ⠄ ⡹ ⢡ ⢋ ⡵ ⡍ ⠟ ⣁ ⣆ ⢐ ⣇ ⢽ ⠂ ⢆ ⠄ ⡯ ⠔ ⠔ ⡼ ⣝ ⢀ ⡠ ⠺
⢹ ⣤ ⣿ ⠴ ⡂ ⢹ ⡰ ⣪ ⣎ ⢠ ⢠ ⡰ ⡿ ⣾ ⣒ ⢊ ⣢ ⠀ ⣦ ⢚ ⡿ ⠣ ⡴ ⢔ ⡐ ⡚ ⣭ ⢲ ⡑ ⢔ ⣼ ⡈ ⠎ ⣹ ⡼ ⣰ ⢺ ⡧ ⠁ ⢻
⣩ ⢜ ⢀ ⣑ ⣪ ⣭ ⢒ ⢨ ⣛ ⣳ ⢍ ⡩ ⢉ ⢡ ⡄ ⢦ ⢐ ⣚ ⡦ ⡩ ⢧ ⢋ ⣇ ⡑ ⠪ ⡌ ⡰ ⢾ ⡺ ⣞ ⡧ ⢦ ⣺ ⣷ ⣂ ⠋ ⡞ ⡏ ⢌ ⠏
⢫ ⢧ ⣹ ⣭ ⠵ ⠊ ⣃ ⠛ ⢻ ⡓ ⣑ ⢆ ⢶ ⠐ ⢖ ⢪ ⠍ ⠛ ⣳ ⡻ ⡔ ⠒ ⡗ ⢎ ⢩ ⡆ ⣰ ⢗ ⢁ ⠼ ⡗ ⡺ ⣴ ⠥ ⡤ ⣝ ⢢ ⢗ ⣴ ⢡
⣘ ⣬ ⣅ ⢡ ⢩ ⡇ ⣽ ⠙ ⢿ ⣊ ⣠ ⡰ ⢋ ⡂ ⢕ ⣥ ⡢ ⣫ ⢱ ⣑ ⡙ ⡢ ⡴ ⢠ ⡤ ⡴ ⢜ ⣱ ⠦ ⣾ ⡈ ⡊ ⡱ ⠆ ⢈ ⢨ ⡠ ⠜ ⡜ ⢘
⠖ ⣻ ⠊ ⠚ ⣾ ⢙ ⠸ ⣊ ⢀ ⢕ ⢘ ⢦ ⣷ ⡇ ⡀ ⢈ ⡌ ⡣ ⢈ ⠞ ⡿ ⢣ ⡲ ⣢ ⢅ ⡿ ⡚ ⣣ ⡓ ⠊ ⠑ ⡜ ⣆ ⡣ ⠱ ⠢ ⡰ ⢕ ⡙ ⠗
⣶ ⡂ ⢾ ⠘ ⡦ ⢊ ⢍ ⡄ ⡒ ⡙ ⣰ ⡥ ⣕ ⣽ ⢏ ⢢ ⢙ ⡳ ⢇ ⡲ ⠑ ⡚ ⠚ ⡀ ⡎ ⡦ ⢁ ⡮ ⠌ ⣓ ⢚ ⠆ ⡔ ⡭ ⣆ ⣌ ⢷ ⡴ ⢋ ⠾
⠡ ⢙ ⣤ ⠶ ⡐ ⢆ ⡴ ⠌ ⠦ ⣝ ⠖ ⢝ ⡧ ⠬ ⡋ ⢥ ⣿ ⣻ ⠼ ⣬ ⢯ ⡙ ⠋ ⣮ ⢺ ⡓ ⠢ ⣶ ⢈ ⠵ ⡓ ⡢ ⢠ ⢂ ⡬ ⠋ ⠖ ⢴ ⢋ ⠣