Topic: How to list unreconciled layers.

[borgiedude]

Hello all,

I've been writing code with lisp for a while but I've recently started trying to branch out with visual lisp. I've spent a couple of nights after work Googling for a way to perform a visual lisp check but I can't seem to find a helpful example.

Basically I want to check if there are unreconciled layers in a drawing and for each unreconciled layer, I want to perform some operations, such as freezing the layer and adding its name to a list before reconciling the layer.

My question is, how would I iterate through the list of layers checking for the unreconciled property?

I've gotten as far as (setq layers (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))), and I can iterate through these with (vlax-for). I think that getextensiondictionary should be used somewhere, but I can't seem to find out how to phrase a logical test.

Can anybody offer a bit of advice? Any help would be greatly appreciated.

[ChrisCarlson]

Perhaps this is of some use

Code - Auto/Visual Lisp: [Select]

1. ;;; PurgeReconciledLayers.LSP
2. ;;;
3. ;;; By Jimmy Bergmark
4. ;;; Copyright (C) 2007 JTB World, All Rights Reserved
5. ;;; Website: www.jtbworld.com
6. ;;; E-mail:
7.  info@jtbworld.com
8. ;;; 2007-04-05 - First release
9. ;;; Written for AutoCAD 2008
10.  
11. ;;; Purge all information about reconciled layers in the drawing
12.  
13. (defun PurgeReconciledLayers ()
14.   (vl-load-com)
15.   (vlax-for layer (vla-get-Layers
16.                     (vla-get-ActiveDocument
17.                       (vlax-get-acad-object)
18.                     )
19.                   )
20.     (vl-Catch-All-Apply
21.       '(lambda ()
22.          (vla-Remove
23.            (vla-GetExtensionDictionary
24.              layer
25.            )
26.            "ADSK_XREC_LAYER_RECONCILED"
27.          )
28.        )
29.     )
30.     (vl-Catch-All-Apply
31.       '(lambda ()
32.          (vla-delete
33.            (vla-GetExtensionDictionary
34.              layer
35.            )
36.          )
37.        )
38.     )
39.   )
40.   (setvar "LAYEREVAL" 0)
41.   (setvar "LAYERNOTIFY" 0)
42.   (princ)
43. )
44.  

[borgiedude]

Thanks for posting that Chris.

I've actually come across things like this a lot in my searching but I've been stuck with a few questions after viewing these sorts of code.

From what I can tell, the script is removing the unreconciled property from all layers in lines 20-29. But if that's the case I'm not sure what lines 30-39 are doing; removing the extension dictionary altogether?

Also I've seen "ADSK_XREC_LAYER_RECONCILED" pop up a lot, and I know that's the detail which I need to interact with, but I'm not sure how I would find that a layer had this property. What I mean is, if I dump the extension dictionary for a layer, this term "ADSK_XREC_LAYER_RECONCILED" does not show up; how could I know that this is what the property is called in the VBA language?

What I keep thinking is along these lines:

(if (= "ADSK_XREC_LAYER_RECONCILED" some-extension-dictionary-function) (progn ...))

Any idea what 'some-extension-dictionary-function' could be?

[ChrisCarlson]

Code - Auto/Visual Lisp: [Select]

1. (defun isreconciled (layname)
2. ;;http://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/layereval-layernotify/m-p/4705497
3.         (not
4.                 (vl-catch-all-error-p
5.                         (vl-catch-all-apply
6.                         'vla-item
7.                                 (list
8.                                         (vla-getextensiondictionary
9.                                                 (vla-item
10.                                                         (vla-get-layers
11.                                                                 (vla-get-activedocument
12.                                                                         (vlax-get-acad-object)
13.                                                                 )
14.                                                         )
15.                                                 layname)
16.                                         )
17.                                 "ADSK_XREC_LAYER_RECONCILED"
18.                                 )
19.                         )
20.                 )
21.         )
22. )
23.  

(isreconciled "layer") will return T if reconciled and nill if unreconciled.

[borgiedude]

Thank you very much Chris.

After work today I'll have a play around with this and see if I can understand what each line is doing. Then I'll probably try to adapt it to my use and post my results!

[borgiedude]

Ok, I think I've put it together. It will probably become apparent from my thinking out loud that I'm very new at this, but hopefully this will help another newbie.

After obtaining the list of layers as a vl object, lines 9 and 15 of the script return the named layer as a vl item.

The extension dictionary is then found for the layer and in lines 5 and 6 the extension dictionary is searched for the vl item identified as "ADSK_XREC_LAYER_RECONCILED". If the vl item is found, line 4 of the script returns nil, since there has been no error, and if the reconciled property is not found, 'vl-item applied to that extension dictionary returns an error, and vl-catch-all-error-p returns T.

Finally, line 3 inverts the T/nil so that logically, isreconciled returns true if the layer is reconciled!

Taking what I've learned, my script can be written as follows:

Code - Auto/Visual Lisp: [Select]

1. (defun c:getunreclayers ( / layers i unreclist )
2.   (vl-load-com)
3.   (setq layers (vla-get-Layers (vla-get-activedocument (vlax-get-acad-object)))
4.         i 0) ; Gather the layers in the active document and set a counter to 0
5.   (repeat (vla-get-count layers) ; Cycle through every layer
6.     (progn
7.       (if       ; Check to see if
8.         (vl-catch-all-error-p ; An error is returned
9.           (vl-catch-all-apply 'vla-item ; When searching for
10.             (list (vla-GetExtensionDictionary (vla-item layers i)) ; The exten-dictionary item
11.                   "ADSK_XREC_LAYER_RECONCILED") ; indicated by this string
12.             )
13.           )
14.         (setq unreclist
15.                (append unreclist ; If an error is returned, because the reconciled property is not found
16.                        (list ; Add the name of the unreconciled layer
17.                          (vla-get-name  ; To the growing list of unreconciled layers
18.                            (vla-item layers i)
19.                            )
20.                          )
21.                        )
22.               )
23.         )
24.       (setq i (+ i 1)) ; increase the counter by 1
25.       )
26.     )
27.   unreclist ; return the list of unreconciled layers
28. )
29.  

It's not too pretty, I'm sure there are better ways of doing things, and I don't doubt that Lee Mac could write  something functionally identical in just 4 lines, but it works and I'm happy with it.

Thanks again for your help Chris!

[Lee Mac]

FWIW, here is another way to approach it - from a Vanilla perspective:

Code - Auto/Visual Lisp: [Select]

1. (defun unreconlayers ( / def dic lay lst )
2.     (while (setq def (tblnext "layer" (not def)))
3.         (setq lay (cdr (assoc 2 def))
4.               dic (cdr (assoc 360 (entget (tblobjname "layer" lay))))
5.         )
6.         (or (and  dic (dictsearch dic "adsk_xrec_layer_reconciled"))
7.             (setq lst (cons lay lst))
8.         )
9.     )
10.     (reverse lst)
11. )

[borgiedude]

Wow, thanks Lee, I didn't know that it was possible to do that with vanilla Lisp.

(THE Lee Mac actually replied to MY thread  )

[Lee Mac]

Wow, thanks Lee, I didn't know that it was possible to do that with vanilla Lisp.

Indeed some data is only accessible through Visual LISP, however Layer Extension Dictionaries are certainly exposed to Vanilla AutoLISP; personally I prefer to access the dictionaries in this way, as the dictsearch function will return nil when the target item is not present, whereas the equivalent ActiveX item method or getobject method will error under such circumstances, requiring the use of a vl-catch-all-apply/error-p statement, which is a bit cumbersome.

(THE Lee Mac actually replied to MY thread  )

Haha! You flatter me