Author Topic: Grvecs and cursor position (Read 4848 times)

CincyJeff · « **on:** August 31, 2015, 11:36:53 AM »

Can anybody help me figure out how to use grvecs to display near the cursor? I'm running a grread loop to track the cursor and I want to display information to the user concerning the number of rows and columns in a dynamic block. I want to use Lee Mac's LM:GrText routine to create the dynamic output but I can't get grvecs to follow the cursor. It displays the text but not any where near the cursor. What do I use with grvecs?

Code - Auto/Visual Lisp: [Select]

(setq code (grread t))
(grvecs (LM:GrText #ofrows)
        (list (list 1.0 0.0 0.0 (caadr code))
        (list 0.0 1.0 0.0 (cadadr code))
        '(0.0 0.0 1.0 0.0)
        '(0.0 0.0 0.0 1.0)))

Lee Mac · « **Reply #1 on:** August 31, 2015, 11:49:26 AM »

Hi Jeff,

As noted in the description on my site, my LM:GrText function will return a list of vectors in pixel units, relative to the origin (this representation is necessary so that such vectors may be scaled & positioned at any zoom level whilst maintaining the 'pixel-to-pixel' resolution).

I would suggest studying the GrTextDemo.lsp file available on my site, which contains several examples showing how to use my LM:GrText function (including a LM:DisplayGrText function to take care of the necesary scaling & positioning relative to the cursor).

If you have further questions, just ask.

Lee

CincyJeff · « **Reply #2 on:** August 31, 2015, 12:50:19 PM »

Thanks Lee. I'll take a look at the demo program.

CincyJeff · « **Reply #3 on:** September 01, 2015, 08:39:56 AM »

I got it to work most of the time but I'm having trouble transforming coordinates. In some drawings the rectangle is drawn displaced by the value of the target system variable. If I transform from World to UCS, instead of UCS to DCS, it eliminates the 'target' displacement. Am I introducing other issues by changing this?

Also, it does not take into account rotated blocks. Is it possible to draw the rectangle to match the block orientation?

Lee Mac · « **Reply #4 on:** September 01, 2015, 09:06:50 AM »

I'm not sure what rectangle you are referring to?

- My LM:GrText function will only display text.

CincyJeff · « **Reply #5 on:** September 01, 2015, 09:26:47 AM »

I was not clear in my post. I am using your Demo3 that displays the area of a rectangle. The blocks I am working with use a rectangular array so I want a rectangle to be drawn to represent the modified size of the array. I don't know how to grip_stretch the dynamic block and update the cursor at the same time so I am just dragging a rectangle instead. As you drag your cursor in Demo3 there is a rectangle that grows from the base point. If I have a block that has been rotated 90 degrees counterclockwise the rectangle is drawn to the upper right from the base point instead of the lower right quadrant to match the block orientation.

Lee Mac · « **Reply #6 on:** September 01, 2015, 09:40:52 AM »

Quote from: CincyJeff on September 01, 2015, 09:26:47 AM

I was not clear in my post. I am using your Demo3 that displays the area of a rectangle. The blocks I am working with use a rectangular array so I want a rectangle to be drawn to represent the modified size of the array. I don't know how to grip_stretch the dynamic block and update the cursor at the same time so I am just dragging a rectangle instead. As you drag your cursor in Demo3 there is a rectangle that grows from the base point. If I have a block that has been rotated 90 degrees counterclockwise the rectangle is drawn to the upper right from the base point instead of the lower right quadrant to match the block orientation.

To clarify, my 'Demo 3' example program simply prompts the user for a base point and constructs the rectangle based on the delta X & Y coordinate values between the cursor position and the given base point - it does not care about objects in the drawing, as the only input is the point supplied by the user.

For your task, you would need to prompt the user to select the block reference entity, retrieve the insertion point & rotation of the block, and then calculate the positions of the two remaining rectangle vertices, given that the block insertion point and cursor position will be located along one of the rectangle diagonals.

Lee Mac · « **Reply #7 on:** September 01, 2015, 11:03:19 AM »

Here's a quick example to get you started:

Code - Auto/Visual Lisp: [Select]

(defun c:test ( / cpt dis ent enx ins pt1 pt2 pt3 pt4 rot suf vec )
    (if (and (setq ent (car (entsel "\nSelect block: ")))
             (= "INSERT" (cdr (assoc 0 (setq enx (entget ent)))))
        )
        (progn
            (setq suf (strcat (if (< (getvar 'lunits) 3) "mm" "in") (chr 178))
                  rot (cdr (assoc 50 enx))
                  vec (list (cos rot) (sin rot))
                  ins (cdr (assoc 10 enx))
                  pt1 (trans ins ent vec)
                  ins (trans ins ent 1)
            )
            (while (= 5 (car (setq pt3 (grread nil 13 0))))
                (redraw)
                (setq cpt (cadr pt3)
                      pt3 (trans cpt 1 vec)
                      dis (mapcar '- pt3 pt1)
                      pt2 (trans (list (car pt1) (cadr pt1) (caddr pt3)) vec 1)
                      pt4 (trans (list (car pt3) (cadr pt3) (caddr pt1)) vec 1)
                )
                (LM:DisplayGrText cpt (LM:GrText (strcat (rtos (abs (* (car dis) (caddr dis))) 2 4) suf)) 3 15 -31)
                (grvecs (list 256 ins pt2 pt2 cpt cpt pt4 pt4 ins))
            )
        )
    )
    (princ)
)

The above could also be achieved using polar.

CincyJeff · « **Reply #8 on:** September 01, 2015, 01:08:39 PM »

Lee,
It's almost there. In your Demo3 lisp you have a great feature that draws the rectangle with a dashed line when the x-value goes negative. I would like to do something similar where my prompt changes and the rectangle is dashed anytime the cursor is not in the positive x-y quadrant from the entity frame of reference. I just can't get my head around the translations going on.
Your line of code was:

Code - Auto/Visual Lisp: [Select]

(if (< (car dis) 0.0) -256 256

which I modified to:

Code - Auto/Visual Lisp: [Select]

(if (or (< (car dis) 0.0) (< (cadr dis) 0.0)) -256 256)

Would I translate the cursor position to relate to the entity?

Code - Auto/Visual Lisp: [Select]

(defun C:ARRSIZE (/ basept col# coldist colspac method row# rowdist rowspac)
  (UTIL:SETDEBUG "ARSI:UPDATEBLOCK")
  (setq entnam  (car entsel)
        blkrot  (vla-get-rotation (vlax-ename->vla-object entnam))
        rowspac 72 ; from block and retrieved with xdata
        colspac 30 ; from block and retrieved with xdata
  ) ;_ end of setq
  (initget 7 "Cursor Keyboard")
  (setq method (getkword "\nSelect input method [Cursor/Keyboard]: "))
  (if (= method "Cursor")
    (if (setq basept (UTIL:DXF 10 (entget entnam)))
      (ARSI:DRAWRECTANGLE)
    ) ;_ end of if
    (progn
      (initget 7)
      (setq row# (getint "\nInput the number of rows: "))
      (initget 7)
      (setq col# (getint "Input the number of columns: "))
    ) ;_ end of progn
  ) ;_ end of if
  (princ "\nUpdating the array. ")
  (if (setq rowdist (* row# rowspac))
    (UTIL:PUTPROPERTY
      entnam
      "Vertical Array Distance"
      rowdist
      vlax-vbdouble
    ) ;_ end of UTIL:PUTPROPERTY
    (alert "Row Distance not set.")
  ) ;_ end of if
  (if (setq coldist (* col# colspac))
    (UTIL:PUTPROPERTY
      entnam
      "Horizontal Array Distance"
      coldist
      vlax-vbdouble
    ) ;_ end of UTIL:PUTPROPERTY
    (alert "Column Distance not set.")
  ) ;_ end of if
  (vl-cmdf "._updatefield" entnam "")
  (UTIL:RESETDEBUG)
) ;_ end of defun - ARSI:UPDATEBLOCK
 
;;;-------------------------------------------------------------------------------------;
;;;  Function: ARSI:DRAWRECTANGLE                                                       ;
;;;-------------------------------------------------------------------------------------;
;;; 
;;;
;; GrText Demo Program 3  -  Lee Mac
;; Prompts the user for a base point and displays
;; the area of the rectangular region enclosed by the
;; base point and cursor as the cursor is moved across the screen.
;;
;; Requires: GrText.lsp
;;;-------------------------------------------------------------------------------------;
 
(defun ARSI:DRAWRECTANGLE (/ cursor dis pt1 pt2 pt3 pt4 vector)
  (setq basept (reverse (cdr (reverse basept)))
        vector (list (cos blkrot) (sin blkrot))
        pt1    (trans basept entnam vector)
        basept (trans basept entnam 1)
  ) ;_ end of setq
  (while (= 5 (car (setq cursor (grread nil 13 0))))
    (redraw)
    (setq cursor (cadr cursor)
          pt3    (trans cursor 1 vector)
          dis    (mapcar '- pt3 pt1)
          row#   (fix (/ (- (cadr cursor) (cadr basept)) rowspac))
          col#   (fix (/ (- (car cursor) (car basept)) colspac))
          pt2    (trans (list (car pt1) (cadr pt1) (caddr pt3)) vector 1)
          pt4    (trans (list (car pt3) (cadr pt3) (caddr pt1)) vector 1)
    ) ;_ end of setq
    (if (and (>= row# 1) (>= col# 1))
      (progn
        (LM:DisplayGrText
          cursor
          (LM:GrText
            (strcat (itoa row#) " Rows, " (itoa col#) " Columns")
          ) ;_ end of LM:GrText
          3
          15
          45
        ) ;_ end of LM:DisplayGrText
        (LM:DisplayGrText
          cursor
          (LM:GrText (strcat (itoa (* row# col#)) " Units"))
          4
          15
          15
        ) ;_ end of LM:DisplayGrText
      ) ;_ end of progn
      (LM:DisplayGrText
        cursor
        (LM:GrText "Zero or negative values NOT allowed!")
        1
        15
        15
      ) ;_ end of LM:DisplayGrText
    ) ;_ end of if
    (grvecs
;; ** line to update **
      (list (if (or (< (car dis) 0.0) (< (cadr dis) 0.0))     
;; ** line to update **
              -256
              256
            ) ;_ end of if
            basept pt2 pt2 cursor cursor pt4 pt4 basept
      ) ;_ end of list
    ) ;_ end of grvecs
  ) ;_ end of while
  (redraw)
) ;_ end of defun - ARSI:DRAWRECTANGLE
 
;; Display GrText  -  Lee Mac
;; pnt  -  cursor point in UCS
;; vec  -  GrText vector list
;; col  -  Text Colour (ACI Colour)
;; xof  -  x-offset from cursor in pixels
;; yof  -  y-offset from cursor in pixels
 
(defun LM:DisplayGrText ( pnt vec col xof yof / scl )
    (setq scl (/ (getvar 'viewsize) (cadr (getvar 'screensize)))
          pnt (trans pnt 1 2)
    )
    (grvecs (cons col vec)
        (list
            (list scl 0.0 0.0 (+ (car  pnt) (* xof scl)))
            (list 0.0 scl 0.0 (+ (cadr pnt) (* yof scl)))
            (list 0.0 0.0 scl 0.0)
           '(0.0 0.0 0.0 1.0)
        )
    )
)
 
(defun UTIL:PUTPROPERTY (entname propname varval vartype / object proplist)
  (setq object (vlax-ename->vla-object entname))
  (setq proplist (vla-getdynamicblockproperties object))
  (setq proplist (vlax-variant-value proplist))
  (setq proplist (vlax-safearray->list proplist))
  (foreach item proplist
    (if (= (strcase (vla-get-propertyname item)) (strcase propname))
      (vla-put-value
        item
        (vlax-make-variant varval vartype)
      ) ;_ end of vla-put-value
    ) ;_ end of if
  ) ;_ end of foreach
) ;_ end of defun - UTIL:PUTPROPERTY

News:

Author Topic: Grvecs and cursor position (Read 4848 times)

CincyJeff

Grvecs and cursor position

Lee Mac

Re: Grvecs and cursor position

CincyJeff

Re: Grvecs and cursor position

CincyJeff

Re: Grvecs and cursor position

Lee Mac

Re: Grvecs and cursor position

CincyJeff

Re: Grvecs and cursor position

Lee Mac

Re: Grvecs and cursor position

Lee Mac

Re: Grvecs and cursor position

CincyJeff

Re: Grvecs and cursor position