Topic: How to determine start point of a polyline?

[mjfarrell]

Yes you can tell in properties which way is which....

Select the line/polyline

Properties

Vertex....it lights up with an X

[ronjonp]

The example drawing posted is using lines ( the subject line of the thread is incorrect ).

[mjfarrell]

did not notice they were all lines...however a quick run of MPEDIT will turn them all into polylines fast enough

[yarnstormer]

Yes you can tell in properties which way is which....

Select the line/polyline

Properties

Vertex....it lights up with an X

What!!! Clearly I asked the wrong question in the first place.
That is what I needed to know. I'll convert them all to polylines.

Sorry about the polyline in thread title - I assumed they were. I never draw "lines" and didn't even notice they weren't polylines until after I started the thread. Again...inherited drawing full of surprises

[Mark]

I'm editing a large file that I did not begin that contains a number of lines to indicate sewer lines. I edit the beginning and end Z coordinates to properly elevate the line and use a custom "above w slope" label to label the distance, pipe size and slope.

Double check the polyline will allow you to do what you want. I'm thinking it won't though.

[mjfarrell]

right they would want to be 3d polylines....

however a quick trip through the revolving door and they can become 3d polylines....


Create FEATURE
Lines from Objects>>>Select objects
They become Feature lines

Use Quick Editor to assign elevations

EXPLODE them

They become 3d polylines @ correct elevations and slopes.

[Mark]

Create FEATURE
Lines from Objects>>>Select objects
They become Feature lines

Use Quick Editor to assign elevations

EXPLODE them

They become 3d polylines @ correct elevations and slopes.

Cool. [LIKE]

[yarnstormer]

right they would want to be 3d polylines....

however a quick trip through the revolving door and they can become 3d polylines....


Create FEATURE
Lines from Objects>>>Select objects
They become Feature lines

Use Quick Editor to assign elevations

EXPLODE them

They become 3d polylines @ correct elevations and slopes.

That is cool but I'm not editing the entire drawing just portions that I come across that are incorrect.
Converting to polylines seems to wipe out my label - not an option.

However I just discovered in the properties if you click in the box is the Z a red X pops up - click it and you get a line on your drawing to that point. I knew there had to be a way!
Thanks everyone for your responses.

[ronjonp]

If you want to send me the file, I could probably whip up some code to orient them correctly for you. Doing this by hand seems extremely tedious.

Interesting. How would you decide which/how to orient them? High end is the start? What would happen if some were not yet elevated? It is the process of elevating that is aggravating.

Could you write something that let me pick a line near one end, manually enter an elevation for that end, and would then request an elevation for the other end. If possible it might reverse the line by using the higher elevation as the new starting point.
I honestly don't care what direction they "think" they are going I just get aggravated that I can't tell in properties which end is which until I change the elevations.

Give this a try .. should speed up the process. Pick near an endpoint on a line to edit, if a coincident point is found at an elevation other than zero it will apply that elevation otherwise it prompts for an elevation.

Code - Auto/Visual Lisp: [Select]

