Topic: Copy Object along Feature Line

[MSTG007]

I did not know if someone already had a way to copy a block along a feature line or not? I have code that I usually use with polylines. The problem is I usually have to draw the feature line first and then redraw a polyline on top of it.

Code: [Select]

(defun c:CBFP (/ foo ss lst pt)
  (defun foo (p)
    (if (vl-consp p)
      (or (vl-member-if
            (function (lambda (a) (equal (list (car a) (cadr a)) (list (car p) (cadr p)))))
            plst
          )
          ((lambda (pnt) (foreach x lst (vla-move (vla-copy x) pt pnt)) (setq pLst (cons p pLst)))
            (vlax-3d-point p)
          )
      )
    )
  )

  (if (and (princ "\nSelect object(s) to copy: ")
           (setq lst ((lambda (i / ss e l)
                        (if (setq ss (ssget "_:L"))
                          (while (setq e (ssname ss (setq i (1+ i))))
                            (setq l (cons (vlax-ename->vla-object e) l))
                          )
                        )
                      )
                       -1
                     )
           )
           (setq pt ((lambda (p) (cond (p (vlax-3d-point (trans p 1 0)))))
                      (getpoint "\nSpecify base point: ")
                    )
           )
           (princ "\nSelect curves to copy object(s) along: ")
           (setq ss (ssget '((0 . "ARC,LINE,*POLYLINE,SPLINE"))))
      )
    ((lambda (i / e eLst p pLst)
       (while (setq e (ssname ss (setq i (1+ i))))
         (cond
           ((vl-position (cdr (assoc 0 (setq eLst (entget e)))) '("ARC" "LINE" "SPLINE"))
            (mapcar (function foo) (list (vlax-curve-getStartPoint e) (vlax-curve-getEndPoint e)))
           )
           ((vl-position (cdr (assoc 0 eLst)) '("LWPOLYLINE" "POLYLINE"))
            (repeat (setq p (1+ (fix (vlax-curve-getEndParam e))))
              (foo (vlax-curve-getPointAtParam e (setq p (1- p))))
            )
           )
         )
       )
     )
      -1
    )
  )
  (princ)
)


[mjfarrell]

exploded feature lines become polylines

[mjfarrell]

and, what type of block are you copying?

could be a way to do this as alignment/assembly process

[MSTG007]

Its just a surface spot block. I try to place one at all vertexes of the feature line quickly.

[mjfarrell]

use points...

along object, vertices


let the point style contain the block you want to place as the symbol

[mjfarrell]

I tend to use points for some labeling functions, as invariably someone later wants a stakeout list.
And points are the most direct way to get that task done.

[MSTG007]

We use the points on top of surfaces sometimes just to be able to project it to a profile.

[mjfarrell]

We use the points on top of surfaces sometimes just to be able to project it to a profile.

by point in this instance are you implying 'blocks'

it would also work with a point I believe

OR you could even try the transparent command 'SSE

[MSTG007]

Nope, the block was to reference the "surface spot elevation" label.