Topic: Visible value true or false

[cadplayer]

Hello!
I have written some rows to can select a PipeObject (AeccDbPipe) in Civil3d and freeze them.
My Problem is I didnīt find anything in Civil3d to unfreeze same object, because I can not select them (isnīt visible).
Here a test

Code: [Select]

(if (setq e (entsel "\n Select Pipe Object!"))
    (progn
      (setq vEnt (vlax-ename->vla-object (car e)))
      (cond
((= (vla-get-objectname vEnt) "AeccDbGraphProfileNetworkPart")
(setq desc (vlax-get-property vEnt 'Description))
(setq disp (vlax-get-property vEnt 'DisplayName))
(alert (strcat
  "\nDescription: " desc
  "\nName: " disp
  )
)
)
((= (vla-get-objectname vEnt) "AeccDbPipe")
(setq desc (vlax-get-property vEnt 'Description))
(setq disp (vlax-get-property vEnt 'DisplayName))
(alert (strcat
  "\nPipe"
  "\nDescription: " desc
  "\nName: " disp
  )
)
)
((= (vla-get-objectname vEnt) "AeccDbStructure")
(setq desc (vlax-get-property vEnt 'Description))
(setq disp (vlax-get-property vEnt 'DisplayName))
(alert (strcat
  "\nStructure"
  "\nDescription: " desc
  "\nName: " disp
  )
)
)
);cond
      (if (and desc disp)
(progn
  (initget "YES NO")
  (setq r (getkword "\n Freeze object? [<Yes> / No]: "))
  (cond
    ((or (= r "YES")(null r))
     (princ (strcat "\nObject " disp " freezed."))
     (vlax-put-property vEnt 'Visible :vlax-false)
     )
    ((= r "NO")
     (princ "Do nothing.")
     )
    )
  )
)
      )
    )
Annother Problem is if I mark to inspect vla-object AeccDbPipe in vlide-console
mark: variable vEnt + Rightclick (Inspect)
or
mark: (vlax-ename->vla-object (car e))  + Rightclick (Inspect)

I get a error message, which I donīt understand
; error: ActiveX Server returned an error: Bad variable type

[kpblc]

What about vlax-dump-object? And did you loaded ObjectEnablers (demandload = 3 ot not)?

[roy_043]

To select invisible objects:

Code - Auto/Visual Lisp: [Select]

1. (ssget "_X" '((60 . 1)))

[cadplayer]

(demandload = 3)
what does it mean (demandload value 3... contains custom or when you invoke on of the applications commands)
vlax-dump-objects works fine

inspect request works with normaly Acadobjects (line, arc, circle...) yesterday it works also by AeccDbPipe-objects from Civil but today I get error-message

This solution unfreeze all Pipes in drawing, but itīs not so usefull, I want select on screen in ca. position or type a name, maybe some Civil-guys have a better way to do that.

Code: [Select]

(if (setq ss (ssget "X" '((8 . "VA-LEDN"))))
    (progn
      (repeat (sslength ss)
(setq vEnt (vlax-ename->vla-object (ssname ss (setq i (1+ i)))))
(vlax-put-property vEnt 'Visible :vlax-true)
(cond
  ((= (vla-get-objectname vEnt) "AeccDbPipe")
   (setq desc (vlax-get-property vEnt 'Description))
   (setq disp (vlax-get-property vEnt 'DisplayName))
   (princ (strcat
  "\nPipe"
  "\nDescription: " desc
  "\nName: " disp
  )
)
   (setq z (1+ z))
   )
  )
)
      (alert (strcat (itoa z) " Pipes found on Layer 'VA-LEDN'"))
      )
    )

[cadplayer]

this is even better, but I continue wondering, why Civil doesnīt have a command for this unfreeze or freeze-function

Code: [Select]

(defun c:showAll()
  (if (setq req (strcase (getstring "\nGet a Pipetype [Vatten / Spill / Dag]")))
    (cond
      ((or (= req "V")(= req "VATTEN"))
       (setq s "V")
       )
      ((or (= req "S")(= req "SPILL"))
       (setq s "S")
       )
      ((or (= req "D")(= req "DAG"))
       (setq s "D")
       )
      )
    )
 
  (setq i -1 z 1)
  (if (setq ss (ssget "X" '((8 . "VA-LEDN"))))
    (progn
      (repeat (sslength ss)
(setq vEnt (vlax-ename->vla-object (ssname ss (setq i (1+ i)))))
(cond
  ((= (vla-get-objectname vEnt) "AeccDbPipe")
   (setq desc (vlax-get-property vEnt 'Description))
   (setq disp (vlax-get-property vEnt 'DisplayName))

   (if (vl-string-search s desc)
     (progn
       (princ (strcat
"\nPipe"
"\nDescription: " desc
"\nName: " disp
)
      )
       (setq z (1+ z))
       (vlax-put-property vEnt 'Visible :vlax-true)
       )
     )
   
   )
  )
)
      (alert (strcat (itoa z) " Pipes found on Layer 'VA-LEDN'"))
      )
    )
  (princ)
  )

[kpblc]

I'm not use Civil, so i can't check code:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun test (/ ent_lst layer str fun_get-prop)
4.  
5.   (defun fun_get-prop (obj prop)
6.     (if (vlax-property-available-p obj prop)
7.       (vl-princ-to-string (vlax-get-property obj prop))
8.       ""
9.       ) ;_ end of if
10.     ) ;_ end of defun
11.  
12.  
13.   (if (not (vl-catch-all-error-p
14.              (setq str
15.                     (vl-catch-all-apply
16.                       (function
17.                         (lambda (/ res)
18.                           (initget 1 "Vatten Spill Dag _ V S D")
19.                           (getkword "\nGet a Pipetype [Vatten/Spill/Dag] <Cancel> : ")
20.                           ) ;_ end of lambda
21.                         ) ;_ end of function
22.                       ) ;_ end of vl-catch-all-apply
23.                    ) ;_ end of setq
24.              ) ;_ end of vl-catch-all-error-p
25.            ) ;_ end of not
26.     (progn
27.       (setq layer (strcase "VA-LEDN"))
28.       (vlax-for ent (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
29.         (if (and (= (strcase (vla-get-layer ent) layer)
30.                     (= (vla-get-objectname ent) "AeccDbPipe")
31.                     ) ;_ end of =
32.                  ) ;_ end of and
33.           (setq ent_lst (cons ent ent_lst))
34.           ) ;_ end of if
35.         ) ;_ end of vlax-for
36.       ) ;_ end of progn
37.     (if ent_lst
38.       (progn
39.         (princ (apply (function strcat)
40.                       (mapcar
41.                         (function
42.                           (lambda (x)
43.                             (strcat "\nPipe:"
44.                                     (mapcar
45.                                       (function
46.                                         (lambda (a)
47.                                           (strcat "\n\t" a (fun_get-prop x a))
48.                                           ) ;_ end of lambda
49.                                         ) ;_ end of function
50.                                       '("Description" "Name")
51.                                       ) ;_ end of mapcar
52.                                     ) ;_ end of strcat
53.                             ) ;_ end of lambda
54.                           ) ;_ end of function
55.                         ent_lst
56.                         ) ;_ end of mapcar
57.                       ) ;_ end of apply
58.                ) ;_ end of princ
59.         (alert (itoa (length ent_lst) " pipes found on layer " layer))
60.         ) ;_ end of progn
61.       (alert "No pipes found")
62.       ) ;_ end of if
63.     ) ;_ end of if
64.   (princ)
65.   ) ;_ end of defun

[cadplayer]

Looking interesting. I get some mistake, but so it works...
Itīs not really solution of in my case, but thanks for your nice work, I learned more about lambda

Code: [Select]

(vl-load-com)
 
(defun c:test (/ ent_lst layer str fun_get-prop)
 
  (defun fun_get-prop (obj prop)
    (if (vlax-property-available-p obj prop)
      (vl-princ-to-string (vlax-get-property obj prop))
      ""
      ) ;_ end of if
    ) ;_ end of defun
 
 
  (if (not (vl-catch-all-error-p
             (setq str
                    (vl-catch-all-apply
                      (function
                        (lambda (/ res)
                          (initget 1 "Vatten Spill Dag _ V S D")
                          (getkword "\nGet a Pipetype [Vatten/Spill/Dag] <Cancel> : ")
                          ) ;_ end of lambda
                        ) ;_ end of function
                      ) ;_ end of vl-catch-all-apply
                   ) ;_ end of setq
             ) ;_ end of vl-catch-all-error-p
           ) ;_ end of not
    (progn
      (setq layer (strcase "VA-LEDN"))
      (vlax-for ent (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
        (if (and (= (strcase (vla-get-layer ent)) layer)
                    (= (vla-get-objectname ent) "AeccDbPipe")
                    ) ;_ end of =
          (setq ent_lst (cons ent ent_lst))
          ) ;_ end of if
        ) ;_ end of vlax-for
      ) ;_ end of progn
    )
 
    (if ent_lst
      (progn
        (princ (apply (function strcat)
      (mapcar
                        (function
                          (lambda (x)
                            (vl-princ-to-string
                                    (mapcar
                                      (function
                                        (lambda (a)
                                          (strcat "\n\t" a ": " (fun_get-prop x a))
                                          ) ;_ end of lambda
                                        ) ;_ end of function
                                      '("Description" "Name")
                                      ) ;_ end of mapcar
      )
                            ) ;_ end of lambda
                          ) ;_ end of function
                        ent_lst
                        ) ;_ end of apply
      )
               ) ;_ end of princ
        (alert (strcat (itoa (length ent_lst)) " pipes found on layer " layer))
        ) ;_ end of progn
      (alert "No pipes found")
      ) ;_ end of if
  (princ)
  ) ;_ end of defun