Author Topic: Help: Adding Prefix to Selected Attribute Text (Read 1036 times)

AVCAD · « **on:** January 19, 2024, 12:15:59 PM »

Hi all,

I found this Lisp from Lee Mac on a separate forum, and it works but it changes all of the attributes where I only want to change the selected attribute or even if its one attribute by the TAG name.

The Tag I need to be changed is called D_ID

This way when i select the text/block it adds the prefix i want to this attribute only.

Code - Auto/Visual Lisp: [Select]

(defun c:test ( / as el en i ss str typ )
 
 (initget "Prefix Suffix")
 (setq typ (cond ((getkword "\nAdd Prefix or Suffix? [Prefix/Suffix] <Prefix>: ")) ("Prefix")))
 (setq str (getstring t (strcat typ " to Add: ")))
 
 (if (setq ss (ssget '((0 . "INSERT") (66 . 1))))
     (repeat (setq i (sslength ss))
         (setq en (ssname ss (setq i (1- i))))
         (while (eq "ATTRIB" (cdr (assoc 0 (setq el (entget (setq en (entnext en)))))))
             (setq as (cdr (assoc 1 el)))
             (if (eq "Prefix" typ)
                 (if (not (wcmatch as (strcat str "*")))
                     (entmod (subst (cons 1 (strcat str as)) (assoc 1 el) el))
                 )
                 (if (not (wcmatch as (strcat "*" str)))
                     (entmod (subst (cons 1 (strcat as str)) (assoc 1 el) el))
                 )
             )
         )
     )
 )
 (princ)
)
 

I found this code here: https://www.cadtutor.net/forum/topic/32354-adding-prefix-or-suffix-to-block-attribute/

Thanks in advance!

edit Kerry : [ code=cadlisp-7 ]

JohnK · « **Reply #1 on:** January 19, 2024, 12:34:59 PM »

Hey, that code is using the RRB_Default Method I've been preaching all these years. Nice!

I digress. If you're picking attributes one at a time I really like a simple attribute editor program a friend wrote. I use it all the time. I wish I saved the link to the original post but it was a very long time ago and I may even have modified the code (very slightly if at all). So, if you want to just pick the attribute and want a simple dialog to change the text, this is a great utility.

Code - Auto/Visual Lisp: [Select]

(defun c:at ( / _ExeFooAtPoint _Foo _EditAttribObject _MakeDCL _Main )
 
    ;;  © Michael Puckett.
 
    (defun _ExeFooAtPoint ( foo pmt hilite / _Hilite result key value done enames )
 
        ;;  ----------------------------------------
        ;;  foo is an arbitrary function that takes
        ;;  one argument, a point. What is does we
        ;;  care not. It is up to foo to ensure it
        ;;  addresses any and all potential errors.
        ;;  ----------------------------------------
        ;;  pmt is a prompt string
        ;;  ----------------------------------------
        ;;  hilight is an entity type match string,
        ;;  e.g. "ATTRIB". The function will hilite
        ;;  matching entities as it goes.
        ;;  ----------------------------------------
 
        (defun _Hilite ( point hilite / ename )
            ;;  uses local global enames
            (cond
                (   (and
                        (setq ename (car (nentselp point)))
                        (not (equal ename (car enames)))
                        (wcmatch
                            (cdr (assoc 0 (entget ename)))
                            hilite
                        )
                    )
                    (redraw ename 3)
                    (setq enames (cons ename enames))
                )
                (   ename
                    (foreach ename (cdr enames) (redraw ename 4))
                    (setq enames (list ename))
                )
                (   t
                    (foreach ename enames (redraw ename 4))
                    (setq enames nil)
                )
            )
        )
 
        (setq hilite (strcase hilite))
 
        (princ pmt)
 
        (while (not done)
            ;;  stay in the loop until the
            ;;  user presses <enter> or <esc>
            (vl-catch-all-apply
               '(lambda ( )
                    (setq
                        result nil
                        result (grread t 13 2)
                    )
                )
            )
            (setq
                key   (car result)
                value (cadr result)
            )
            (cond
                ;;  user pressed <enter> or <esc> exit quietly
                ((member result '(nil (2 13))) (setq done t value nil))
                ;;  user hit right mouse button, consider done
                ((eq 25 key)(setq done t value nil))
                ;;  user picked a point, let's roll
                ((eq 3 key) (foo value))
                ((eq 5 key) (_Hilite value hilite))
            )
        )
 
        (foreach ename enames (redraw ename 4))
 
    )
 
    (defun _Foo ( point / ename data )
        (if (setq ename (car (nentselp point)))
            (if (setq data (entget ename))
                (if (eq "ATTRIB" (cdr (assoc 0 data)))
                    (_EditAttrib (vlax-ename->vla-object ename))
                    (princ "<not an attribute>")
                )
                (princ "<no data for entity>")
 
            )
            (princ "<no entity at point>")
        )
    )
 
    (defun _EditAttrib ( attribObject / _Text _Cancel _Accept text )
 
        ;;  note, uses local global dclid
 
        (defun _Text ( value )
            ;;  update local global
            (setq text value)
        )
 
        (defun _Cancel ( )
            ;;  just bail
            (done_dialog)
        )
 
        (defun _Accept ( )
            ;;  uses local glabal text
            (vla-put-textstring
                attribObject
                text
            )
            (done_dialog)
        )
 
        (new_dialog "EdAtt" dclid)
 
        (set_tile "title"
            (strcat "Edit attribute <"
                (vla-get-tagstring attribObject)
                ">"
            )
        )
 
        (set_tile "text"
            (setq text
                (vla-get-textstring attribObject)
            )
        )
 
        (action_tile "text" "(_Text $value)")
        (action_tile "cancel" "(_Cancel)")
        (action_tile "accept" "(_Accept)")
        (start_dialog)
 
    )
 
    (defun _MakeDCL ( / fname handle )
 
        (setq
            fname  (vl-filename-mktemp "1.dcl")
            handle (open fname "w")
        )
 
        (mapcar '(lambda (x) (write-line x handle))
           '(
                "EdAtt : dialog {"
                "    label = \"Edit Attribute <TagString>\";"
                "    key = \"title\";"
                "    initial_focus = \"text\";"
                "    spacer;"
                "    :   edit_box {"
                "        label = \"Attribute value:\";"
                "        key = \"text\";"
                "        edit_width = 20;"
                "        edit_limit = 2048;"
                "        allow_accept = true;"
                "    }"
                "    spacer;"
                "    ok_cancel;"
                "    spacer;"
                "}"
            )
        )
 
        (close handle)
 
        fname
 
    )
 
    (defun _Main ( / dclname dclid )
        (cond
            (   (setq dclid
                    (load_dialog
                        (setq dclname (_MakeDCL))
                    )
                )
                (_ExeFooAtPoint _Foo "Pick an attribute <esc|enter to end>: " "ATTRIB")
                (unload_dialog dclid)
                (vl-file-delete dclname)
            )
        )
        (princ)
    )
 
    (_Main)
 
)
 

AVCAD · « **Reply #2 on:** January 19, 2024, 02:36:55 PM »

Thanks JohnK.

I like this program but really what i need is something that is predefined just click the text and it adds the prefix to the text there already.

JohnK · « **Reply #3 on:** January 19, 2024, 03:33:56 PM »

Quote from: AVCAD on January 19, 2024, 02:36:55 PM

Thanks JohnK.

I like this program but really what i need is something that is predefined just click the text and it adds the prefix to the text there already.

How long is a string?
I'm sure that can be done but you're being a little vague about what you want. For example, what do you want as a prefix, how many blocks (would this have to happen to all the instances in the whole drawing), etc.. So please take some time and define your problem so people can help you.

AVCAD · « **Reply #4 on:** January 19, 2024, 05:07:24 PM »

Sorry,

I would like to select as many blocks as needed...one, 2 a window...

The block names a all the same which i dont think would matter anyways and the TAG's are all the same D_ID

what I want is to select the blocks and have the prefix be EXISTING and it gets added to all of the tag D_ID 's it finds

I found the below and modified it a little to make it work. seems to be working good right now

Code - Auto/Visual Lisp: [Select]

(defun c:attfix (/ as el en i n pat ss str tag typ i2 ss2 en2 el2 as2 pat2 str2 tag2 n2)
 ;; Change tag to suit
 (setq tag "D_ID")
 (initget "Prefix Suffix")
 (if (and (setq typ (cond ((getkword "\nAdd Suffix or Prefix  <Prefix>: "))
                   ("Prefix")
             )
   )
   (/= "" (setq str (getstring t (strcat typ " to Add: "))))
   (setq ss (ssget ":L" '((0 . "INSERT") (66 . 1))))      
     )
   (repeat (setq i (sslength ss))
     (setq en (ssname ss (setq i (1- i))))
     (while (eq "ATTRIB" (cdr (assoc 0 (setq el (entget (setq en (entnext en)))))))
(setq as  (cdr (assoc 1 el))
      pat (cond ((eq "Prefix" typ) (strcat str as))
                ((strcat as str))
          )
      n   (vl-string-search (strcase str) (strcase as))
)
(if (and (= tag (cdr (assoc 2 el)))
         (or (null n)
             (not (wcmatch (strcase as)
                           (strcase (cond ((= 0 n) (strcat str "*"))
                                          ((strcat "*" str))
                                    )
                           )
                  )
             )
         )
    )
  (entmod (subst (cons 1 pat) (assoc 1 el) el))
)
     )
   )
 )
(setq tag2 "D_MODEL")
 (initget "Y N")
 (if (and (setq typ2 (cond ((getkword "\nExisting Model?  <Y>: "))
                   ("Y")
             )
   )
(IF (= typ2 "Y")
  (setq str2 "//")
  )
     )
   (repeat (setq i2 (sslength ss))
     (setq en2 (ssname ss (setq i2 (1- i2))))
     (while (eq "ATTRIB" (cdr (assoc 0 (setq el2 (entget (setq en2 (entnext en2)))))))
(setq as2  (cdr (assoc 1 el2))
      pat2 (cond        ((eq "Prefix" typ) (strcat str2 as2))
                ((strcat as2 str2))
          )
      n2          (vl-string-search (strcase str2) (strcase as2))
)
(if (and (= tag2 (cdr (assoc 2 el2)))
         (or (null n2)
             (not (wcmatch (strcase as2)
                           (strcase (cond ((= 0 n2) (strcat str2 "*"))
                                          ((strcat "*" str2))
                                    )
                           )
                  )
             )
         )
    )
  (entmod (subst (cons 1 pat2) (assoc 1 el2) el2))
)
     )
   )
 )
 (princ)
)
 

edit Kerry : [ code=cadlisp-7 ]

AVCAD · « **Reply #5 on:** January 26, 2024, 03:50:12 PM »

Hello again,

I had a request after I got this to work to make all the items that were changed be put on a different layer

I sort of got it to work....but it changes all of the selected blocks even if the block was not changed... I know why....its because I am using "previous" as the selection method. I thought it would only select the blocks that got changed but it is not doing that.

Is there away of doing this? only putting the items that were changed on the layer instead of everything I selected? Just easier to use a Crossing window to select instead of selecting each object

Thanks in advance again!

Code Below:

Code - Auto/Visual Lisp: [Select]

(defun c:attfix (/ as el en i n pat ss str tag typ i2 ss2 en2 el2 as2 pat2 str2 tag2 n2)
 ;; Change tag to suit
 (setq tag "D_ID")
 (initget "Prefix Suffix")
 (if (and (setq typ (cond ((getkword "\nAdd Suffix or Prefix  <Prefix>: "))
                   ("Prefix")
             )
   )
   (/= "" (setq str (getstring t (strcat typ " to Add: "))))
   (setq ss (ssget ":L" '((0 . "INSERT") (66 . 1))))      
     )
   (repeat (setq i (sslength ss))
     (setq en (ssname ss (setq i (1- i))))
     (while (eq "ATTRIB" (cdr (assoc 0 (setq el (entget (setq en (entnext en)))))))
(setq as  (cdr (assoc 1 el))
      pat (cond ((eq "Prefix" typ) (strcat str as))
                ((strcat as str))
          )
      n   (vl-string-search (strcase str) (strcase as))
)
(if (and (= tag (cdr (assoc 2 el)))
         (or (null n)
             (not (wcmatch (strcase as)
                           (strcase (cond ((= 0 n) (strcat str "*"))
                                          ((strcat "*" str))
                                    )
                           )
                  )
             )
         )
    )
  (entmod (subst (cons 1 pat) (assoc 1 el) el))
)
     )
   )
 )
(setq tag2 "D_MODEL")
 (initget "Y N")
 (if (and (setq typ2 (cond ((getkword "\nExisting Model?  <Y>: "))
                   ("Y")
             )
   )
(IF (= typ2 "Y")
  (setq str2 "//")
  )
     )
   (repeat (setq i2 (sslength ss))
     (setq en2 (ssname ss (setq i2 (1- i2))))
     (while (eq "ATTRIB" (cdr (assoc 0 (setq el2 (entget (setq en2 (entnext en2)))))))
(setq as2  (cdr (assoc 1 el2))
      pat2 (cond        ((eq "Prefix" typ) (strcat str2 as2))
                ((strcat as2 str2))
          )
      n2          (vl-string-search (strcase str2) (strcase as2))
)
(if (and (= tag2 (cdr (assoc 2 el2)))
         (or (null n2)
             (not (wcmatch (strcase as2)
                           (strcase (cond ((= 0 n2) (strcat str2 "*"))
                                          ((strcat "*" str2))
                                    )
                           )
                  )
             )
         )
    )
  (entmod (subst (cons 1 pat2) (assoc 1 el2) el2))
)
     )
   )
 )
(setq curlay (getvar "clayer"))
(command "-layer" "m" "1_AV-LINE-OFE" "c" "251" "" "")
(setvar "clayer" "1_AV-LINE-OFE")
(command "chprop" "P" "" "la" "1_AV-LINE-OFE" "")
(setvar "clayer" curlay)
 (princ)
)
 (princ "\nAttribute Prefix tool has been loaded: command = ATTFIX ")
 

kdub_nz · « **Reply #6 on:** January 26, 2024, 05:23:41 PM »

Perhaps make a list and add the entity ( block inserts ) as you modify it.

After you've processed the selection set iterate the list and change the layer of each block insert changed.

. . or change the Layer as soon as you identify the block is a candidate for changing.

just a side note.
It would make the code easier to decipher if you refactored it into mltiple functions that each has reduced functionality.
That way it would be easier for determine what is happening, and easier to check. ( and change )

AVCAD · « **Reply #7 on:** January 29, 2024, 08:42:05 AM »

Thanks for the response Kdub,

however I am not a coder, I can modify some code and can sort of read it when its in front of me but I am not good at writing it and everything you just said was like a jet flying at 30,000ft and I am at like 6 ft.

The code supplied was code I found on and modified it to work for what I wanted but like I said the request now is to have the blocks that were modified (only blocks with D_ID and D_model attribute tags) to be reselected or what ever the method is to then be put on a different layer.

What happens right now is that all of the blocks selected will be put on the layer but that's not what I want I just want the changed blocks to go to the new layer.

BIGAL · « **Reply #8 on:** January 29, 2024, 09:16:36 PM »

Just a suggestion if you use Nentsel you can pick an attribute and return its tag name, like wise you can use the pick point to get the block name also.

Code: [Select]

(cdr (assoc 2 (entget (car (nentsel "\nPick attribute ")))))

kdub_nz · « **Reply #9 on:** January 29, 2024, 09:36:10 PM »

I think this is what you want . . could be improved or enhanced.

Don't be scared by the amount of code.
Most of it is from my generic library.

WTF happened to the formatting ?? This fixed the file https://www.browserling.com/tools/tabs-to-spaces

Main Code

Code - Auto/Visual Lisp: [Select]

(defun c:att_prefix  (/ *error* default-tag curlay ss i blockinsert
           attributelist current-value dotlist
          )
   ;; simple error trap
   (defun *error* (msg)
    (if (null (wcmatch (strcase msg t) "*break,*cancel*,*exit*"))     
     (progn (princ (strcat "\nxError: " msg)) (vl-bt))
    )
    (princ)
   )
   ;;------
   (princ
    "If selected blockInsert has D_ID and D_MODEL Attribute tag ' ' "
   )
   (princ "\n . . Prefix D_ID Tag and change Layer to 1_AV-LINE-OFE")
   (setq default-tag "D_ID")
   (setq curlay (getvar "clayer"))
   (command "-layer" "m" "1_AV-LINE-OFE" "c" "251" "" "")
   (setvar "clayer" curlay)
   ;;
   (setq *attprefix* (kdub:getstring "blockinsertter Prefix "
                   *attprefix*
                   1
                   nil
           )
   )
   (if (not  (and *attprefix*
         (setq ss (ssget ":L" '((0 . "INSERT") (66 . 1))))
      )
     )
    quit
   )
   ;;
   (repeat (setq i (sslength ss))
    (setq blockinsert (ssname ss (setq i (1- i))))
    (if
     (and (setq attributelist (kdub:getattributelist blockinsert))
        (setq
         current-value (cdr (assoc default-tag attributelist))
        )
        (assoc "D_MODEL" attributelist)
     ) (progn
        (setq  dotlist
            (list  (cons default-tag
                  (strcat *attprefix* current-value)
              )
            )
        )
        (kdub:set-prefixed-attributes  blockinsert
                      default-tag
                      dotlist
        )
        (command "chprop" blockinsert "" "la" "1_AV-LINE-OFE" "")
       )
    )
   )
   (princ)
)
(princ
   "\nAttribute Prefix tool has beblockinsert loaded: command = ATT_ATTFIX "
)
(princ)
 

Library Code
Either pre-load this or add it to the main file.
This code is 20+ years matured, so best not change it

Code - Auto/Visual Lisp: [Select]

;;========================================================================
;| #lib.
kdub:getString (<Promptmsg><Default><InitBit><AllowSpaces>)
kwb 20021103
Revised Library : kwb 20051031
20051101 kwb : ESC test added.
Build 2.0 :
 
(SETQ tmpVal (kdub:getString "Lot Description" nil (+ 1 ) T))
(SETQ tmpVal (kdub:getString "Name" "Me" (+ 1 ) Nil))
(SETQ tmpVal (kdub:getString nil nil nil Nil))
|;
 
(defun kdub:getstring (promptmsg              ; The prompt string.
             default                ; Value to return if response is <blockinsertter>
             initbit                ; Initget bit
             allowspaces              ; spaces Flag < T or nil )
                              ;
             / returnvalue
            )
   ;;------------------------------
   (or initbit (setq initbit 0))
   ;;------------------------------
   (setq promptmsg (strcat "\n"
               (cond (promptmsg)
                 ("Specify String Value")
               )
           )
   )
   ;;------------------------------
   (if (and default (= (type default) 'str) (/= default ""))
    (progn (setq
        promptmsg (strcat "\n" promptmsg " << " default " >>: ")
       )
       (if (vl-catch-all-error-p
          (setq returnvalue (vl-catch-all-apply
                     'getstring
                     (list allowspaces promptmsg)
                    )
          )
         )
        ;; ESC was pressed.
        (setq returnvalue nil
            default nil
        )
       )
       (setq returnvalue (if (= returnvalue "")
                  default
                  returnvalue
                 )
       )
    )
    ;; Else no default, so don't accept blockinsertTER or SPACEBAR
    ;;
    (progn
     (setq promptmsg (strcat "\n" promptmsg ": "))
     (if (= initbit 1)
      (while (= ""
            (setq  returnvalue  (vl-catch-all-apply
                       'getstring
                       (list allowspaces promptmsg)
                    )
            )
           )
      )
      ;;
      (setq returnvalue (vl-catch-all-apply
                 'getstring
                 (list allowspaces promptmsg)
                )
      )
     )
     (if (vl-catch-all-error-p returnvalue)
      ;; ESC was pressed.
      (setq returnvalue nil)
     )
    )
   )
   ;;------------------------------
   returnvalue
)
;;========================================================================
;;;------------------------------------------------------------------
;;;------------------------------------------------------------------
;;;
 
(defun getattributes (objselection)
   (if (= (type objselection) 'ename)
    (setq objselection (vlax-ename->vla-object objselection))
   )
   (if (= (vla-get-hasattributes objselection) :vlax-true)
    (mapcar '(lambda (x)
          (cons (vla-get-tagstring x) (vla-get-textstring x))
         )
        (vlax-safearray->list
         (variant-value (vla-getattributes objselection))
        )
    )
   )
)
 
;;;------------------------------------------------------------------
;;;------------------------------------------------------------------
;;;
;| KDUB:GetAttributeList
    < BlockRef > [VLA-OBJECT]
    
   Description: Read all attribute values from a block.
   
   Return [Typ]:
     ==> [Dot-list ] '(("tagstring1" . "textstring1")...) [LIST]
     or ==>nil
   Remarks: 
     N/a
  Dependencies:
     N/a
   revised kdub 2003 for ac2004|;
|                              ;
 
 
(defun kdub:getattributelist (blockref / catchit returnval)
   (if (= (type blockref) 'ename)
    (setq blockref (vlax-ename->vla-object blockref))
   )
   (if (vl-catch-all-error-p (setq catchit
                   (vl-catch-all-apply 'vlax-invoke
                             (list blockref 'getattributes)
                   )
               )
     )
    (alert (vl-catch-all-error-message catchit))
    ;; else
    (setq  returnval (mapcar '(lambda (attref)
                  (cons  (vla-get-tagstring attref)
                    (vla-get-textstring attref)
                  )
                 )
                catchit
            )
    )
   )
   returnval
)
;;;------------------------------------------------------------------
;;;------------------------------------------------------------------
;;;
;| KDUB:KDUB:SetAttributes
    < BlockRef > [VLA-OBJECT]
     < DotList  > [Dot-list  ] '(("tagstring1" . "textstring1")...)
     
   Description: Set attribute values to a block.
   
   Return [Typ]:     
     ==>nil
     
   Remarks: 
     N/a
  Dependencies:
     N/a  
  revised kdub 2003 for ac2004|;
|                              ;
;;;------------------------------------------------------------------
;;;------------------------------------------------------------------
;;;
(defun kdub:setattributes (blockref dotlist / catchit attval)
   (if (= (type blockref) 'ename)
    (setq blockref (vlax-ename->vla-object blockref))
   )
   (if (vl-catch-all-error-p (setq catchit
                   (vl-catch-all-apply 'vlax-invoke
                             (list blockref 'getattributes)
                   )
               )
     )
    (alert (vl-catch-all-error-message catchit))
    ;; else
    (progn
     (mapcar '(lambda (attref)
           (if (setq
              attval (cdr  (assoc (vla-get-tagstring attref)
                         dotlist
                    )
                   )
             )
            (vla-put-textstring attref attval)
           )
          )
         catchit
     )
     (vla-update blockref)
    )
   )
   (princ)
)
;;;------------------------------------------------------------------
;;;------------------------------------------------------------------
 

Regards,

AVCAD · « **Reply #10 on:** January 30, 2024, 07:22:16 PM »

30,000ft...you just went to 100,000....lol Thanks for this. I am just seeing it now so tomorrow I will have to test it out.

Will let you know.

kdub_nz · « **Reply #11 on:** January 30, 2024, 07:45:46 PM »

Consider the Library functions as black-box functions, you don't 'need' to know how thay work . . . just what to feed it and what irt returns.

I find that the main code can be kept a lot quieter coding this way.
Most times I extract code from the main into local well-named functions.
You'd be surprised how much simpler the code looks a couple months later.

It also makes the main a lot easier to think about.

Regards,

AVCAD · « **Reply #12 on:** February 22, 2024, 12:29:19 PM »

So finally found some time to test this out and I am getting this error after it allows me to select objects

Code - Auto/Visual Lisp: [Select]

xError: no function definition: KDUB:SET-PREFIXED-ATTRIBUTES
Backtrace:
[0.55] (VL-BT)
[1.51] (*ERROR* "no function definition: KDUB:SET-PREFIXED-ATTRIBUTES")
[2.46] (_call-err-hook #<SUBR @000001b88436ac50 *ERROR*> "no function definition: KDUB:SET-PREFIXED-ATTRIBUTES")
[3.40] (sys-error "no function definition: KDUB:SET-PREFIXED-ATTRIBUTES")
:ERROR-BREAK.35 nil
[4.32] (#<SUBR @000001b8820d8b88 null-fun-hk> <Entity name: 1b8fd6af980> "D_ID" (("D_ID" . "OFE4K60 HDMI RX")))
[5.26] (KDUB:SET-PREFIXED-ATTRIBUTES <Entity name: 1b8fd6af980> "D_ID" (("D_ID" . "OFE4K60 HDMI RX")))
[6.19] (C:ATT_PREFIX)
[7.15] (#<SUBR @000001b88436f250 -rts_top->)
[8.12] (#<SUBR @000001b8820d8700 veval-str-body> "(C:ATT_PREFIX)" T #<FILE internal>)
:CALLBACK-ENTRY.6 (:CALLBACK-ENTRY)
:ARQ-SUBR-CALLBACK.3 (nil 0)
 

any idea?

PKENEWELL · « **Reply #13 on:** February 22, 2024, 03:29:19 PM »

Quote from: kdub_nz on January 30, 2024, 07:45:46 PM

Consider the Library functions as black-box functions, you don't 'need' to know how thay work . . . just what to feed it and what irt returns.

I find that the main code can be kept a lot quieter coding this way.
Most times I extract code from the main into local well-named functions.
You'd be surprised how much simpler the code looks a couple months later.

It also makes the main a lot easier to think about.

Regards,

Kdubb - you're missing a function you call in the main routine here:

Code - Auto/Visual Lisp: [Select]

(kdub:set-prefixed-attributes  blockinsert
             default-tag
             dotlist
)
 

News:

Author Topic: Help: Adding Prefix to Selected Attribute Text (Read 1036 times)

AVCAD

Help: Adding Prefix to Selected Attribute Text

JohnK

Re: Help: Adding Prefix to Selected Attribute Text

AVCAD

Re: Help: Adding Prefix to Selected Attribute Text

JohnK

Re: Help: Adding Prefix to Selected Attribute Text

AVCAD

Re: Help: Adding Prefix to Selected Attribute Text

AVCAD

Re: Help: Adding Prefix to Selected Attribute Text

kdub_nz

Re: Help: Adding Prefix to Selected Attribute Text

AVCAD

Re: Help: Adding Prefix to Selected Attribute Text

BIGAL

Re: Help: Adding Prefix to Selected Attribute Text

kdub_nz

Re: Help: Adding Prefix to Selected Attribute Text

AVCAD

Re: Help: Adding Prefix to Selected Attribute Text

kdub_nz

Re: Help: Adding Prefix to Selected Attribute Text

AVCAD

Re: Help: Adding Prefix to Selected Attribute Text

PKENEWELL

Re: Help: Adding Prefix to Selected Attribute Text