Topic: 3DPolyline Analysis

[ChrisCarlson]

I'm drawing a blank this morning but how can you determine if a 3dpolyline is straight when it has vertexes? If there is only a start and end point that's easy to figure out but when vertexes are involved it gets confusing.

Comparing start and end point doesn't help as it would show both of these as "straight"

[David Bethel]

Maybe:

Code: [Select]

;;;ARG -> TestPt LinePt1 LinePt2 Fuzz
;;;RET T nil
(defun is_pt_online (pt l1 l2 fz)
  (and (numberp fz)
       (equal (distance l1 l2)
              (+ (distance l1 pt)
                 (distance l2 pt)) fz)))

For 1st 3 points of the 3DPOLY :

Code: [Select]

(is_pt_online v1 v0 v2 1e-8)


-David

[Keith Brown]

If I was doing this in .net then i would just start at the beginning and get the first two points.  Call them my start and end point and calculate its normal vector.  I would then take the end point and call it the start point and then get the next point and call it the end point and calculate its normal vector.  If the two vectors are equal then the two segments are straight.  Rinse and repeat with the next segment.


I am not a lisp programmer so I hope I am not repeating the previous solution.

[Lee Mac]

As Keith has indicated, you can test every set of three vertices, e.g.:

Code - Auto/Visual Lisp: [Select]

1. (defun straight3dpoly-p ( ent )
2.     (pointsonline-p (polyvertices ent))
3. )
4. (defun polyvertices ( ent / enx )
5.     (if (= "VERTEX" (cdr (assoc 0 (setq enx (entget ent)))))
6.         (cons (cdr (assoc 10 enx)) (polyvertices (entnext ent)))
7.         (if (= "POLYLINE" (cdr (assoc 0 enx)))
8.             (polyvertices (entnext ent))
9.         )
10.     )
11. )
12. (defun pointsonline-p ( lst )
13.     (or (null (caddr lst))
14.         (and
15.             (equal
16.                 (distance (car lst) (caddr lst))
17.                 (+ (distance (car lst) (cadr lst)) (distance (cadr lst) (caddr lst)))
18.                 1e-8
19.             )
20.             (pointsonline-p (cdr lst))
21.         )
22.     )
23. )
24.  

[ChrisCarlson]

Maybe:

Code: [Select]

;;;ARG -> TestPt LinePt1 LinePt2 Fuzz
;;;RET T nil
(defun is_pt_online (pt l1 l2 fz)
  (and (numberp fz)
       (equal (distance l1 l2)
              (+ (distance l1 pt)
                 (distance l2 pt)) fz)))

For 1st 3 points of the 3DPOLY :

Code: [Select]

(is_pt_online v1 v0 v2 1e-8)


-David

As Keith has indicated, you can test every set of three vertices, e.g.:

Code - Auto/Visual Lisp: [Select]

1. (defun straight3dpoly-p ( ent )
2.     (pointsonline-p (polyvertices ent))
3. )
4. (defun polyvertices ( ent / enx )
5.     (if (= "VERTEX" (cdr (assoc 0 (setq enx (entget ent)))))
6.         (cons (cdr (assoc 10 enx)) (polyvertices (entnext ent)))
7.         (if (= "POLYLINE" (cdr (assoc 0 enx)))
8.             (polyvertices (entnext ent))
9.         )
10.     )
11. )
12. (defun pointsonline-p ( lst )
13.     (or (null (caddr lst))
14.         (and
15.             (equal
16.                 (distance (car lst) (caddr lst))
17.                 (+ (distance (car lst) (cadr lst)) (distance (cadr lst) (caddr lst)))
18.                 1e-8
19.             )
20.             (pointsonline-p (cdr lst))
21.         )
22.     )
23. )
24.  

So if I'm reading these correctly the thought is as such;

3DPolyLine (numbers being vertices)
1 - 2 - 3 - 4 - 5 - 6

Test the following
1 - 2 - 3
2 - 3 - 4
3 - 4 - 5
4 - 5 - 6

if all the above is true, then the line is straight.

[Lee Mac]

Correct 

[Stefan]

Another 3 variants, first 2 using the same method as in Lee's lisp.

Code - Auto/Visual Lisp: [Select]

1. (defun str_poly1 (e / r i n a b c)
2.   (setq r T
3.         i (vlax-curve-getstartparam e)
4.         n (vlax-curve-getendparam e)
5.         )
6.   (while (and (<= i n)  r)
7.     (setq c (vlax-curve-getpointatparam e i))
8.     (or
9.       (if (not a) (setq a c))
10.       (if (not b) (setq b c))
11.       (setq r (equal (+ (distance a b) (distance b c)) (distance a c) 1e-8)
12.             a b b c i (1+ i))
13.       )
14.     )
15.   r
16.   )

Code - Auto/Visual Lisp: [Select]

1. (defun str_poly2 (e / i l)
2.   (repeat (setq i (1+ (fix (vlax-curve-getendparam e))))
3.     (setq l (cons (vlax-curve-getpointatparam e (setq i (1- i))) l))
4.     )
5.   (vl-every
6.     '(lambda (a b c)
7.        (equal (+ (distance a b) (distance b c)) (distance a c) 1e-8)
8.      )
9.     l (cdr l) (cddr l)
10.   )
11. )

Code - Auto/Visual Lisp: [Select]

1. (defun str_poly3 (e)
2.   (equal
3.     (distance (vlax-curve-getstartpoint e) (vlax-curve-getendpoint e))
4.     (vlax-curve-getdistatparam e (vlax-curve-getendparam e))
5.     1e-8
6.     )
7.   )

Code - Auto/Visual Lisp: [Select]

1. (defun c:test ( / e)
2.   (while (setq e (ssget "_+.:S" '((0 . "*polyline"))))
3.     (setq e (ssname e 0))
4.     (print (str_poly1 e))
5.     (princ "\t")
6.     (princ (str_poly2 e))
7.     (princ "\t")
8.     (princ (str_poly3 e))
9.     )
10.   (princ)
11.   )

[Lee Mac]

Code - Auto/Visual Lisp: [Select]

1. (defun str_poly3 (e)
2.   (equal
3.     (distance (vlax-curve-getstartpoint e) (vlax-curve-getendpoint e))
4.     (vlax-curve-getdistatparam e (vlax-curve-getendparam e))
5.     1e-8
6.     )
7.   )

Good observation Stefan, I like it 

[kdub_nz]

Code - Auto/Visual Lisp: [Select]

1. (defun str_poly3 (e)
2. ;<...>
3.  )

excellent return to first principles.