1. (defun c:putelev (/ _getends _ss2l _vc c e o p p2 ss)
2.   (vl-load-com)
3.   (defun _vc (center segments color / lst cnt)
4.     (setq cnt 0)
5.     (repeat segments
6.       (setq lst (cons
7.                   (trans (polar center (* cnt (/ (* pi 2) segments)) (* 0.01 (car (getvar 'screensize))))
8.                          0
9.                          1
10.                   )
11.                   lst
12.                 )
13.             cnt (1+ cnt)
14.       )
15.     )
16.     (grvecs (cons color (append lst (cdr lst) (list (car lst)))))
17.     (princ)
18.   )
19.   (defun _ss2l (ss / n out)
20.     (if (= (type ss) 'pickset)
21.       (repeat (setq n (sslength ss)) (setq out (cons (ssname ss (setq n (1- n))) out)))
22.     )
23.   )
24.   (defun _getends (e /)
25.     (vl-remove-if
26.       '(lambda (p) (= 0.0 (last p)))
27.       (list (vlax-curve-getstartpoint e) (vlax-curve-getendpoint e))
28.     )
29.   )
30.   (if (and (setq ss (ssget "_A" '((0 . "line"))))
31.            (setq e (entsel "\nPick a line near an end point to edit: "))
32.            (= "LINE" (cdr (assoc 0 (entget (car e)))))
33.            (setq p (cadr e))
34.            (setq e (car e))
35.            (setq o (vlax-ename->vla-object e))
36.            (setq p (vlax-curve-getclosestpointto e p))
37.            (setq p (cond ((< (vlax-curve-getparamatpoint e p) (/ (vlax-curve-getendparam e) 2.))
38.                           (setq c 'startpoint)
39.                           (vlax-curve-getstartpoint e)
40.                          )
41.                          (t (setq c 'endpoint) (vlax-curve-getendpoint e))
42.                    )
43.            )
44.       )
45.     (cond ;; Look for matching endpoint at an elevation other than zero
46.           ((setq p2
47.                   (car
48.                     (vl-remove-if-not
49.                       (function (lambda (x) (equal (list (car p) (cadr p)) (list (car x) (cadr x)) 0.01)))
50.                       (apply 'append (mapcar '_getends (_ss2l (ssdel e ss))))
51.                     )
52.                   )
53.            )
54.            (vlax-put o c p2)
55.            (_vc p  30 2)
56.            (print (strcat "\nZ value " (vl-princ-to-string (last p2)) " found.."))
57.           )
58.           ;; Else prompt
59.           ((setq p2 (getreal "\nEnter Z value: "))
60.            (_vc p  30 2)
61.            (vlax-put o c (list (car p) (cadr p) p2))
62.           )
63.     )
64.   )
65.   (princ)
66. )

[mjfarrell]

Create FEATURE
Lines from Objects>>>Select objects
They become Feature lines

Use Quick Editor to assign elevations

EXPLODE them

They become 3d polylines @ correct elevations and slopes.

Cool. [LIKE]

It has other uses as well and thus even cooler than you now know

[yarnstormer]

Hey now that's great - also a good way to check the elevation in cases where it's not 0 but it's not correct either! Thank you so much! Only improvement I could suggest would be the opportunity to choose to default to the current elevation or change it rather than end the routine if the elev is other than 0

Explain coincident point please. Is that a point on the line in question or would a point on a line adjacent to it be included?

[ronjonp]

Hey now that's great - also a good way to check the elevation in cases where it's not 0 but it's not correct either! Thank you so much! Only improvement I could suggest would be the opportunity to choose to default to the current elevation or change it rather than end the routine if the elev is other than 0

Explain coincident point please. Is that a point on the line in question or would a point on a line adjacent to it be included?

The routine looks at the end point being modified, then looks at all other endpoints of all lines in the drawing to see if one of those point is "equal".


Give this version a try:

Code - Auto/Visual Lisp: [Select]

1. (defun c:putelev (/ _getends _ss2l _vc c e o p p2 ss)
2.   (vl-load-com)
3.   (defun _vc (center segments color / lst cnt)
4.     (setq cnt 0)
5.     (repeat segments
6.       (setq lst (cons
7.                   (trans (polar center (* cnt (/ (* pi 2) segments)) (* 0.01 (car (getvar 'screensize))))
8.                          0
9.                          1
10.                   )
11.                   lst
12.                 )
13.             cnt (1+ cnt)
14.       )
15.     )
16.     (grvecs (cons color (append lst (cdr lst) (list (car lst)))))
17.     (princ)
18.   )
19.   (defun _ss2l (ss / n out)
20.     (if (= (type ss) 'pickset)
21.       (repeat (setq n (sslength ss)) (setq out (cons (ssname ss (setq n (1- n))) out)))
22.     )
23.   )
24.   (defun _getends (e /)
25.     (vl-remove-if
26.       '(lambda (p) (= 0.0 (last p)))
27.       (list (vlax-curve-getstartpoint e) (vlax-curve-getendpoint e))
28.     )
29.   )
30.   ;; Global to store elevation
31.   (or *elev* (setq *elev* (getvar 'elevation)))
32.   (if (and (setq ss (ssget "_A" '((0 . "line"))))
33.            (setq e (entsel "\nPick a line near an end point to edit: "))
34.            (= "LINE" (cdr (assoc 0 (entget (car e)))))
35.            (setq p (cadr e))
36.            (setq e (car e))
37.            (setq o (vlax-ename->vla-object e))
38.            (setq p (vlax-curve-getclosestpointto e p))
39.            (setq p (cond ((< (vlax-curve-getparamatpoint e p) (/ (vlax-curve-getendparam e) 2.))
40.                           (setq c 'startpoint)
41.                           (vlax-curve-getstartpoint e)
42.                          )
43.                          (t (setq c 'endpoint) (vlax-curve-getendpoint e))
44.                    )
45.            )
46.       )
47.     (cond
48.       ;; Look for matching endpoint at an elevation other than zero
49.       ((setq p2
50.               (car
51.                 (vl-remove-if-not
52.                   (function (lambda (x) (equal (list (car p) (cadr p)) (list (car x) (cadr x)) 0.01)))
53.                   (apply 'append (mapcar '_getends (_ss2l (ssdel e ss))))
54.                 )
55.               )
56.        )
57.        (initget "YES NO")
58.        (if
59.          (= "YES"
60.             (getkword
61.               (strcat "\nUse Coincident Z value <" (vl-princ-to-string (last p2)) ">? [YES/NO]: ")
62.             )
63.          )
64.           (setq *elev* (last p2))
65.           (setq
66.             *elev* (cond ((getreal (strcat "\nEnter Z value [" (vl-princ-to-string *elev*) "]: ")))
67.                          (*elev*)
68.                    )
69.           )
70.        )
71.        (vlax-put o c (list (car p2) (cadr p2) *elev*))
72.        (_vc p 30 2)
73.       )
74.       ;; Else prompt
75.       ((setq
76.          *elev* (cond ((getreal (strcat "\nEnter Z value [" (vl-princ-to-string *elev*) "]: ")))
77.                       (*elev*)
78.                 )
79.        )
80.        (_vc p 30 2)
81.        (vlax-put o c (list (car p) (cadr p) *elev*))
82.       )
83.     )
84.   )
85.   (princ)
86. )

[yarnstormer]

Ah problem is that there may be as many as 4 lines converging all with different elevations due to different pipe inverts. So, the line needs to only reference itself - display the current elevation at that end, let me default and move on to other end and enter or default as necessary.

It might be good if it did as you have written and picked up on the adjacent invert but still let me override if the actual invert is different.

Is that possible? I really need to learn this stuff...

[ronjonp]

Ah problem is that there may be as many as 4 lines converging all with different elevations due to different pipe inverts. So, the line needs to only reference itself - display the current elevation at that end, let me default and move on to other end and enter or default as necessary.

It might be good if it did as you have written and picked up on the adjacent invert but still let me override if the actual invert is different.

Is that possible? I really need to learn this stuff...

All you need to do is take out the coincident point check (lines 48 - 73). I added something I thought would be useful but apparently it's not ( I don't do this type of drafting).


After rereading your post the code already does this:

It might be good if it did as you have written and picked up on the adjacent invert but still let me override if the actual invert is different.

[ronjonp]

If you'd like to find all your lines that have a point (or two) @ elevation 0, you could run this little snippet:

Code - Auto/Visual Lisp: [Select]

1. (sssetfirst
2.   nil
3.   (ssget "_X"
4.     '((0 . "line")
5.       (-4 . "<OR")
6.       (-4 . "*,*,=")
7.       (10 0.0 0.0 0.0)
8.       (-4 . "*,*,=")
9.       (11 0.0 0.0 0.0)
10.       (-4 . "OR>")
11.      )
12.   )
13. )