Topic: Delete a layer within a block

[GDF]

Is it possible to delete a layer within a block without using the block editor?

[ChrisCarlson]

As in delete a layer from the drawing or delete an object on that layer?

[Lee Mac]

Put simply:

Code - Auto/Visual Lisp: [Select]

1. (vlax-for obj (vla-item (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))) "YourBlockHere")
2.     (if (and (= "YourLayerHere" (vla-get-layer obj)) (vlax-write-enabled-p obj))
3.         (vla-delete obj)
4.     )
5. )

[GDF]

Thanks Lee.

Perfect!

[Lee Mac]

You're welcome! 

[GDF]

Example of how I'm using your routine:

(defun C:DLB (/ YourBlockHere YourLayerHere)
  (Setq YourBlockHere (cdr (assoc 2 (entget (car (entsel "Select Block: "))))))
  (vlax-for obj (vla-item (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))) YourBlockHere)
    (if (and (= "A-DIMS" (vla-get-layer obj)) (vlax-write-enabled-p obj))
        (vla-delete obj)
    )
  )
  (princ)
)

[Lee Mac]

Nice one Gary 

Here are some tweaks to include a little more error trapping to account for null user input, dynamic blocks etc.:

Code - Auto/Visual Lisp: [Select]

1. (defun c:dlb ( / ent )
2.     (while
3.         (progn (setvar 'errno 0) (setq ent (car (entsel "\nSelect block: ")))
4.             (cond
5.                 (   (= 7 (getvar 'errno))
6.                     (princ "\nMissed, try again.")
7.                 )
8.                 (   (null ent) nil)
9.                 (   (/= "INSERT" (cdr (assoc 0 (entget ent))))
10.                     (princ "\nSelected object is not a block.")
11.                 )
12.                 (   t
13.                     (vlax-for obj
14.                         (vla-item
15.                             (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
16.                             (vla-get-effectivename (vlax-ename->vla-object ent))
17.                         )
18.                         (if (and (= "A-DIMS" (vla-get-layer obj)) (vlax-write-enabled-p obj))
19.                             (vla-delete obj)
20.                         )
21.                     )
22.                     nil
23.                 )
24.             )
25.         )
26.     )
27.     (princ)
28. )

[Krushert]

Code - Auto/Visual Lisp: [Select]

1. (defun c:dlb ( / ent )
2.     (while
3.         (progn (setvar 'errno 0) (setq ent (car (entsel "\nSelect block: ")))
4.             (cond
5.                 (   (= 7 (getvar 'errno))
6.                     (princ "\nMISSED IT by that much Agent 99, try again.")
7.                 )
8.                 (   (null ent) nil)
9.                 (   (/= "INSERT" (cdr (assoc 0 (entget ent))))
10.                     (princ "\nSelected object is not a block.")
11.                 )
12.                 (   t
13.                     (vlax-for obj
14.                         (vla-item
15.                             (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
16.                             (vla-get-effectivename (vlax-ename->vla-object ent))
17.                         )
18.                         (if (and (= "A-DIMS" (vla-get-layer obj)) (vlax-write-enabled-p obj))
19.                             (vla-delete obj)
20.                         )
21.                     )
22.                     nil
23.                 )
24.             )
25.         )
26.     )
27.     (princ)
28. )

My tweak within Lee's Code.   

[Lee Mac]

My tweak within Lee's Code.   

 

[ChrisCarlson]

Since we are offering tweaks, utilize Lee's selectif function and make a call to it. Very useful that way.

[ronjonp]

Since we are offering tweaks, utilize use Lee's selectif function and make a call to it. Very useful that way.

Here's my 'tweak' 

[GDF]

Thanks 99

[GDF]

another variation:

Code: [Select]

(defun c:DLBX ( / chgblk obj e i s YourLayerHere YourBlockHere)
  (setq YourLayerHere (strcase (getstring "\n* Enter Layer Name:")))
  (if (= YourLayerHere "")(setq YourLayerHere (strcase "A-DIMS")))
  (defun chgblk (YourBlockHere YourLayerHere)
    (vlax-for obj (vla-item (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))) YourBlockHere)
      (if (and (= YourLayerHere (vla-get-layer obj)) (vlax-write-enabled-p obj))
        (vla-delete obj)
      )
    )
  )
  (if (setq s (ssget "X" '((2 . "`unit*"))))
     (progn
        (setq i (1- (sslength s)))
          (while (<= 0 i)
                (setq e (ssname s i)
                      YourBlockHere (cdr (assoc 2 (entget e)))
                      i (1- i)
                )
                (chgblk (strcase YourBlockHere) YourLayerHere)
               
            )
        )
  )
  (princ)
)


[Lee Mac]

Careful Gary - consider that we are modifying the block definition for these blocks, and so this change need only be performed once for each block name.

If you are looking to modify all blocks with name starting "unit", it becomes far more efficient to iterate directly over the block collection, i.e.:

Code - Auto/Visual Lisp: [Select]

1. (defun c:dlbx nil
2.     (vlax-for blk (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
3.         (if (wcmatch (strcase (vla-get-name blk) t) "unit*")
4.             (vlax-for obj blk
5.                 (if (and (= "A-DIMS" (strcase (vla-get-layer obj))) (vlax-write-enabled-p obj))
6.                     (vla-delete obj)
7.                 )
8.             )
9.         )
10.     )
11.     (princ)
12. )

[GDF]

Thanks Lee