Topic: combinations

[Peter Guappa]

Given a list of n-integers (no duplicates)
Result: a list containing all unique combinations of 3 integers

eg (1 2 3 4 5) => ((1 2 3) (1 2 4) (1 2 5) (2 3 4) (2 3 5) (3 4 5))

any suggestions?
Thanks

[kpblc]

something like this?

Code - Auto/Visual Lisp: [Select]

1. (setq lst '(1 2 3 4 5 6 7))
2.  
3. (defun test (lst)
4.   (cond
5.     ((= (length lst) 3) (list lst))
6.     ((> (length lst) 3)
7.      (append (mapcar
8.                (function
9.                  (lambda (x)
10.                    (list (car lst) (cadr lst) x)
11.                    ) ;_ end of lambda
12.                  ) ;_ end of function
13.                (cddr lst)
14.                ) ;_ end of mapcar
15.              (test (cdr lst))
16.              ) ;_ end of append
17.      )
18.     ) ;_ end of cond
19.   ) ;_ end of defun

[ronjonp]

Another:

Code - Auto/Visual Lisp: [Select]

1. (defun _foo (l / i out tmp)
2.   (while l
3.     (setq i   (car l)
4.           l   (cdr l)
5.           tmp (cdr l)
6.     )
7.     (while tmp (setq out (cons (list i (car l) (car tmp)) out)) (setq tmp (cdr tmp)))
8.   )
9.   (reverse out)
10. )
11. (_foo '(0 1 2 3 4 5 6))
12. ;; ((0 1 2) (0 1 3) (0 1 4) (0 1 5) (0 1 6) (1 2 3) (1 2 4) (1 2 5) (1 2 6) (2 3 4) (2 3 5) (2 3 6) (3 4 5) (3 4 6) (4 5 6))

[Peter Guappa]

Thanks guys 

[Lee Mac]

See also:
www.theswamp.org/index.php?topic=2694
www.theswamp.org/index.php?topic=34086
http://lee-mac.com/permutations.html

[ElpanovEvgeniy]

I got different results 

Code - Auto/Visual Lisp: [Select]

1. (defun f (l)
2.   (if (cddr l)
3.     (apply (function append)
4.            (cons (f (cdr l))
5.                  (mapcar (function
6.                            (lambda (b) (mapcar (function (lambda (a) (list (car l) b a))) (cdr (member b l))))
7.                          )
8.                          (cdr l)
9.                  )
10.            )
11.     )
12.   )
13. )

Code - Auto/Visual Lisp: [Select]

1. (f '(1 2 3 4 5))
2. =>> ((3 4 5) (2 3 4) (2 3 5) (2 4 5) (1 2 3) (1 2 4) (1 2 5) (1 3 4) (1 3 5) (1 4 5))
3. (_foo  '(1 2 3 4 5))
4. =>> ((1 2 3) (1 2 4) (1 2 5) (2 3 4) (2 3 5) (3 4 5))
5. (test  '(1 2 3 4 5))
6. =>> ((1 2 3) (1 2 4) (1 2 5) (2 3 4) (2 3 5) (3 4 5))

Is it true I realized exercise? 

[ElpanovEvgeniy]

variant to sorted lists:

Code - Auto/Visual Lisp: [Select]

1. (defun f (l)
2.   (if (cddr l)
3.     (apply (function append)
4.            (append (mapcar (function
5.                              (lambda (b) (mapcar (function (lambda (a) (list (car l) b a))) (cdr (member b l))))
6.                            )
7.                            (cdr l)
8.                    )
9.                    (list (f (cdr l)))
10.            )
11.     )
12.   )
13. )

Test:

Code - Auto/Visual Lisp: [Select]

1. (f '(1 2 3 4 5))
2. =>>((1 2 3) (1 2 4) (1 2 5) (1 3 4) (1 3 5) (1 4 5) (2 3 4) (2 3 5) (2 4 5) (3 4 5))

[ronjonp]

I got different results 

Code - Auto/Visual Lisp: [Select]

1. (defun f (l)
2.   (if (cddr l)
3.     (apply (function append)
4.            (cons (f (cdr l))
5.                  (mapcar (function
6.                            (lambda (b) (mapcar (function (lambda (a) (list (car l) b a))) (cdr (member b l))))
7.                          )
8.                          (cdr l)
9.                  )
10.            )
11.     )
12.   )
13. )

Code - Auto/Visual Lisp: [Select]

1. (f '(1 2 3 4 5))
2. =>> ((3 4 5) (2 3 4) (2 3 5) (2 4 5) (1 2 3) (1 2 4) (1 2 5) (1 3 4) (1 3 5) (1 4 5))
3. (_foo  '(1 2 3 4 5))
4. =>> ((1 2 3) (1 2 4) (1 2 5) (2 3 4) (2 3 5) (3 4 5))
5. (test  '(1 2 3 4 5))
6. =>> ((1 2 3) (1 2 4) (1 2 5) (2 3 4) (2 3 5) (3 4 5))

Is it true I realized exercise? 

Knowing your skills I bet you're right    I just put something together that matched the OP's list and desired result.