Topic: How can I check if the point type is a variant or not?

[donnieworld]

 How can I check if the point type is a variant or not?

Some functions are setting the variable like:
(setq ptIns (getpoint "\nInsertion point > "))

others this way:
(setq ptIns (vla-getpoint util nil "\nInsertion point > "))

I need this function to identify the type:
(if (= ptIns ?is a variant?)
  (vlax-put-property myMText 'InsertionPoint ptIns)
  (vlax-put-property myMText 'InsertionPoint (vlax-3d-point ptIns))
)

[kdub_nz]

Have a look at

https://www.bricsys.com/bricscad/help/en_AU/CurVer/DevRef/source/vlevariantp.htm

(vle-variantp  obj)

replacement for AutoCAD's : (= (type obj) 'VARIANT)

[roy_043]

Keep in mind that if you are writing Lisp code for BricsCAD you do no need to check this.

Code: [Select]

(setq myMText (vlax-ename->vla-object (car (entsel))))
(setq ptList '(0.0 0.0 0.0))
(setq ptVariant (vlax-3d-point '(1.0 1.0 1.0)))
This all works in BricsCAD:

Code: [Select]

(vla-put-insertionpoint myMText ptList)
(vla-put-insertionpoint myMText ptVariant)
(vlax-put-property myMText 'insertionpoint ptList)
(vlax-put-property myMText 'insertionpoint ptVariant)
(vlax-put myMText 'insertionpoint ptList)
(vlax-put myMText 'insertionpoint ptVariant)

[donnieworld]

Thanks, this is exactly what I was looking for. While BricsCAD is my primary target, all of my routines still need to run on AutoCAD as well. A couple, not this one, require that I have distinct code for each.

This is the complete function I am updating at the moment:

(defun HASD:AddMText ( ptIns nHt nRot sStyle sText sJust / )

   (cond
      ((= sJust "TL") (setq sJustify acAttachmentPointTopLeft))
      ((= sJust "TC") (setq sJustify acAttachmentPointTopCenter))
      ((= sJust "TR") (setq sJustify acAttachmentPointTopRight))
      ((= sJust "ML") (setq sJustify acAttachmentPointMiddleLeft))
      ((= sJust "MC") (setq sJustify acAttachmentPointMiddleCenter))
      ((= sJust "MR") (setq sJustify acAttachmentPointMiddleRight))
      ((= sJust "BL") (setq sJustify acAttachmentPointBottomLeft))
      ((= sJust "BC") (setq sJustify acAttachmentPointBottomCenter))
      ((= sJust "BR") (setq sJustify acAttachmentPointBottomRight))
      (t (setq sJustify acAttachmentPointMiddleCenter))
   )

   (setq nTextWidth 0) ; width of Mtext object still needs to be calculated

   (vla-SetVariable thisdrawing "TEXTSIZE" nHT)
   
   (setq myMText (vla-AddMText mspace (vlax-3d-point ptIns) nTextWidth sText))
      
   (if (= (vlax-property-available-p myMText 'AttachmentPoint) T)
      (vlax-put-property myMText 'AttachmentPoint sJustify))
   
   (if (= (vlax-property-available-p myMText 'Rotation) T)
      (vlax-put-property myMText 'Rotation (HASD:D2R nRot)))

   (if (= (vlax-property-available-p myMText 'StyleName) T)
      (vlax-put-property myMText 'StyleName sStyle))   
         
   (if (= (vlax-property-available-p myMText 'InsertionPoint) T)
      (vlax-put-property myMText 'InsertionPoint (vlax-3d-point ptIns)))
      
(princ)

)

[ronjonp]

FWIW .. here's an idea for your justification code:

Code - Auto/Visual Lisp: [Select]

1. (setq o (vlax-ename->vla-object (car (entsel))))
2. (setq just "BR")
3. (vlax-put o
4.           'attachmentpoint
5.           (cdr (assoc just
6.                       '(("TL" . 1)
7.                         ("TC" . 2)
8.                         ("TR" . 3)
9.                         ("ML" . 4)
10.                         ("MC" . 5)
11.                         ("MR" . 6)
12.                         ("BL" . 7)
13.                         ("BC" . 8)
14.                         ("BR" . 9)
15.                        )
16.                )
17.           )
18. )

[Lee Mac]

Also:

Code - Auto/Visual Lisp: [Select]

1. (setq o (vlax-ename->vla-object (car (entsel))))
2. (setq just "BR")
3. (vlax-put o 'attachmentpoint
4.     (vl-position just '("""TL""TC""TR""ML""MC""MR""BL""BC""BR"))
5. )

[ronjonp]

Cool .. did not know you could feed it strings too.

[Lee Mac]

Cool .. did not know you could feed it strings too.

Still using integers 

[ronjonp]

Cool .. did not know you could feed it strings too.

Still using integers 

Well don't I feel silly 
LOL .. trickster you are    .. better finish my cup of coffee.

[Lee Mac]

 

[Lee Mac]

   (if (= (vlax-property-available-p myMText 'AttachmentPoint) T)
      (vlax-put-property myMText 'AttachmentPoint sJustify))
   
   (if (= (vlax-property-available-p myMText 'Rotation) T)
      (vlax-put-property myMText 'Rotation (HASD:D2R nRot)))

   (if (= (vlax-property-available-p myMText 'StyleName) T)
      (vlax-put-property myMText 'StyleName sStyle))   
         
   (if (= (vlax-property-available-p myMText 'InsertionPoint) T)
      (vlax-put-property myMText 'InsertionPoint (vlax-3d-point ptIns)))

FWIW, there is no need to test for the availability of these properties, as an MText object will always have such properties.

Also:

Code: [Select]

(if (= (vlax-property-available-p myMText 'AttachmentPoint) T)
Can be simply:

Code: [Select]

(if (vlax-property-available-p myMText 'AttachmentPoint)