Topic: 3d polyline draw with text

[dussla]

hello  friends
i need help again ~
if you see dwg file , you can see  polyline with text
i would like to draw 3d polyline  with text ( z value)
if i select  1   text     ,  after that    draw 3d polyline countley ~

[dussla]

(defun c:Poly ( / a)
  (command "._3dpoly")
  (while (eq 1 (logand 1 (getvar "cmdactive")))
    (if a (setq a (getpoint a "\n Pick Point: "))
      (setq a (getpoint "\n Pick Point: "))
    )

    (if a
   
     ( cond
     (setq e (car (entsel "\nNew Elevation, Select TEXT object [Return for KB input]: ")))
     (setq elist (entget e))
     (setq elev (read (cdr (assoc 1 elist)))) 
   
   
   
  (command (list (car a) (cadr a) elev))     
      (command)
    
      )
    )
   
  )
  (princ)
)


 this is  code  but that does not work

[roy_043]

Below is an improved version of your code. You will probably need to switch to the WCS before using it.

BricsCAD supports arbitrary input for entsel. But, according to the docs, AutoCAD does not. Which is a pity: the code can be more user friendly if arbitrary input is possible.

Code - Auto/Visual Lisp: [Select]

1. (defun c:Poly ( / elev elist enme pt)
2.   (command "._3dpoly")
3.   (while (eq 1 (logand 1 (getvar "cmdactive")))
4.     (if
5.       (and
6.         (if pt
7.           (setq pt (getpoint pt "\nPick Point: "))
8.           (setq pt (getpoint "\nPick Point: "))
9.         )
10.         (or
11.           (and
12.             (setq enme (car (entsel "\nNew Elevation from TEXT object or Enter: ")))
13.             (setq elist (entget enme))
14.             (numberp (setq elev (read (cdr (assoc 1 elist)))))
15.           )
16.           (setq elev (getdist "\nNew Elevation or Enter to quit: "))
17.         )
18.       )
19.       (command "_non" (list (car pt) (cadr pt) elev))
20.       (command nil)
21.     )
22.   )
23.   (princ)
24. )

[ribarm]

Here is my attempt...

Code - Auto/Visual Lisp: [Select]

1. (defun c:3pltxtelev ( / *error* *adoc* ape px pt pick enter gr p s pl lil )
2.  
3.   (vl-load-com)
4.  
5.   (defun *error* ( msg )
6.     (if lil
7.       (foreach li lil
8.         (entdel li)
9.       )
10.     )
11.     (command "_.3DPOLY")
12.     (foreach pt (reverse pl)
13.       (if (listp pt) (command "_non" pt))
14.     )
15.     (command "")
16.     (if ape (setvar 'aperture ape))
17.     (vla-endundomark *adoc*)
18.     (if msg (prompt msg))
19.     (princ)
20.   )
21.  
22.   (setq *adoc* (vla-get-activedocument (vlax-get-acad-object)))
23.   (vla-startundomark *adoc*)
24.   (setq ape (getvar 'aperture))
25.   (setvar 'aperture 15)
26.   (setq px (/ (getvar 'viewsize) (cadr (getvar 'screensize))))
27.   (setq pt (getpoint "\nStart point : "))
28.   (prompt "\nPick text entity or ENTER for keyboard input...")
29.   (while (and (not el) (setq gr (grread t 15 2)))
30.     (cond
31.       ( (= (car gr) 3)
32.         (if (osnap (cadr gr) "_nea") (setq p (osnap (cadr gr) "_nea")) (setq p (cadr gr)))
33.         (setq s (ssget "_C" (mapcar '- p (list (* (getvar 'aperture) px) 0.0 0.0)) (mapcar '+ p (list (* (getvar 'aperture) px) 0.0 0.0)) '((0 . "TEXT"))))
34.         (if s (setq pick nil) (setq pick t))
35.       )
36.       ( (and (= (car gr) 2) (or (= (cadr gr) 13) (= (cadr gr) 32)))
37.         (setq enter t)
38.       )
39.     )
40.     (if (not s)
41.       (cond
42.         ( pick
43.           (prompt "\nMissed, try picking text entity again, or press ENTER for keyboard input...")
44.           (setq el nil pick nil)
45.         )
46.         ( enter
47.           (setq el (getdist "\nPick or specify elevation for point specification <0.0> : "))
48.           (if (null el) (setq el 0.0))
49.           (setq enter nil)
50.         )
51.       )
52.       (setq el (atof (cdr (assoc 1 (entget (ssname s 0))))))
53.     )
54.   )
55.   (setq pt (list (car pt) (cadr pt) el))
56.   (setq pl (cons pt pl))
57.   (setq el nil s nil)
58.   (while (and pt (and (not (eq pt "c")) (not (eq pt "C")) (not (eq pt "Close"))))
59.     (if (= (length pl) 1)
60.       (progn
61.         (initget 1)
62.         (setq pt (getpoint (car pl) "\nPick or specify next point : "))
63.       )
64.       (progn
65.         (initget 128)
66.         (setq pt (getpoint (car pl) "\nPick or specify next point or [Undo/Close] <ENTER-FINISH> : "))
67.       )
68.     )
69.     (if (and pt (listp pt))
70.       (progn
71.         (prompt "\nPick text entity or ENTER for keyboard input...")
72.         (while (and (not el) (setq gr (grread t 15 2)))
73.           (cond
74.             ( (= (car gr) 3)
75.               (if (osnap (cadr gr) "_nea") (setq p (osnap (cadr gr) "_nea")) (setq p (cadr gr)))
76.               (setq s (ssget "_C" (mapcar '- p (list (* (getvar 'aperture) px) 0.0 0.0)) (mapcar '+ p (list (* (getvar 'aperture) px) 0.0 0.0)) '((0 . "TEXT"))))
77.               (if s (setq pick nil) (setq pick t))
78.             )
79.             ( (and (= (car gr) 2) (or (= (cadr gr) 13) (= (cadr gr) 32)))
80.               (setq enter t)
81.             )
82.           )
83.           (if (not s)
84.             (cond
85.               ( pick
86.                 (prompt "\nMissed, try picking text entity again, or press ENTER for keyboard input...")
87.                 (setq el nil pick nil)
88.               )
89.               ( enter
90.                 (setq el (getdist "\nPick or specify elevation for point specification <0.0> : "))
91.                 (if (null el) (setq el 0.0))
92.                 (setq enter nil)
93.               )
94.             )
95.             (setq el (atof (cdr (assoc 1 (entget (ssname s 0))))))
96.           )
97.         )
98.         (setq pt (list (car pt) (cadr pt) el))
99.         (setq pl (cons pt pl))
100.         (setq lil (cons (entmakex (list '(0 . "LINE") (cons 10 (trans (car pl) 1 0)) (cons 11 (if (cadr pl) (trans (cadr pl) 1 0) (trans (car pl) 1 0))))) lil))
101.         (setq el nil s nil)
102.       )
103.       (cond
104.         ( (or (eq pt "u") (eq pt "U") (eq pt "Undo"))
105.           (setq pl (cdr pl))
106.           (entdel (car lil))
107.           (setq lil (cdr lil))
108.         )
109.         ( (or (eq pt "c") (eq pt "C") (eq pt "Close"))
110.           (setq pl (cons (last pl) pl))
111.         )
112.       )
113.     )
114.   )
115.   (*error* nil)
116. )
117.  

HTH, M.R.

[dussla]

roy_043  , ribram   really thank you
work is good

really  thank youy