Topic: Problem with spaces in script file

[danglar]

I have a program for add file prefix "Xref-" and suffix as current date
and open modified XREF file with close and delete previous file (see attached lisp).
Program working properly until you have file name with spaces between words
(example: pump station.dwg) or you have a path with spaces between words
(example: c:\Pump station\example.dwg)
Can somebody fix it?

[ronjonp]

Try putting quotes around the text like so "c:\Pump station\example.dwg"

[danglar]

Part and name of file here is a variable (not constant) so I need to do it programmaticaly somehow...

[ronjonp]

Use a combination of vl-prin1-to-string & strcat:

Code - Auto/Visual Lisp: [Select]

1. (alert (vl-prin1-to-string (strcat (getvar 'dwgprefix) (vl-filename-base (getvar 'dwgname)))))

[danglar]

..but this string

Code - Auto/Visual Lisp: [Select]

1. (alert (vl-prin1-to-string (strcat (getvar 'dwgprefix) "XREF-" (vl-filename-base (getvar 'dwgname) "-TPZ-" thedate ))))
2.  
3.  

returns an error: too many arguments

[ronjonp]

Your closing paren for vl-filename-base is in the wrong place.

[danglar]

right way is:

Code - Auto/Visual Lisp: [Select]

1.  
2. (setq www (vl-prin1-to-string (strcat (getvar 'dwgprefix) "XREF-" (vl-filename-base (getvar 'dwgname)) "-TPZ-" thedate )))
3.  
4.  

but now i have an eror in this strings

Code - Auto/Visual Lisp: [Select]

1. (write-line (strcat "open " www) fil1)
2. (write-line (strcat "(vl-file-delete www)") fil1)
3.  

[ronjonp]

Sorry Danglar, I don't have time right now to debug your code. You initial question was just about spaces & text strings.

[danglar]

Thank you ronjonp. Your help was very appreciated..

[ronjonp]

Thank you ronjonp. Your help was very appreciated..

You're welcome.

[Prickle Farmer]

Why make you life complicated with VL?

Code - Auto/Visual Lisp: [Select]

1. (setq www (strcat (getvar "DWGPREFIX") "XREF-" (substr (getvar "DWGNAME") 1 (- (strlen (getvar "DWGNAME")) 4)) "-TPZ-" (rtos (gevar "CDATE") 2 0)))

EDIT: Added code tags. - John

[ronjonp]

Why make you life complicated with VL?

(setq www (strcat (getvar "DWGPREFIX") "XREF-" (substr (getvar "DWGNAME") 1 (- (strlen (getvar "DWGNAME")) 4)) "-TPZ-" (rtos (gevar "CDATE") 2 0)))

What is complicated about VL ? Your solution seems more complicated to me.

[danglar]

Thank you
for your note, but I still have a problem with script ..
I have an error " error: no function definition: GEVAR"
when I invoke this string

Code - Auto/Visual Lisp: [Select]

1. (write-line  "open " www fil1)
2.  

[Kerry]

That's because you spelled it incorrectly.

Try GETVAR

http://help.autodesk.com/view/ACD/2016/ENU/?guid=GUID-9C56BEA8-D473-4305-9E17-BEF7630C334D

[danglar]

You are right:
correct string is:

Code - Auto/Visual Lisp: [Select]

1. (setq www (strcat (getvar "DWGPREFIX") "XREF-" (substr (getvar "DWGNAME") 1 (- (strlen (getvar "DWGNAME")) 4)) "-TPZ-" (rtos (getvar "CDATE") 2 0)))

but program now not working properly

[Kerry]

What is the name of your drawing ?

and what are these values ?

Code - Auto/Visual Lisp: [Select]

1. (getvar "DWGPREFIX")
2. (getvar "DWGNAME")
3. (getvar "CDATE")

[danglar]

Drawing name is a variable. Only for example it can be "pump station.dwg" but can be something else

[Kerry]

Well what is the value of the variable ...
and these

Code - Auto/Visual Lisp: [Select]

1. (getvar "DWGPREFIX")
2. (getvar "DWGNAME")
3. (getvar "CDATE")

AND

if the name is a variable, what is the actual code you are trying to evaluate ;
and the value of the variables you are using.

[Kerry]

Which part isn't working ??

Just a idle query ; should the variable www have ".Dwg" appended ??

[danglar]

Sorry for my misunderstanding, but I checked the program and my opinion is:
Two strings not working properly:

Code - Auto/Visual Lisp: [Select]

1. (write-line  "open " www fil1)
2.  (write-line (strcat "(vl-file-delete " (vl-string-right-trim "\"" (vl-prin1-to-string str1)) str3 ".dwg\")") fil1)
3.  
4.  

see attached lisp

[Kerry]

Do us both a favor ..

reduce your code to the minimum possible that can demonstrate the issue you have.

[danglar]

I'll try...

[Kerry]

