Topic: Create a selection set of objects based on a text string

[roy_043]

Maybe something like this?:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun _Conv_Pickset_To_EnameList (ss / i ret)
4.   (if ss
5.     (repeat (setq i (sslength ss))
6.       (setq ret (cons (ssname ss (setq i (1- i))) ret))
7.     )
8.   )
9. )
10.  
11. (defun c:Test ( / fuzz ptLst str ss ssOut)
12.   (if
13.     (and
14.       (/= "" (setq str (getstring T "\nLook for TEXT entities containing this string: ")))
15.       (setq ss (ssget "_X" (list '(0 . "TEXT") (cons 410 (getvar 'ctab)) (cons 1 (strcat "*" str "*")))))
16.       (setq ptLst
17.         (mapcar
18.           '(lambda (enme)
19.             (vlax-get (vlax-ename->vla-object enme) 'insertionpoint)
20.           )
21.           (_Conv_Pickset_To_EnameList ss)
22.         )
23.       )
24.     )
25.     (progn
26.       (vla-zoomextents (vlax-get-acad-object)) ; Crossing points must be visible on screen.
27.       (setq fuzz 1.0)
28.       (setq ssOut (ssadd))
29.       (mapcar
30.         '(lambda (pt / ss)
31.           (setq pt (trans pt 0 1))
32.           (if
33.             (setq ss
34.               (ssget
35.                 "_C"
36.                 (mapcar '- pt (list fuzz fuzz 0.0))
37.                 (mapcar '+ pt (list fuzz fuzz 0.0))
38.                 '((0 . "LINE,LWPOLYLINE,POINT,TEXT"))
39.               )
40.             )
41.             (foreach enme (_Conv_Pickset_To_EnameList ss)
42.               (ssadd enme ssOut)
43.             )
44.           )
45.         )
46.         ptLst
47.       )
48.       (vla-zoomprevious (vlax-get-acad-object))
49.       (if (/= 0 (sslength ssOut))
50.         (sssetfirst nil ssOut)
51.       )
52.     )
53.   )
54.   (princ)
55. )

[Dave M]

That worked!  At first I didn't think it was working, but the text string I used had a lot of objects.  The only downside is that it selects everything that shares or crosses that common point.  Would it be difficult to specify what is to be selected?  I used Quick Select to further filter the selection.


Thank you very much!

[kdub_nz]

Would it be difficult to specify what is to be selected?

See line 38 in the code posted by roy.

'((0 . "LINE,LWPOLYLINE,POINT,TEXT"))

[roy_043]

The code in my previous post was actually my 2nd stab at this. In my first attempt (see the code below) I tried to solve the problem in a more efficient way by creating a single selection set using a complex point filter. This solution actually works fine and since it looks at points is more critical in what is selected. The only problem is that for polylines only the first point is checked by the filter.

Alternative code (the code assumes that all entities have an OCS that matches the WCS):

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun _Conv_Pickset_To_EnameList (ss / i ret)
4.   (if ss
5.     (repeat (setq i (sslength ss))
6.       (setq ret (cons (ssname ss (setq i (1- i))) ret))
7.     )
8.   )
9. )
10.  
11. (defun GeneratePtFilter (ptLst grpCd fuzz)
12.   (apply
13.     'append
14.     (mapcar
15.       '(lambda (pt)
16.         (list
17.           '(-4 . "<AND")
18.           '(-4 . ">,>,*")
19.           (cons grpCd (mapcar '- pt (list fuzz fuzz 0.0)))
20.           '(-4 . "<,<,*")
21.           (cons grpCd (mapcar '+ pt (list fuzz fuzz 0.0)))
22.           '(-4 . "AND>")
23.         )
24.       )
25.       ptLst
26.     )
27.   )
28. )
29.  
30. (defun c:Test ( / ptLst str ss ssOut)
31.   (if
32.     (and
33.       (/= "" (setq str (getstring T "\nLook for TEXT entities containing this string: ")))
34.       (setq ss (ssget "_X" (list '(0 . "TEXT") (cons 410 (getvar 'ctab)) (cons 1 (strcat "*" str "*")))))
35.       (setq ptLst
36.         (mapcar
37.           '(lambda (enme)
38.             (vlax-get (vlax-ename->vla-object enme) 'insertionpoint)
39.           )
40.           (_Conv_Pickset_To_EnameList ss)
41.         )
42.       )
43.       (setq ssOut
44.         (ssget
45.           "_X"
46.           (append
47.             (list
48.               '(0 . "LINE,LWPOLYLINE,POINT,TEXT")
49.               (cons 410 (getvar 'ctab))
50.               '(-4 . "<OR")
51.             )
52.             (GeneratePtFilter ptLst 10 1.0)
53.             (GeneratePtFilter ptLst 11 1.0)
54.             '((-4 . "OR>"))
55.           )
56.         )
57.       )
58.     )
59.     (sssetfirst nil ssOut)
60.   )
61.   (princ)
62. )

[Dave M]

Thank you for taking the time to help me with this!  I really appreciated it!