Does this work for you ??

[Kerry]

Going back through your code, the first thing your could do is add some error trapping.

Perhaps try something like this

Code - Auto/Visual Lisp: [Select]

1.  
2. (defun myDefault*error* (msg)
3.   (while (< 0 (getvar 'cmdactive)) (command-s nil))
4.   (setvar 'menuecho 1)
5.   (cond ((not msg))
6.         ((member (strcase msg t)
7.                  '("console break" "function cancelled" "quit / exit abort")
8.          )
9.          (princ "\nFunction Cancelled.")
10.         )
11.         ((princ (strcat "\nApplication Error: " (itoa (getvar 'errno)) " :- " msg))
12.          (vl-bt)
13.         )
14.   )
15.   (setvar 'errno 0)
16.   (princ)
17. )
18.  

Code - Auto/Visual Lisp: [Select]

1.   ;;-----------
2.   (defun *error* (msg)
3.     (myDefault*error* msg)
4.   )
5.   ;;-----------
6.  

[danglar]

Error trapping - is a good idea!
I can add it to program.
About your previous replay..
It's took for me some time but I check it according to your notes and didn't find any errors if I use certain file name and path instead variables.
It seem to me very complicated and I don't now how to find a solution

[Kerry]

I'll ask the obvious question :
Why are you using a Script file to delete the previous file ?

[Kerry]

Correct me is I'm incorrect.

You have a drawing open.

You save the drawing with a different name.

You open the new drawing.

You delete the original drawing.

Alternative:

Save current
SaveAs with a different name
Delete original.

Is this correct ?

[danglar]

Obviously you are correct, but with little additions in alternative way as you call it:

I don’t need to Save current drawing, because i use this program as a part of "cleaning" process
Save As with a different name
Open the new file
Delete original.

[Kerry]

Will this work for you.
It will leave the 'Original' in th Temp folder at the moment ... it can be deleted programmatically if you want.

Code - Auto/Visual Lisp: [Select]

1.  
2. (defun c:doit (/ *error*)                              ; TODO add local variables
3.   ;;-----------
4.   (defun *error* (msg) (myDefault*error* msg))
5.   ;;-----------
6.   (vl-cmdf "_qsave")
7.   (setq dwgprefix     (getvar "dwgprefix")
8.         dwgname       (getvar "dwgname")
9.         filename-base (vl-filename-base dwgname)
10.         tempprefix    (getvar "tempprefix")
11.         thedate       (rtos (getvar "CDATE") 2 0)
12.   )
13.   (setq OriginalFileName (strcat dwgprefix dwgname)
14.         ArchiveFileName (strcat tempprefix dwgname)
15.         newFileName     (strcat dwgprefix    "XREF-"
16.                                 filename-base
17.                                 "-TPZ-"      thedate ".Dwg" )
18.   )
19.   (if (findfile newFileName)
20.     (progn
21.       (alert (strcat newFileName " exists ... cancelling command"))
22.       (exit)
23.     )
24.   )
25.   (if (findfile ArchiveFileName)
26.     (progn
27.       (alert (strcat ArchiveFileName " exists ... cancelling command"))
28.       (exit)
29.     )
30.   )
31.   ;;--
32.   (vl-cmdf "_Saveas" "2013" ArchiveFileName )
33.   (vl-cmdf "_Saveas" "2013" newFileName )
34.   (vl-file-delete OriginalFileName)
35.   ;; (vl-file-delete ArchiveFileName) ;; if you really want to
36.   (princ)
37. )
38.  
39. (princ)
40.  
41.  
42. (defun myDefault*error* (msg)
43.   (while (< 0 (getvar 'cmdactive)) (command-s nil))
44.   (setvar 'menuecho 1)
45.   (cond ((not msg))
46.         ((member (strcase msg t)
47.                  '("console break" "function cancelled" "quit / exit abort")
48.          )
49.          (princ "\nFunction Cancelled.")
50.         )
51.         ((princ (strcat "\nApplication Error: " (itoa (getvar 'errno)) " :- " msg))
52.          (vl-bt)
53.         )
54.   )
55.   (setvar 'errno 0)
56.   (princ)
57. )
58.  
59.  
60. (princ)
61.  
62.  

modified:kdub

[danglar]

looks nice , but what's about delete orriginal file and open new one?

[Kerry]

The new one is already open because of the saveas.

Delete the original the same way you did previously if you really want to.

eg
(vl-file-delete ArchiveFileName)

Personally I'd leave it in the Temp folder for a while


ahhh I see what you mean ... just a sec

[Kerry]

Have a play now

[danglar]

now it's works more efficient, but in some cases i need to reduce "wight" of cleaned file and I prefere to do it via "wblock" command. In your program I have a little problem with it because in wblock case i have an existing file and I need to overwrite it

[Kerry]

Sounds like a Personal Problem.
I'm sure you can resolve it.

I don't see a problem.

[danglar]

thank you I'll try to find a solution

[Kerry]

When are you wblocking ?
How are you wblocking ?
Which drawing are you wblocking ?
What is the name of the new drawing ?

I shouldn't need to ask these questions ... they should be part of your question.

.

[danglar]

you are right about the questions and time to ask it..
I need:
1. wblock from current file with new name, like you did it
2. open new file (created by wblock command)
3. close previous file
4. delete previous file

[Kerry]

Do you want to do this ALL the time or only sometimes  ?

That is : will you need 2 functions or one ?

[Kerry]

I have an old memory of there being problems wblocking and re-opening a drawing .... not sure about it

Personally I'd
set layer 0
Zoom Extents
Purge 3 times
Audit with repair.
Save.

Do the above in one function.

Then run the renamer we've been playing with.

I'm off to bed.

[danglar]

I need to do wblocking All the times.. in my old program i did it without any problem except for spaces between words in path and name of file

[Kerry]

This seems to work OK for me.
Please Test thoroughly.

Code - Auto/Visual Lisp: [Select]

1. (defun c:doit (/ *error*)                              ; TODO add local variables
2.   ;;-----------
3.   (defun *error* (msg) (myDefault*error* msg))
4.   ;;-----------
5.   (vl-cmdf "_qsave")
6.   (setq dwgprefix     (getvar "dwgprefix")
7.         dwgname       (getvar "dwgname")
8.         filename-base (vl-filename-base dwgname)
9.         tempprefix    (getvar "tempprefix")
10.         thedate       (rtos (getvar "CDATE") 2 0)
11.   )
12.   (setq OriginalFileName (strcat dwgprefix dwgname)
13.         ArchiveFileName  (strcat tempprefix
14.                                  dwgname
15.                                  "-"
16.                                  (rtos (* (getvar "cdate") 1000000) 2 0)
17.                          )
18.         newFileName      (strcat dwgprefix    "XREF-"
19.                                  filename-base
20.                                  "-TPZ-"      thedate
21.                                  ".Dwg"
22.                                 )
23.   )
24.   ;;--
25.   (setq expert (getvar "expert"))
26.   (setvar "expert" 5)
27.   ;;---------- wblock  
28.   (vl-cmdf "-layer" "set" "0" "")
29.   (vl-cmdf ".ucs" "W")
30.   (vl-cmdf "Zoom" "E")
31.   (vl-cmdf "_Saveas" "2013" ArchiveFileName)
32.   (setq ss (ssget "X"))
33.   (vl-cmdf ".wblock" newFileName "" (getvar "insbase") ss "")
34.   (setvar "expert" expert)
35.   ;;---------- write script
36.   (setq fn (open (strcat tempprefix "sclean.scr") "w"))
37.   (write-line "close n" fn)
38.   (write-line
39.     (strcat "open "
40.             (strcat (vl-string-right-trim
41.                       "\""
42.                       (vl-prin1-to-string
43.                         (vl-string-translate "\\" "/" newFileName)
44.                       )
45.                     )
46.                     "\""
47.             )
48.     )
49.     fn
50.   )
51.   (write-line
52.     (strcat
53.       "(vl-file-delete "
54.       (vl-string-right-trim
55.         "\""
56.         (vl-prin1-to-string (vl-string-translate "\\" "/" dwgprefix))
57.       )
58.       filename-base
59.       ".dwg\")"
60.     )
61.     fn
62.   )
63.   (close fn)
64.   ;;----------
65.   (vl-cmdf "script" (strcat tempprefix "sclean.scr"))
66.   (princ)
67. )
68.  
69. (princ)
70.  
71.  
72.  
73.  
74. (defun myDefault*error* (msg)
75.   (while (< 0 (getvar 'cmdactive)) (command-s nil))
76.   (setvar 'menuecho 1)
77.   (cond ((not msg))
78.         ((member
79.            (strcase msg t)
80.            '("console break" "function cancelled" "quit / exit abort")
81.          )
82.          (princ "\nFunction Cancelled.")
83.         )
84.         ((princ (strcat "\nApplication Error: "
85.                         (itoa (getvar 'errno))
86.                         " :- "
87.                         msg
88.                 )
89.          )
90.          (vl-bt)
91.         )
92.   )
93.   (setvar 'errno 0)
94.   (princ)
95. )
96.  
97.   (princ)
98.  
99.  

[danglar]

As requested, i did a Test of your program thoroughly and find it's working properly!
In a same time I made the necessary changes for me.
For example I set the date in a convenient for the Europeans form and canceled backups because I have
automatical backup on my comp.
Now, I think, we have a final solution of the issue (see attached lisp)
Thank you very much for Great Help!

[Kerry]

Good to hear.

Personally I would keep the archive copy ... unless you have a backup immediately before you wblock it and erase the original.

If something weird happens with the wblock you will need to rely on your last backup, which may not be current.